Annotated Source: Zork 2

"GCLOCK for
                            The Zork Trilogy
         (c) Copyright 1983 Infocom, Inc.  All Rights Reserved"
 
<CONSTANT C-TABLELEN 180>
 
The timer table. See the “Timers” tab for a current listing.
<GLOBAL C-TABLE <ITABLE NONE 180>>
 
Indicates how much of the timer table is used for daemons. (No relation to the wizard’s demon!)
The difference between daemons and timers is that timers run every turn; daemons run every input, even if no turn passes. But Zork 2 does not use daemons.
<GLOBAL C-DEMONS 180>
 
Indicates how much of the timer table (C-TABLE) is used. This counts down from C-TABLELEN, which is 180.
<GLOBAL C-INTS 180>
 
<CONSTANT C-INTLEN 6>
 
<CONSTANT C-ENABLED? 0>
 
<CONSTANT C-TICK 1>
 
<CONSTANT C-RTN 2>
 
<ROUTINE DEMON (RTN TICK "AUX" CINT)
  #DECL ((RTN) ATOM (TICK) FIX (CINT) <PRIMTYPE VECTOR>)
  <PUT <SET CINT <INT .RTN T>> ,C-TICK .TICK>
  .CINT>
 
<ROUTINE QUEUE (RTN TICK "AUX" CINT)
  #DECL ((RTN) ATOM (TICK) FIX (CINT) <PRIMTYPE VECTOR>)
  <PUT <SET CINT <INT .RTN>> ,C-TICK .TICK>
  .CINT>
 
<ROUTINE INT (RTN "OPTIONAL" (DEMON <>) E C INT)
  #DECL ((RTN) ATOM (DEMON) <OR ATOM FALSE> (E C INT) <PRIMTYPE
                                  VECTOR>)
  <SET E <REST ,C-TABLE ,C-TABLELEN>>
  <SET C <REST ,C-TABLE ,C-INTS>>
  <REPEAT ()
          <COND (<==? .C .E>
                 <SETG C-INTS <- ,C-INTS ,C-INTLEN>>
                 <AND .DEMON <SETG C-DEMONS <- ,C-DEMONS ,C-INTLEN>>>
                 <SET INT <REST ,C-TABLE ,C-INTS>>
                 <PUT .INT ,C-RTN .RTN>
                 <RETURN .INT>)
                (<EQUAL? <GET .C ,C-RTN> .RTN> <RETURN .C>)>
          <SET C <REST .C ,C-INTLEN>>>>
 
<GLOBAL CLOCK-WAIT <>>
 
<ROUTINE CLOCKER ("AUX" C E TICK (FLG <>))
  #DECL ((C E) <PRIMTYPE VECTOR> (TICK) FIX (FLG) <OR FALSE ATOM>)
  <COND (,CLOCK-WAIT <SETG CLOCK-WAIT <>> <RFALSE>)>
  <SET C <REST ,C-TABLE <COND (,P-WON ,C-INTS) (T ,C-DEMONS)>>>
  <SET E <REST ,C-TABLE ,C-TABLELEN>>
  <REPEAT ()
          <COND (<==? .C .E>
                 <COND (<G? <SETG MOVES <+ ,MOVES 1>> 999>
                        <SETG MOVES 0>)>
                 <RETURN .FLG>)
                (<NOT <0? <GET .C ,C-ENABLED?>>>
                 <SET TICK <GET .C ,C-TICK>>
                 <COND (<0? .TICK>)
                       (T
                        <PUT .C ,C-TICK <- .TICK 1>>
                        <COND (<AND <NOT <G? .TICK 1>>
                                    <APPLY <GET .C ,C-RTN>>>
                               <SET FLG T>)>)>)>
          <SET C <REST .C ,C-INTLEN>>>>