Chapter 1 - Do Not Change Any Of This

Include Cragne Suite by Ryan Veeder.

[Don't mess with other people's rooms!]

WOO is a region.

WOO1 is a room in WOO.

WOO3 is a room in WOO. WOO3 is northeast of WOO1.

WOO4 is a room in WOO. WOO4 is southeast of WOO3.

WOO6 is a room in WOO. WOO6 is north of WOO3.

Part 1 - Middle of Woods

Commentary of WOO3 is "Thank you to Michael Gentry for the original [italic type]Anchorhead[roman type], which I first experienced while driving across the vast expanse of the United States. Sam Ashwell was my passenger/narrator, and punched in commands with a tiny stylus on a Palm Pilot. Ah, memories! Certain pieces of text in my room are in [italic type]italics[roman type]; those are callbacks to the original game, bits of text from Anchorhead that fit this room nicely and helped add to its feel.[paragraph break]Thanks to Ryan and Jenni for this wild idea, and for all the work they did to make it happen, and thanks to you for playing."

A thing can be Jacq-Examined or Jacq-Unexamined. A thing is usually Jacq-Unexamined.

A person can be Jacq-Calm or Jacq-Terrified. A person is usually Jacq-Calm.

Printed name of WOO3 is "The Dim Recesses of the Forest (Jacqueline A. Lott Ashwell)".

Description of WOO3 is "Branches scramble overhead, straining toward one another in a bid to blot out the sky. Mercifully, light manages to filter down through an opening in the canopy above a small pond. Paths slither away into the forest to the north, southwest, and southeast.[if unvisited][paragraph break][italic type]You pause a moment to let the hushed peacefulness of this place soak in -- a welcome relief from the unsettling events of the day.[roman type]"

Instead of listening while the player is in WOO3, say "You look up, into the trees, and listen. Wind occasionally moves through the branches. Now and then, a dove calls."

The Jacq-Dove is scenery in WOO3. The printed name of the Jacq-Dove is "mourning dove". Understand "mourning" and "dove" as the Jacq-Dove. Instead of doing something to the Jacq-Dove, say "The mourning dove remains hidden somewhere in the dim recesses of the forest."

Instead of smelling while the player is in WOO3, say "Damp. Decaying leaves. Slightly stagnant water."

The Jacq-Rock is nowhere. The printed name of the Jacq-Rock is "flat stone". Understand "rock" and "flat" and "stone" as the Jacq-Rock. The description of the Jacq-Rock is "A flat stone with rounded edges[if the Jacq-Rock is Jacq-Skipped], not unlike the stone you carelessly tossed into the pond, awakening a long-dormant horror. You damn well won't make that mistake again[otherwise]."

Instead of taking the Jacq-Rock:

    if the Jacq-Rock is Jacq-Skipped:

        say "It reminds you of the stone you skipped across the pond, awakening a long-dormant horror. You cannot bring yourself to touch it.";

    otherwise:

        say "Taken.";

        move the Jacq-Rock to the player.

A thing can be Jacq-Skipped or Jacq-Unskipped. A thing is usually Jacq-Unskipped.

Jacq-Skipping is an action applying to one thing. Understand "skip [something]" or "toss [something]" or "skim [something]" as Jacq-Skipping.

Instead of Jacq-Skipping the Jacq-Rock, try dropping the Jacq-Rock.

Jacq-Screaming is an action applying to nothing. Understand "scream" or "yell" or "shout" as Jacq-Screaming. Instead of Jacq-Screaming when the player is in WOO3:

    if Jacq-Drenching is not happening:

        say "You feel no need.";

    otherwise:

        say "If only that could save you.".

Instead of dropping the Jacq-Rock:

    if the player is in WOO3:

        if the Jacq-Rock is Jacq-Unskipped:

            say "You weigh the flat stone in the palm of your hand for a moment or two, then decide to see if you can make it skip across the pond: you wind your arm back and fling the rock at an angle near-parallel to the water. It [one of]unfortuantely hits the surface at an imperfect angle, makes a sad *plop* sound, and disappears from view. You sigh[or]skips once... twice... three times... then silently disappears. Not bad[or]skips once... twice... three... four five six seven times, then disappears from view. You enjoy a brief feeling of accomplishment[at random].";

            now the Jacq-Rock is Jacq-Skipped;

            now the Jacq-Rock is nowhere;

            stop the action;

        if the Jacq-Rock is Jacq-Skipped:

            say "There is absolutely no fucking way you will try skipping stones again. [italic type]Ever.[roman type][line break]";

    otherwise:

        say "You just can't bring yourself to part with the flat stone."

Jacq-Drenching is a scene. Jacq-Drenching begins when the Jacq-Rock is Jacq-Skipped. Jacq-Drenching ends when the time since Jacq-Drenching began is 5 minutes.

Every turn when Jacq-Drenching is happening:

    say "[one of]All of the sudden, the forest goes quiet. [italic type]Completely[roman type] quiet. No wind, no doves, no sound at all.[paragraph break]You are frozen in the stillness, too scared to move.[or][run paragraph on][stopping]".

Before doing something when Jacq-Drenching is happening:

    say "[one of]The unsettling silence continues. It's almost as if the forest is waiting for something to ... to [italic type]happen[roman type].[paragraph break]From the pond, a slimy ivory tentacle emerges, feeling its way toward you through the dead leaves.[paragraph break]You are transfixed, and powerless with fear.[or]It is as if you are observing from outside your own body: you watch as the eburnean appendage begins wrapping itself slowly around your ankle.[paragraph break]Suddenly, you are back inside your skin, and feel yourself being dragged toward the pond! You kick at the clammy white arm with your free foot, and desperately dig your fingers into the earth in an attempt to prevent the inevitable.[paragraph break]The surface of the once-placid pond now churns violently.[or]To your horror, you are pulled beneath the surface![paragraph break]All is dark. All is still. An unearthly calm consumes you. You cannot breathe, but you do not seem to care. You blink, unable to make out any shapes in the black water.[paragraph break]Then, from the depths, an ivory shape emerges: a many-tentacled creature. The cephalapod floats toward you, coming eye to eye, and you sense something... maybe [italic type]sadness?[roman type]...[or]Gently, two white tentacles place a delicate silver chain around your neck. Before you have time to express surprise or gratitude, the pond kraken carries you to shore. You inhale, thankful for the air, and turn back toward the pond just in time to see the last of the creature slip back beneath the surface.[or][run paragraph on][line break][stopping]";

    stop the action.

The Jacq-Locket is nowhere. The Jacq-Locket is wearable. The Jacq-Locket is an openable container. The Jacq-Locket is closed. The printed name of the Jacq-Locket is "antique locket".  Understand "antique" or "locket" or "necklace" or "silver" or "chain" or "delicate" as the Jacq-Locket. The description of the Jacq-Locket is "Like its chain, the locket is silver, surprisingly untouched by the murky depths from which it came. The front of the locket bears a tiny embossed likeness of a kraken. The initials [italic type]E.C.[roman type] are engraved on its back."

A thing can be Jacq-Examined or Jacq-Unexamined. A thing is usually Jacq-Unexamined.

A Jacq-Photo is inside the Jacq-Locket. The Jacq-Photo is undescribed. The printed name of the Jacq-Photo is "tintype". Understand "photo" or "photograph" or "tintype" or "image" as the Jacq-Photo.

Instead of examining the Jacq-Photo:

    if the Jacq-Photo is in the Jacq-Locket:

        say "It is a portrait of a young but stern-looking woman with dark locks and darker eyes. [if the Jacq-Photo is Jacq-Unexamined]The photograph is, to your amazement, dry and in good nick, despite how it came to be in your possession.[otherwise][line break]";

        now the Jacq-Photo is Jacq-Examined;

    otherwise:

        say "It is a portrait of a young but stern-looking woman with dark locks and darker eyes. [if the Jacq-Photo is Jacq-Unexamined]The photograph is, to your amazement, dry and in good nick, despite how it came to be in your possession.[otherwise][paragraph break]Turning the photo over to examine its back, you notice some writing, so small as to be barely discernible.";

        now the Jacq-Photo is Jacq-Examined.

Instead of removing the Jacq-Photo from the Jacq-Locket:

    say "As you handle the photo, you notice some writing on its reverse.";

    move the Jacq-Photo to the player;

Instead of taking the Jacq-Photo:

    say "As you handle the photo, you notice some writing on its reverse.";

    move the Jacq-Photo to the player.

The Jacq-Writing is part of the Jacq-Photo. The printed name of the Jacq-Writing is "writing". Understand "writing" or "note" as the Jacq-Writing. Instead of examining or reading the Jacq-Writing:

    If the Jacq-Photo is inside the Jacq-Locket:

        say "You can't see any such thing.";

    Otherwise:

        say "The handwriting is so small; you marvel at the clarity of the feminine script, which you are just able to make out. It reads: [paragraph break][italic type]To my Eliakim,[line break]Eburnean Alderman of[line break]the Variegated Court.[line break]I would follow thee[line break]to the depths of hell.[line break]          - Faythe[roman type][line break]".

When Jacq-Drenching ends:

    now the Jacq-Locket is worn by the player.

Every turn when the player is in WOO3:

    if Jacq-Drenching is happening:

        do nothing;

    otherwise:

        if a random chance of 1 in 2 succeeds, say "[one of][run paragraph on][or][italic type]A flurry of dead leaves goes skittering along the ground, swirling past you in the wind.[line break][roman type][or]For a moment, the wind dies down. Leaves on the ground come to rest.[or]The wind momentarily stirs up a pile of leaves.[or]Somewhere in the distance, you hear a mourning dove's plaintive song. From above, a leaf floats slowly toward the ground.[or]The wind picks up again for a moment, and a few leaves fall from above. One lands in your hair, which you remove and toss to the ground.[or]The wind comes from a new direction, moving through the branches with a haunting whistle and scratching the skeletons of dead leaves against one another.[cycling]".

The Jacq-Pond is scenery in WOO3. The printed name of the Jacq-Pond is "small pond". Understand "small" and "pond" and "sinister" and "stagnant" and "water" and "waters" and "black" as the Jacq-Pond.

Instead of examining the Jacq-Pond:

    say "[one of]Your reflection stares back at you, tree branches framing your face[or]Lanky water-gliding insects scootch across the surface, navigating between bits of scum and floating twigs[or]Withered leaves float aimlessly, like tiny forgotten boats[cycling].  You can discern nothing beneath the surface of the black water. The pond might be a foot deep, or a hundred feet deep. Or bottomless.";

    now the Jacq-Pond is Jacq-Examined.

Instead of searching the Jacq-Pond:

    say "You can discern nothing beneath the surface of the black water. The pond might be a foot deep, or a hundred feet deep. Or bottomless.";

    now the Jacq-Pond is Jacq-Examined.

Instead of entering the Jacq-Pond:

    try Jacq-Swimming.

Instead of eating or drinking the Jacq-Pond, say "In the interest of self-preservation, you think better of drinking from the pond."

Instead of touching the Jacq-Pond, say "There is something sinister about the water. You cannot bring yourself to touch it."

The Jacq-Reflection is scenery in WOO3. The printed name of the Jacq-Reflection is "reflection". The indefinite article of the Jacq-Reflection is "your".  Understand  "my reflection" and "reflection" and "face" and "my face" as the Jacq-Reflection. Instead of examining the Jacq-Reflection:

    if the player is Jacq-Calm:

        try examining the player;

    otherwise:

        say "You're terrified.".

Some Jacq-Insects are scenery in WOO3. The printed name of the Jacq-Insects is "lanky water-gliding insects". Understand "lanky" and "water-gliding" and "gliding" and "insects" and "bugs" as the Jacq-Insects. The description of the Jacq-Insects is "They scootch."

The Jacq-Scum is scenery in WOO3. The printed name of the Jacq-Scum is "bits of scum and twigs". Understand "bits" and "bits of scum" and "scum" and "floating" and "twigs" as the Jacq-Scum. The description of the Jacq-Scum is "Scummy, as stagnant pools of sinister water so often are."

Some Jacq-Branches are scenery in WOO3. The printed name of the Jacq-Branches is "branches". Understand "branch" and "branches" and "canopy" and "opening" and "opening in the canopy" and "tree" and "trees" as the Jacq-Branches. The description of the Jacq-Branches is "You gaze up. Were it not for the pond, you get the feeling these branches would weave themselves together to plunge these woods into near-total darkness."

The Jacq-Sky is scenery in WOO3. The printed name of the Jacq-Sky is "sky". Understand "sky" and "overhead" and "moody" and "grey" and "cloud" and "clouds" and "light" and "sun" and "sunlight" as the Jacq-Sky. The description of the Jacq-Sky is "The moody sky provides some light, but is occasionally darkened by grey clouds."

Some Jacq-Paths are scenery in WOO3. The printed name of the Jacq-Paths is "paths". Understand "path" and "paths" and "trail" and "trails" and "road" and "roads" and "woods" and "forest" as the Jacq-Paths. The description of the Jacq-Paths is "Paths slither away into the forest to the north, northeast, and southeast."

Some Jacq-Leaves are scenery in WOO3. The printed name of the Jacq-Leaves is "leaves". Understand "leaf" and "leaves" and "tiny" and "forgotten" and "boats" and "dead" as the Jacq-Leaves. The description of the Jacq-Leaves is "Leaves are everywhere. Some float, withered and aimless on the surface of the black water, the rest carpet the forest floor." Instead of taking or touching the Jacq-Leaves, try searching the Jacq-Leaves.

Instead of searching or pushing or pulling the Jacq-Leaves:

    if the Jacq-Rock is nowhere:

        now the Jacq-Rock is in WOO3;

        say "You feel no need to collect any leaves, but you poke at them with your foot, uncovering a flat stone.";

    otherwise:

        say "You find nothing of interest.".

Jacq-Swimming is an action applying to nothing.  Understand "swim" as Jacq-Swimming.

Instead of Jacq-Swimming when the location is WOO3:

    say "[if the player is Jacq-Calm]You consider the ominously inky water, and, considering yourself sane, decide against entering the pond voluntarily.[otherwise]There is absolutely no freakin' way you're going anywhere near that water."

Instead of examining the player when the location is WOO3 and the player is not Jacq-Calm:

    say "You're terrified."

Instead of examining up when the player is in WOO3, try examining the Jacq-Sky.

Instead of examining inside when the player is in WOO3, try examining the Jacq-Pond.

Instead of examining northeast when the player is in WOO3, say "The trees are too thick to go that direction."

Instead of examining north when the player is in WOO3, try examining the Jacq-Paths.

Instead of examining northwest when the player is in WOO3, say "The trees are too thick to go that direction."

Instead of examining west when the player is in WOO3, say "The trees are too thick to go that direction."

Instead of examining southwest when the player is in WOO3, try examining the Jacq-Paths.

Instead of examining south when the player is in WOO3, say "The trees are too thick to go that direction."

Instead of examining southeast when the player is in WOO3, try examining the Jacq-Paths.

Instead of examining east when the player is in WOO3, say "The trees are too thick to go that direction."

Instead of going up when the player is in WOO3, say "If only you could fly away from here..."

Instead of going northeast when the player is in WOO3, say "You don't feel much like bushwhacking."

Instead of going northwest when the player is in WOO3, say "You don't feel much like bushwhacking."

Instead of going west when the player is in WOO3, say "You don't feel much like bushwhacking."

Instead of going south when the player is in WOO3, say "You don't feel much like bushwhacking."

Instead of going east when the player is in WOO3, say "You don't feel much like bushwhacking."

Instead of going down when the player is in WOO3, say "Go where? Into the pond? You consider the ominously inky water, and, considering yourself sane, decide against entering the pond voluntarily."