Chapter 1 - Do Not Change Any Of This

Include Cragne Suite by Ryan Veeder.

[Don't mess with other people's rooms!]

Release along with the source text and a website.

MGR is a region.

MGR3 is a room in MGR. MGR3 is inside from MGR2.

Part - MGR3 Greenhouse

[Include Object Response Tests by Juhana Leinonen.]

Use unabbreviated object names.

[Delete the line below in the final game! I and Sam Kabo Ashwell have agreed to give the whetstone the same internal name in our code.]

The player carries a petter-whetstone. The petter-whetstone is handled.

[Delete the line below in the final game! I have not been able to get in touch with Harrison Gerard and agree on an internal name for the cardboard box.]

The harrison-cardboard-box is a closed openable container. Understand "cardboard" and "box" as the harrison-cardboard-box. The printed name of harrison-cardboard-box is "(preliminary printed name) cardboard box". The description of harrison-cardboard-box is "This is a preliminary dummy description of the output item of my room. Harrison Gerard will provide the final description. It is a vacuum component in a cardboard box, around the size of a jewelry box."

Petter-room is a kind of room. MGR3 is a petter-room.

Printed name of MGR3 is "Greenhouse (Petter Sjölund)".

To say ps--: say Unicode 8212.

Understand "whetstone/stone" as petter-whetstone. The printed name of petter-whetstone is "dark grey whetstone". The description of petter-whetstone is "A dark grey, smooth whetstone, great for sharpening any cutting implements."

Instead of touching or rubbing or squeezing the petter-whetstone when the location is a petter-room:

    say "It is damp and abrasive to the touch."

Commentary of a petter-room is "I participated in this project just to see if I had it in me to create a finished piece of interactive fiction. Well, I didn't drop out at least.[paragraph break]The main inspiration was some pictures I found of the ruins on Ross Island. I also looked at real-world greenhouses, such as the Royal Botanic Gardens in Kew, but very little of that actually ended up in the game. Neither the wonders of complex architecture or the joy of walking among a huge variety of plants are easy to capture in writing. At first, I wanted it to be more of a straight-faced mood piece, but there is something about classic parser interactive fiction and its puzzles that inevitably pushes toward silliness.[paragraph break]A big thanks to everyone involved, and a special thanks to my testers: Austin Auclair, Sanna Borell, Chandler Groover, Llew Mason, Andrew Schultz, Sean M. Shore, Lucian Smith, Matt Weiner, and Caleb Wilson."

Test MGR3 with "u / get machete / sharpen machete with whetstone / d / x statue / cut roots / scrape parrot with machete / u / climb tree / u / u / u / cut branches / x cage / cut wire / cut wire / cut wire / attack bird / open cage / x nest / get cardboard box".

Test MGR3-peaceful with "u / get machete / sharpen machete with whetstone / d / x statue / cut roots / scrape parrot with machete / u / climb tree / u / u / u / cut branches / x cage / open cage / x nest / get cardboard box".

Test MGR3-death with "u / get machete / sharpen machete with whetstone / climb tree / u / u / u / u / u / u / cut branches / x cage / open cage / x nest / get cardboard box".

Test MGR3-d2 with "u / get machete / sharpen machete with whetstone / d / x statue /  u / climb tree / u / u / u / u / u / u / cut branches / x cage / cut wire / cut wire / cut wire / wait".

Test MGR3-fall with "u / get machete / sharpen machete with whetstone / d / x statue / cut roots / scrape parrot with machete / u / climb tree / u / u / u / cut branches / x cage / cut wire / cut wire / cut wire".

Instead of going nowhere when the location is a petter-room:

    say "[Reply corresponding to a Room of location in the Table of Petter-Blocked Exit Replies].".

Chapter - Greenhouse Custom verbs

Understand "use [something]" or "use [something] on [something]" as a mistake ("You will have to say how.") when the location is a petter-room.

Understand "sing" or "shout" or "swear" as a mistake ("Your voice echoes strangely.") when the location is a petter-room.

Understand "xyzzy" as a mistake ("This is not Colossal Cave.") when the location is a petter-room.

Understand "petter är dum" as a mistake ("Du kan va dum.") when the location is a petter-room.

Instead of smelling when the location is a petter-room:

    say "Everything in this humid air smells of rot and mold." instead.

Understand "grab [something]" or "grab hold of [something]" or "grasp [something]" or "catch [something]" or "hold onto [something]" as taking when the location is a petter-room.

Understand "breathe [something]" as smelling when the location is a petter-room.

Understand "pull out [something]" as pulling when the location is a petter-room.

Definition: A room is on-petter-tree:

    if it is MGR3b:

        yes;

    if it is MGR3c:

        yes;

    if it is MGR3d:

        yes;

    if it is MGR3e:

        yes;

    no.

After dropping something when the location is on-petter-tree:

    if the noun is in location:

        move noun to MGR3;

        say "[The noun] [fall] through the branches to the ground [if location is not MGR3b]far [end if]below[if the petter-statue is in MGR3][one of], barely missing the parrot sculpture[or][stopping][end if]." instead.

Instead of tasting the player when the location is a petter-room:

    say "You can't help doing that."

Instead of eating the player when the location is a petter-room:

    say "You hope that you will never be that hungry."

Instead of touching or rubbing the player when the location is a petter-room:

    say "This is not the time or the place."

Instead of jumping when the location is a petter-room:

    if the location is MGR3:

        say "You try to reach the lower branches of the tree, but they are too high.";

    otherwise:

        if the location is MGR3d or the location is MGR3e:

            say "That would mean certain death up here.";

        otherwise:

            if the location is MGR3f:

                say "That is not an easy thing to do while falling.";

            otherwise:

                say "That would not be safe up here."

Understand "vomit" or "throw up" or "puke" or "barf" as a mistake ( "You'd rather not, if you can avoid it.") when the location is a petter-room.

Understand "die" as quitting the game when the location is a petter-room.

Understand "pee" as a mistake ("You don't feel the urge.") when the location is a petter-room.

Understand "tear apart/-- [something]" or "tear [something] apart" or "pull [something] apart" or "rip [something] apart" or "rip apart/-- [something]" as pulling when the location is a petter-room.

Section - Falling

To fall is a verb.

Understand "fall" as petter-falling when the location is a petter-room. Petter-falling is an action applying to nothing.

Carry out petter-falling:

    say "You'd rather avoid falling if at all possible."

Instead of petter-falling when the location is on-petter-tree:

    try jumping.

Section - Looking up

Instead of examining up when the location is on-petter-tree:

    if the location is MGR3e:

        try examining the petter-ceiling;

    otherwise:

        say "There seems to be some climbable branches above you."

Section - Looking down

Understand "examine the/-- ground/floor" as petter-down-looking when the location is a petter-room. Petter-down-looking is an action applying to nothing.

Carry out petter-down-looking:

    try examining down.

Instead of examining down when the location is on-petter-tree:

    if the location is MGR3b:

        say "You see the root-covered ground [if the petter-statue is in MGR3]and the parrot sculpture [end if]not too far below.";

    otherwise:

        say "[one of]Against your better judgment, you look down. Through the branches of the tree, you see the root-covered ground[if the petter-statue is in MGR3] and the parrot sculpture[end if] far below[if the petter-statue is in MGR3 and the petter-cage is in location], right below the birdcage[end if]. The vertigo almost makes you lose your grip[or]You'd rather not do that again[stopping]."

Instead of examining down when the location is MGR3:

    say "You see the root-covered ground."

Instead of examining down when the location is MGR3a:

    say "You see the root-covered ground below the walkway and the stairs leading up to it[if the petter-statue is in MGR3 and the petter-statue is not petter-clean]. The stone parrot almost seems to look straight at you[end if]."

Instead looking under the player when the location is a petter-room:

    try examining down.

Section - Looking out

Instead of examining outside when the location is a petter-room:

    try examining the petter-walls.

Section - Looking behind

Understand "look behind [something]" as petter-looking behind when the location is a petter-room. Petter-looking behind is an action applying to one thing.

Carry out petter-looking behind something fixed in place when the location is MGR3:

    say "You find nothing of note." instead.

Instead of looking under something fixed in place when the location is MGR3 and the noun is not petter-insubstantial:

    say "You cannot see what is under [the noun]."

Carry out petter-looking behind something:

    try looking under the noun instead.

Understand "walk around [something]" or "go around [something]" as petter-walking around when the location is a petter-room. Petter-walking around is an action applying to one thing.

Carry out petter-walking around something:

    say "That seems a bit pointless."

Understand "turn" or "turn around" or "look behind me/--" or "look behind my back" as vaguely petter-turning when the location is a petter-room. Vaguely petter-turning is an action applying to nothing.

Instead of turning the player when the location is a petter-room:

    try vaguely petter-turning.

Carry out vaguely petter-turning:

    say "[one of]You turn around slowly, ready for anything. There is nothing behind you[or]You turn around, but there is nothing[stopping]."

Section - Praying

Understand "pray" as vaguely petter-praying when the location is a petter-room. Vaguely petter-praying is an action applying to nothing.

Carry out vaguely petter-praying:

    say "Whatever gods may live here are deaf to your prayers."

Understand "pray to/-- [thing]" as petter-praying to when the location is a petter-room. Petter-praying to is an action applying to one visible thing.

To ignore is a verb.

Carry out petter-praying to something:

    say "[The noun] [ignore] your pathetic attempts at worship."

Section - Digging

Understand "dig ground/--" or "dig in the/-- ground" as vaguely petter-digging when the location is a petter-room. Vaguely petter-digging is an action applying to nothing.

Carry out vaguely petter-digging:

    say "There is nothing to dig in here."

Understand "dig in/-- [something]" as petter-digging when the location is a petter-room. Petter-digging is an action applying to one thing.

Carry out petter-digging:

    say "Try as you might, you can't dig [the noun]."

Section - Climbing

Understand "climb" or "climb higher" or "ascend" or "scale" as vaguely petter-climbing when the location is a petter-room. Vaguely petter-climbing is an action applying to nothing.

Instead of vaguely petter-climbing:

    try climbing the petter-tree.

Understand "climb [direction]" as going when the location is a petter-room.

Instead of climbing the petter-tree when the location is on-petter-tree:

    try going up.

Section - Throwing

Check throwing something at the player:

    say "[one of]That won't help things[or]You don't see what that'd accomplish[cycling]." instead.

Check throwing something at something:

    if the location is a petter-room:

        if the second noun is petter-insubstantial:

            say "[The noun] passes right through [the second noun][run paragraph on]";

        otherwise:

            say "[The noun] bounces off [the second noun]. There is a cloud of mold, but no visible damage to [the second noun][run paragraph on]";

        if the location is on-petter-tree:

            say ". [The noun] [fall] down to the ground below[run paragraph on]";

            move the noun to MGR3;

        otherwise:

            move the noun to location;

        say "." instead.

To hit is a verb.

Instead throwing something at the petter-dummy-sculpture when the petter-statue is in MGR3:

    if a random chance of 1 in 2 succeeds:

        say "[The noun] [hit] the sculpture, but bounces off without doing any damage.";

    otherwise:

        say "You miss the sculpture.";

    move the noun to MGR3.

Understand "throw down [something preferably held]" or "throw [something preferably held] down" as dropping when the location is a petter-room.

Section - Sharpening

Understand "sharpen [something preferably held]" or "hone [something preferably held]" as vaguely petter-sharpening when the location is a petter-room. Vaguely petter-sharpening is an action applying to one thing.

Carry out vaguely petter-sharpening the petter-machete:

    if the petter-whetstone is visible:

        say "(with [the petter-whetstone])[command clarification break]";

        try petter-sharpening the petter-machete with the petter-whetstone instead;

    otherwise:

        say "You have nothing to sharpen the machete with." instead.

Carry out vaguely petter-sharpening:

    say "[The noun] [don't] need sharpening."

Does the player mean vaguely petter-sharpening the petter-machete:

    it is very likely.

Understand "sharpen [something preferably held] with [something preferably held]" or "hone [something preferably held] with [something preferably held]" as petter-sharpening it with when the location is a petter-room. Petter-sharpening it with is an action applying to one thing and one carried thing.

Carry out petter-sharpening the petter-machete with the petter-whetstone:

    if the noun is petter-sharp:

        say "The rusty machete is not going to get any sharper." instead;

    otherwise:

        if the player does not carry the petter-machete:

            say "(first taking [the petter-machete])[command clarification break]";

            silently try taking the petter-machete;

        now the noun is petter-sharp;

        say "These days you prefer plastic pull-through sharpeners, but you vaguely remember something like this from your days in scouting. You spit on the whetstone and rub it at an angle against the edge of the machete. You repeat this until the edge feels reasonably sharp against your finger.[paragraph break]Then you suddenly remember a particularly annoying scout leader explaining to you, in his condescending way, how a machete isn't supposed to be sharp like a knife, and how it must be sharpened with a file and not a whetstone. Oh, well. Hopefully you didn't ruin it completely." instead.

Carry out petter-sharpening something with:

    say "[The noun] [don't] need sharpening."

Instead of putting the petter-whetstone on the petter-machete:

    try petter-sharpening the petter-machete with the petter-whetstone.

Instead of putting the petter-machete on the petter-whetstone:

    try petter-sharpening the petter-machete with the petter-whetstone.

Section - Cutting

Understand "cut [something] with [something preferably held]" or "attack [something] with [the petter-machete]" or "strike [something] with [the petter-machete]" as petter-cutting it with when the location is a petter-room. Petter-cutting it with is an action applying to two things.

Instead of cutting the petter-machete when the petter-machete is enclosed by location:

    say "You can't cut the machete with itself."

Instead of cutting something when the location is a petter-room and (the petter-machete is not enclosed by location or the noun is the petter-machete):

        say "You have nothing suitable to cut with."

Instead of petter-cutting something with the petter-machete when the petter-machete is petter-dull:

    say "The machete is too dull to cut anything[if petter-whetstone is not handled]. You wish you had something to sharpen it with[end if]."

Instead of cutting something when the player carries a petter-dull petter-machete and the location is a petter-room:

    say "The machete is too dull to cut anything[if petter-whetstone is not handled]. You wish you had something to sharpen it with[end if]."

Carry out petter-cutting something with:

    Try cutting the noun instead.

Instead of cutting the petter-branches when the player carries a petter-sharp petter-machete:

    say "[one of]You chop off some particularly annoying branches with the machete[or]There are too many branches to cut away them all[stopping]."

Instead of cutting or attacking the player when the player carries a petter-sharp petter-machete and the location is a petter-room:

    say "[one of]That won't help[or]You don't want to ruin the machete[or]Suicide is not the answer[or]The machete might not hold out[or]You don't see what that'd accomplish[cycling]."

Instead of attacking the player when the location is a petter-room:

    say "[one of]That won't help[or]Suicide is not the answer to this one[or]You don't see what that'd accomplish[cycling]."

Before cutting something when the location is a petter-room and petter-machete is enclosed by location:

    unless the player carries the petter-machete:

        say "(first taking the machete)[command clarification break]";

        silently try taking the petter-machete.

Instead of cutting the petter-hidden-cage when the player carries a petter-sharp petter-machete and the petter-statue is not petter-clean:

    now the petter-hidden-cage is nowhere;

    now the petter-cage is in location;

    say "You cut through the branches with the machete. As the leaves fall away, a human-size birdcage, suspended from the ceiling, is revealed."

Check cutting the petter-whetstone when the player carries the petter-machete:

    try petter-sharpening the petter-machete with the petter-whetstone instead;

Check cutting something when the location is a petter-room and the noun is not petter-insubstantial and the noun is not portable and the player carries a petter-sharp petter-machete:

        say "You strike [the noun]. A yellow cloud of spores billows up, dense enough to make you cough and your eyes run, but [the noun] seems unaffected." instead;

Understand "cut down [petter-cage]" as a mistake ("You will have to say exactly how.").

Section - Rubbing

Understand "rub [something] with [something preferably held]"  or "scrape [something] with [something preferably held]" as petter-rubbing it with when the location is a petter-room. Petter-rubbing it with is an action applying to two things.

Understand "scrape [something]" as rubbing when the location is a petter-room.

Understand "scrape [something] with my/-- nails/fingernails" as rubbing when the location is a petter-room.

Carry out petter-rubbing it with:

    say "You rub [the noun] with [the second noun]."

Understand "remove [petter-mold] from [something]" or "scrape [petter-mold] from/off [something]" as petter-mold-removing it from. Petter-mold-removing  it from is an action applying to two things.

Carry out petter-mold-removing something from something:

    try rubbing the petter-mold instead.

Carry out petter-mold-removing something from the petter-statue:

    try rubbing the petter-statue instead.

Understand "remove [petter-statue-roots] from [something]" or "pull [petter-statue-roots] from/off [something]" or "remove [petter-roots] from [something]" or "pull [petter-roots] from/off [something]" as petter-roots-removing it from. Petter-roots-removing  it from is an action applying to two things.

Carry out petter-roots-removing something from something:

    try taking the noun instead.

Section - Hugging

Understand "kiss [something]" or "hug [something]" or "embrace [something]" or "pet [something]" or "stroke [something]" as petter-hugging when the location is a petter-room. Petter-hugging is an action applying to one thing.

Carry out petter-hugging:

    say "You show affection to [the noun]."

Section - Riding

Understand "ride [something]" or "fly [something]" as petter-riding when the location is a petter-room. Petter-riding is an action applying to one thing.

Carry out petter-riding:

    say "That is not something you can ride."

Section - Flying

Understand "fly" or "flap my/-- arms/--" or "spread my/-- arms" as petter-flying when the location is a petter-room. Petter-flying is an action applying to nothing.

Carry out petter-flying:

    say "You flap your arms but to no avail."

Section - Screaming

Understand "scream" as a mistake ("You scream at the universe. An echo mocks you.") when the location is a petter-room.

Section - Custom defaults

Instead of taking a petter-backdrop which is not petter-insubstantial:

    say "[one of]You don't need any [noun][or]You don't need any [noun]. Besides, there is something sticky about [them] that makes you reluctant to touch [them][or]You'd rather not touch [regarding the noun][them] unless you have to[cycling]."

Instead of pulling a petter-backdrop:

    try taking the noun.

Check attacking something:

    if the location is a petter-room and the noun is not portable:

        say "You strike [the noun]. A yellow cloud of spores billows up, dense enough to make you cough and your eyes run. But [the noun] seems unaffected." instead.

Check tasting something:

    if the location is a petter-room and the noun is not portable:

        say "[The noun] [don't] look appetizing[one of]. Or indeed sanitary[or][stopping]." instead.

Check eating something:

    if the location is a petter-room and the noun is not portable:

        say "You are not hungry." instead.

Check touching something:

    if the location is a petter-room and the noun is not portable:

        say "Everything in here is slightly sticky to the touch." instead.

Section - Insubstantial things

A thing can be petter-insubstantial.

Instead of searching something petter-insubstantial:

    try examining the noun instead.

Instead of rubbing or taking something petter-insubstantial:

    say "Your hand passes right through [the noun]." instead.

Instead of doing something to something petter-insubstantial when the action requires a touchable noun (this is the block touching petter-insubstantial nouns rule):

    say "[The noun] [are] too insubstantial."

Instead of doing something when the second noun is petter-insubstantial and the action requires a touchable second noun (this is the block touching petter-insubstantial second nouns rule):

    say "[The second noun] [are] too insubstantial."

The block touching petter-insubstantial nouns rule is listed last in the Instead rules.

The block touching petter-insubstantial second nouns rule is listed last in the Instead rules.

Chapter - Greenhouse backdrops

A petter-backdrop is a kind of backdrop.

Instead of touching or rubbing or squeezing a petter-backdrop which is not petter-insubstantial:

    say "[The noun] [are] slightly sticky to the touch."

Section - The vines

The petter-vines are a plural-named petter-backdrop. Every petter-room contains the petter-vines. The printed name of the petter-vines is "vines". Understand "vine" and "vines" as the petter-vines. The description of petter-vines is "The vines are slippery and sticky and slimy."

Instead of climbing the petter-vines:

    say "The vines are too slippery to climb and too weak to support your weight."

Instead of swinging the petter-vines:

    say "You might as well try swinging on a slimy wet spaghetti."

Instead of touching or pulling or rubbing or squeezing the petter-vines:

    say "[description of petter-vines] You wipe the slime off your hand on your trousers."

Instead of cutting the petter-vines when the player carries a petter-sharp petter-machete:

    say "You don't need any vines."

Section - The mold

The petter-mold is a backdrop. Every petter-room contains the petter-mold. The printed name of the petter-mold is "mold". Understand "mold/lichen/moss/rot/fungus" and "fungal growth/bloom" as the petter-mold. The description of petter-mold is "Splotches of yellow mold can be found on almost everything in here. When touched, it releases a cloud of spores."

Instead of touching or taking or taking off or rubbing or squeezing the petter-mold:

    say "A puff of spores is released whenever you touch the yellow mold."

Instead of cutting the petter-mold when the player carries a petter-sharp petter-machete:

    say "[one of]As you scrape off some mold, it turns into a cloud of spores[or]There is too much mold to scrape it all off[stopping]."

Understand "scrape off/-- [petter-mold]" as a mistake ("There is too much to scrape it all off.").

Section - The ivy

The petter-ivy is a petter-backdrop. Every petter-room contains the petter-ivy. The printed name of the petter-ivy is "ivy". Understand "ivy" as the petter-ivy. The description of petter-ivy is "Like most things in here, the ivy is sticky to the touch and splotched with yellow mold."

Instead of cutting the petter-ivy when the player carries a petter-sharp petter-machete:

    say "You don't need any ivy."

Section - The spores

The petter-spores are a plural-named petter-insubstantial petter-backdrop. Every petter-room contains the petter-spores. The printed name of the petter-spores is "spores". Understand "spore/spores/puff/cloud/smoke/particles/yellow/dust/pollen" as the petter-spores. The description of petter-spores is "This dust seems to be released whenever you touch anything in here. Looking closer, you can make out tiny individual yellow particles."

Instead of taking or touching the petter-spores:

    say "The spores slip through your fingers."

Instead of smelling or tasting or eating the petter-spores:

    say "The spores in the air tickle in your nose and throat, and leave a metallic, blood-like taste in your mouth."

Section - The air

The petter-air is a petter-insubstantial petter-backdrop. Every petter-room contains the petter-air. The printed name of petter-air is "air". Understand "air/wind/atmosphere" as the petter-air. The description of petter-air is "The air is humid and smells of rot and mold."

Instead of listening to the petter-air:

    try listening to location.

Instead of touching the petter-air:

    try examining the petter-air.

Instead of tasting or eating or drinking the petter-air:

    try tasting the petter-spores.

Instead of cutting the petter-air when the player carries a petter-sharp petter-machete:

    try swinging the petter-machete instead.

Section - The sunlight

The petter-spots are a petter-insubstantial backdrop. The indefinite article of the petter-spots is "some". Every petter-room contains the petter-spots. The printed name of the petter-spots is "sunlight". Understand "spots/spot/cones/bright/light/sun/sunlight" as the petter-spots. The description of the petter-spots is "The sun [if the location is MGR3e or the location is MGR3d or the location is MGR3c]finds its way between the branches[otherwise]breaks through cracks in the root-covered walls[end if], creating cones of light through the dusty air, casting bright spots everywhere."

Instead of touching the petter-spots:

    say "Things are warmer where the light shines."

Instead of taking the petter-spots:

    say "Your hands pass right through the light."

Instead of tasting or eating or drinking the petter-spots:

    try tasting the petter-spores.

Understand "reflect [petter-spots]" or "mirror [petter-spots]" as a mistake ("The light is too weak to be usefully reflected with your equipment.").

Understand "reflect [petter-spots] at/into [petter-statue-eyes]" as a mistake ("Nice try, but the eyes contain no light sensors.").

Section - The parrot sculpture from above

[This catches attempts to refer to the parrot sculpture from up the tree. It is intended as a clue that the parrot can be destroyed by dropping something on it from high up.]

The petter-dummy-sculpture is a backdrop. The petter-dummy-sculpture is in MGR3a, MGR3b, MGR3c, MGR3d, and MGR3e. The printed name of the petter-dummy-sculpture is "parrot sculpture below". Understand "parrot/-- sculpture/statue" and "stone parrot" as the petter-dummy-sculpture.

Instead of examining the petter-dummy-sculpture when the petter-statue is in MGR3:

        say "You can't see much from here."

Instead of doing something when the petter-dummy-sculpture is the noun or the petter-dummy-sculpture is the second noun:

    if the petter-statue is in MGR3:

        say "The sculpture is too far away.";

    otherwise:

        say "The parrot sculpture is gone."

Does the player mean doing something when the petter-dummy-sculpture is the noun or the petter-dummy-sculpture is the second noun:

    it is very unlikely.

Does the player mean throwing something at the petter-dummy-sculpture:

    it is very likely.

Section - The ceiling

The petter-ceiling is a backdrop. Every petter-room contains the petter-ceiling. The printed name of the petter-ceiling is "ceiling". Understand "ceiling/sky/dome/crown" or "crown of leaves" as the petter-ceiling. The description of petter-ceiling is "[if location is MGR3e]Through the dirty glass ceiling you see the sky outside. It is a bright, sunny day and the sky is blue with little puffy white clouds[otherwise]The ceiling of the greenhouse dome is hidden behind the dark green crown of the tree[end if]."

Understand "puffy/white/clouds" as the petter-ceiling when the location is MGR3e.

Instead of taking the petter-ceiling:

    say "Even if you could reach it, it would hardly be portable."

Instead of throwing something at the petter-ceiling when the location is not MGR3e:

    say "The ceiling is too high to hit with [the noun]."

Instead of petter-looking behind or searching the petter-ceiling when the location is a petter-room:

    try examining the petter-ceiling.

Instead of doing something to the petter-ceiling when the action requires a touchable noun:

    say "It is [if the location is MGR3e]still [end if]too far away."

Instead of attacking or cutting the petter-ceiling:

    say "Even if you were strong enough to break the glass, you would probably cut yourself badly on the shards."

Section - The walls

The petter-walls is a backdrop. Every petter-room contains the petter-walls. The printed name of the petter-walls is "wall". Understand "greenhouse/-- walls/wall/window/windows/glass/curve" as the petter-walls. The description of the petter-walls is "[if the location is MGR3 or the location is MGR3a or the location is MGR3b]Down here, the walls are covered by a thick mesh of roots[otherwise]Through the dirty, uneven glass, you can see [the MGR2][end if]."

Instead of searching or petter-looking behind the petter-walls:

    try examining the petter-walls.

Instead of attacking or cutting the petter-walls:

    say "Even if you managed to break the glass, you would probably cut yourself badly on the shards."

Section - The tree

The petter-tree is a backdrop. Every petter-room contains the petter-tree. The printed name of the petter-tree is "tree". Understand "tree/trunk/bark/African/fern/pine/stripped" as the petter-tree.

Instead of taking the petter-tree:

    say "That is not exactly portable."

Instead of cutting the petter-tree when the player carries a petter-sharp petter-machete:

    say "[one of]You strike the tree hard. A yellow cloud of spores billows up, dense enough to make you cough and your eyes run, but the tree itself seems unaffected[or]You'd rather not try that again[stopping]."

Instead of petter-looking behind the petter-tree:

    say "You discover nothing new."

Instead of looking under the petter-tree:

    try examining down.

Section - The branches

The petter-branches are a plural-named petter-backdrop. Every petter-room contains the petter-branches. The printed name of the petter-branches is "branches". Understand "branch/branches/twig/twigs/thicket" as the petter-branches.

Instead of climbing the petter-branches:

    try climbing the petter-tree.

Instead of pulling or attacking the petter-branches:

    if the location is:

        -- MGR3: say "You can't reach the branches.";

        -- MGR3b: say "The branches here are to thick to break or move.";

        -- otherwise: say "You only hurt your hands on the pointy twigs."

Section - The roots

The petter-roots is a plural-named backdrop. Every petter-room contains the petter-roots. The printed name of the petter-roots is "roots". Understand "roots/root/rootlet/rootlets/aerial/mesh/strangler/fig" as the petter-roots.

Instead of taking or pulling or taking off the petter-roots:

    say "The roots are tougher than they look and hard to get a hold on."

Instead of cutting the petter-roots when the player carries a petter-sharp petter-machete:

    say "[one of]You cut away some roots. A viscous milky fluid is excreted from the cuts[or]There are far too many roots to remove them all[stopping]."

Instead of eating the petter-roots:

    try eating the petter-fruit.

Section - The fluid

The petter-fluid is a petter-backdrop. Every petter-room contains the petter-fluid. The printed name of the petter-fluid is "milky fluid". Understand "fluid/viscous/cut/quick-drying/latex/milky" as the petter-fluid. The description of the petter-fluid is "A quick-drying milky fluid seems to heal any damage done to the roots."

Instead of attacking the petter-fluid:

    say "That seems pointless."

Instead of drinking the petter-fluid:

    say "You'd rather not."

Section - The leaves

The petter-leaves are a plural-named petter-backdrop. Every petter-room contains the petter-leaves. The printed name of the petter-leaves is "leaves". Understand "leaves/leaf/growth" as the petter-leaves.

Instead of cutting the petter-leaves when the player carries a petter-sharp petter-machete:

    say "You don't need any leaves."

Section - The bird noise

The petter-ghost is a petter-insubstantial backdrop. The petter-ghost can be petter-quiet or petter-noisy. The petter-ghost is petter-quiet. Every petter-room contains the petter-ghost.

The printed name of the petter-ghost is "whatever you heard before". The petter-ghost is proper-named.

Understand "noise/animal/flapping/sound" as the petter-ghost when the location is not MGR3f.

Understand "wings/bird/parrot" as the petter-ghost when the location is not MGR3 and the location is not MGR3f.

Petter-invisible-bird is a scene. Petter-invisible-bird begins when the location is MGR3. Petter-invisible-bird ends in jumpscare when Petter-first-fall begins. Petter-invisible-bird ends in revelation when petter-cage is in location.

Instead of listening to a petter-room:

    try listening to the petter-ghost.

Instead of waiting when the location is a petter-room:

    say "You wait. [run paragraph on]";

    if petter-invisible-bird is happening:

        try listening to the petter-ghost;

    otherwise:

        say line break.

Instead of throwing something at the petter-ghost:

    if the petter-ghost is petter-noisy:

        say "You have no idea where that went, if it indeed was something.";

    otherwise:

        say "I don't know what you are taking about."

Instead of listening to the petter-ghost:

    if the petter-ghost is petter-noisy:

        say "[one of]Whatever you heard before is quiet now[or]You try to be very still. No sound[or]You listen intently, holding your breath. Only the sound of your heart beating[or]Whatever you heard is quiet now[stopping].";

        now the petter-ghost is petter-quiet;

    otherwise:

        say "[one of]The leaves rustle slightly, and there is a quiet buzz of insects[or]A slight breeze blows through the humid air[cycling].";

Instead of doing something when the noun is the petter-ghost or the second noun is the petter-ghost:

    if the petter-ghost is petter-noisy:

        try listening to the petter-ghost;

    otherwise:

        say "You can see no such thing."

Instead of taking the petter-ghost:

    try eating the petter-ghost.

Instead of touching the petter-ghost:

    try eating the petter-ghost.

Section - Wounds

Petter-wound is a kind of value. The petter-wounds are petter-unscratched, petter-scratched, petter-cut-up, petter-bruised and petter-battered.

Yourself has a petter-wound called petter-condition. The petter-condition of yourself is petter-unscratched.

Instead of examining the player when the location is a petter-room:

    try examining the petter-wound-thing.

Instead of taking the petter-wound-thing:

    say "Your wounds are already yours to carry."

Instead of touching or rubbing or squeezing the petter-wound-thing:

    if the petter-condition of the player is:

        -- petter-unscratched: say "You have no physical wounds.";

        -- petter-scratched: say "Your scratches sting a little.";

        -- otherwise: say "Your wounds might get infected if you keep touching them.".

The petter-wound-thing is a plural-named backdrop. Every petter-room contains the petter-wound-thing. The printed name of the petter-wound-thing is "wounds". Understand "wounds/wound/scratch/scratches/bruises/bruise/cuts/leg/blood/bleeding/bump" as the petter-wound-thing. The description of the petter-wound-thing is "[Description corresponding to a Petter-wound-kind of petter-condition of the player in the Table of Petter-Wound Descriptions].".

Chapter - Greenhouse backdrops, ground and walkway only

The petter-pots are a plural-named petter-backdrop. The petter-pots are in MGR3 and MGR3a. The printed name of the petter-pots is "pots". Understand "pots/pot/soil/plants" as the petter-pots. The description of petter-pots is "There are several large plant pots visible beneath the roots, though many of them are broken beyond recognition. Inside there is dry soil and the remains of dead exotic plants."

The petter-walkway is a petter-backdrop. The petter-walkway is in MGR3 and MGR3a, and MGR3b. The printed name of the petter-walkway is "mesh walkway". Understand "walkway/mesh/platform" as the petter-walkway. The description of the petter-walkway is "The root-covered walkway circles the greenhouse, but looks broken and bent in several places[if the location is MGR3]. A staircase leads up to it from here[end if][if the location is MGR3a]. Tree branches have grown into the metal mesh, almost forming a natural bridge to the trunk of the tree[end if]."

Does the player mean doing something to the petter-walkway:

    it is very likely.

The petter-sculptures are plural-named scenery in MGR3a. The printed name of the petter-sculptures is "sculptures". Understand "sculptures/ornaments" as the petter-sculptures. The description of the petter-sculptures is "Scattered across the walkway are broken pieces of garden ornaments, strangled by the roots."

Instead of taking the petter-sculptures:

    say "You don't need any broken garden ornaments."

The petter-rubble is a petter-backdrop. The petter-rubble is in MGR3 and MGR3a. The printed name of the petter-rubble is "rubble". Understand "rubble/remains/twisted/metal/weeds" as the petter-rubble. The description of petter-rubble is "Under the roots there are bits and pieces of broken pots, soil, dry leaves and dead plants[if the location is MGR3a], twisted cast-iron remains of the walkway and railing[end if] interspersed with still growing weeds."

Instead of petter-digging the petter-rubble:

    try searching the petter-rubble.

Section - Staircase

The petter-staircase is a backdrop. It is in MGR3 and MGR3a. The printed name of the petter-staircase is "spiral staircase". Understand "spiral/staircase/stairs/steps/handrail/rail/railing" as the petter-staircase. The description of the petter-staircase is "When you get closer, the original iron staircase is visible through the coiled roots. It leads [if the location is MGR3]up to a root-covered mesh walkway that circles the greenhouse[otherwise]down to the greenhouse floor[end if]."

Instead of cutting the petter-staircase when the player carries a petter-sharp petter-machete:

    say "[one of]You cut off a couple of roots from the staircase, but it doesn't make much difference[or]It would take far too much time to cut away all the roots[stopping]."

Instead of climbing or entering or taking the petter-staircase:

    if the location is MGR3:

        try going up;

    otherwise:

        try going down.

Instead of touching or rubbing or squeezing the petter-staircase:

    say "The roots covering the staircase are slightly slippery."

Instead of touching or rubbing or squeezing the petter-broken-staircase:

    say "The broken staircase seems to be covered in a fine dust."

Instead of climbing or entering or taking the petter-broken-staircase:

    try going up.

The petter-broken-staircase is scenery. The printed name of the petter-broken-staircase is "broken staircase". Understand "spiral/staircase/stairs/steps/handrail/broken" as the petter-broken-staircase. The description of the petter-broken-staircase is "The staircase and a large section of the walkway above have collapsed into a large heap of roots and broken metal. There is no way up anymore."

Chapter - Non-existent scenery

[Petter-non-existent is a special kind of scenery that is meant to catch attempts to refer to things which are no longer there, so that any attempt to do something with it will give a response like "The parrots you saw before are gone", i.e. the description of the thing.]

A petter-non-existent is a kind of thing. A petter-non-existent is petter-insubstantial scenery.

Instead of throwing something at a petter-non-existent:

    say "[description of the second noun][line break]"

Instead of doing something when the noun is a petter-non-existent:

    say "[description of the noun][line break]"

Instead of doing something when the second noun is a petter-non-existent:

    say "[description of the second noun][line break]"

Chapter - Room-adapted descriptions

Carry out examining the petter-tree:

    if the location is:

        -- MGR3: say "The moldy strangler fig roots cover the enormous trunk at the center of the greenhouse, seeming to melt into one another, making it impossible to tell what the host tree used to looked like. There are no branches within reach.";

        -- MGR3a: say "From here you can see the moldy strangler fig roots growing down the host tree. A thick root-covered branch has grown into the metal mesh.";

        -- MGR3b: say "The smooth, grey strangler fig roots cover the original host tree completely. Thick root-covered branches lead up and west from here.";

        -- MGR3c: say "Here, gaps between the strangler fig roots reveal the original host tree, which looks like an African fern pine. The original bark has been stripped bare in a wide circle around the trunk by the strangler fig, effectively killing the host. Thick root-covered branches lead up and down from here.";

        -- MGR3d: say "Up here where there is more sunlight, the strangler figs bear green leaves and flowers among the dead branches of the African fern pine.";

        -- MGR3e: say "This is the top of the tree, the green leaves and flowers of the strangler fig filling the upper part of the greenhouse along with the dead, pointy twigs of its victim. There is nowhere to go except down.";

        -- MGR3f: say "The tree watches in solemn silence as you fall to your doom";

        -- otherwise: say "You are not in the MGR3 region.";

    the rule succeeds.

Carry out examining the petter-roots:

    if the location is:

        -- MGR3: say "[one of]It looks like a species of strangler fig, which has germinated in a crevice of the host tree, growing its roots downward and upward, enveloping everything in its way[or]The roots seem to have everything in their grasp[stopping].";

        -- MGR3a: say "The roots seem to have everything in their grasp here.";

        -- MGR3b: say "The smooth, grey strangler fig roots cover the host tree completely, growing upward and downward from here.";

        -- MGR3c: say "Through the hole you see the strangler fig growing like a spinal cord through the hollow trunk of the dead host tree.";

        -- MGR3d: say "Up here where there is more sunlight, the strangler figs bear green leaves and flowers and fruit among the dead branches of the African fern pine.";

        -- MGR3e: say "This is the top of the tree, the green leaves and flowers of the strangler fig filling the upper part of the greenhouse along with the dead, pointy twigs of its victim. There is nowhere to go except down.";

        -- MGR3f: say "The strangler fig roots look on in silence as you fall to your death.";

        -- otherwise: say "You are not in the MGR3 region.";

    the rule succeeds.

Carry out examining the petter-branches:

    if the location is:

        -- MGR3: say "The root-covered branches of the tree are too high to reach from here, but they seem to fill the entire upper part of the greenhouse.";

        -- MGR3a: say "A thick, root-covered branch has grown into the metal mesh, almost forming a natural bridge to the trunk of the tree.";

        -- MGR3b: say "Here the root-covered branches are thick and sturdy, growing almost horizontally. To the west, it is possible to climb to the walkway circling the greenhouse.";

        -- MGR3c: say "The branches here are murky and hollow, but the roots growing around them make them strong enough to climb.";

        -- MGR3d: say "The dead branches are thin, sharp and numerous, like a thicket.";

        -- MGR3e: say "[if the petter-hidden-cage is in location]It looks like something metallic is hanging from the ceiling further out, but the branches grow to dense to see it clearly[otherwise]The dead branches are thin, sharp, and numerous, like a thicket[end if].";

        -- MGR3f: say "A blur of branches whip by.";

        -- otherwise: say "You are not in the MGR3 region.";

    the rule succeeds.

Carry out examining the petter-leaves:

    if the location is:

        -- MGR3: say "There are many brown, decomposing leaves on the ground here.";

        -- MGR3a: say "There are many brown, decomposing leaves on the walkway, and a couple of living green ones growing from the roots.";

        -- MGR3b: say "There are a few long, oval leaves with little spots of yellow fungus growing from the roots here.";

        -- MGR3c: say "The leaves are long and oval. They seem to be more numerous up here, with less fungus on them.";

        -- MGR3d: say "Up here the green, sticky leaves grow huge and are difficult to move between.";

        -- MGR3e: say "The green leaves stick to the glass ceiling of the greenhouse.";

        -- MGR3f: say "The leaves rush by like green brushstrokes.";

        -- otherwise: say "You are not in the MGR3 region.";

    the rule succeeds.

Table of Petter-Blocked Exit Replies

Room (a room)    Reply (some text)

MGR3    "If there ever were any exits other than the overgrown archway through which you entered, they are covered by impenetrable roots[if petter-staircase is in MGR3], but there is a spiral staircase leading up to a walkway[otherwise]. The staircase leading up has collapsed[end if]"

MGR3a    "The walkway is broken and impassable, but there is large branch to the east. Stairs lead down"

MGR3b    "Apart from the branch leading west to the walkway, there is nowhere to go here unless you want to climb higher"

MGR3c    "The branches here are weak and you'd prefer to stay close to the trunk. It might be possible to climb up or down, though"

MGR3d    "The branches hinder your movement here. It might be possible to climb up or down, though"

MGR3e    "You'd prefer to move around as little as possible up here. The only reasonably safe way is down"

MGR3f    "There is only going down from here"

Table of Petter-Wound Descriptions

Petter-wound-kind (a petter-wound)    Description (some text)

petter-unscratched    "The sickly yellowish-green light in here glistens in the sweat on your skin. At least you seem to be relatively unscathed"

petter-scratched    "There are scratches from the branches wherever your skin is bare"

petter-cut-up    "Your skin is badly scratched and there are a couple of minor bleeding wounds"

petter-bruised    "You are scratched and bleeding. You have minor bruises all over, and a huge aching one your leg"

petter-battered    "You are bruised and bleeding all over,  with a huge bump on your head, but nothing serious. Your shoulder and leg hurt a little and you walk with a slight limp"

Chapter - Greenhouse bottom level (MGR3)

Description of MGR3 is "Nothing should be growing here anymore [ps--] the heating and irrigation have been off for years [ps--] but roots seem to have covered everything.[paragraph break]The walls curve inward, forming a huge dome, with a mesh of roots covering it from the floor up to about halfway to the ceiling. Sunlight still breaks through in places, throwing a pattern of bright spots across the room. The roots grow from an enormous tropical tree at the center of the greenhouse, towering all the way up to the ceiling, which it hides behind a thick crown of leaves.[paragraph break][if petter-staircase is in location]A spiral staircase, seemingly woven of roots, leads to a circular mesh walkway higher up along the wall[otherwise]The staircase to the upper level has collapsed along with much of the platform above. There are shards of glass everywhere and a cold wind blows from the broken ceiling[end if]."

Instead of climbing the petter-tree when the location is MGR3:

    say "You cannot reach any branches from here. The roots leading up are too flimsy to support your weight and the moldy trunk is too slippery[if petter-staircase is in location]. But there is a staircase leading up to a walkway circling the tree[end if]."

Instead of going to MGR3a from MGR3 when the petter-broken-staircase is in location:

    say "The spiral staircase has collapsed."

Instead of examining up when the location is MGR3:

    say "The huge tree towers above you,  growing all the way up to the hidden ceiling. It seems to have no branches reachable from here."

Before going to MGR3a from MGR3 when the petter-staircase is in location:

    say "[one of]What is visible of the iron staircase through the root mesh looks bent and badly corroded. The roots are slippery to the touch as you grab hold of the handrail and start climbing. After only a couple of steps the entire structure [ps––] including the platform above [ps––] lurches, and for a moment you think it is all going to come apart on top of you[or]You climb the unstable staircase[stopping]."

Before going to MGR3 from MGR3a:

    say "You climb down the unstable staircase."

The petter-archway is scenery in MGR3. The printed name of petter-archway is "overgrown archway". Understand "overgrown/archway/door/exit" as the petter-archway. The description of the petter-archway is "This overgrown archway is the way you came in, and it seems to be the only way out of here."

Instead of vaguely petter-digging when the location is MGR3:

    say "The thick roots covering the ground makes digging impossible here."

Petter-plaster is scenery. The printed name of petter-plaster is "plaster". Understand "plaster/bone/powder/white" as petter-plaster. The description of petter-plaster is "There is a white powder where the plaster bone shattered."

Instead of taking the petter-plaster:

    say "You don't need any plaster."

Chapter - Stone parrot

The petter-statue is fixed in place in MGR3. The printed name of the petter-statue is "sculpture". The petter-statue can be petter-examined or petter-unexamined. Understand "statue/sculpture/broken/parrot/beak/garden/ornament/bird/parrot" or "white stone" as the petter-statue. The initial appearance of the petter-statue is "[if the petter-statue is petter-unexamined]Something vaguely sculpture-like[otherwise]The parrot sculpture[end if] protrudes from the roots near the exit."

The petter-statue-roots are plural-named scenery. Understand "roots/root/web/fine" as the petter-statue-roots. The printed name of the petter-statue-roots is "roots covering the sculpture". The description of petter-statue-roots is "A fine web of roots covers the sculpture, like cracks in old china."

Does the player mean doing something to the petter-statue-roots:

    it is very likely.

Instead of entering or climbing the petter-statue:

    say "Every attempt to stand on the narrow, slippery surface of the sculpture ends with you losing your balance and falling off."

Instead of entering or climbing the petter-statue-roots:

    say "Every attempt to stand on the narrow, slippery surface of the sculpture ends with you losing your balance and falling off."

Instead of taking or pulling or taking off or turning or pushing the petter-statue-roots:

    say "[one of]You succeed in tearing off some of the thinner rootlets on the statue, but the roots[or]The roots on the statue[stopping] are tougher than they look and hard to get a grip on."

Instead of taking or pulling or taking off or turning or pushing the petter-statue:

    say "The sculpture is made of solid stone and [if the petter-statue-roots are part of the petter-statue]roots hold it in a firm grip[otherwise]far too heavy to move[end if]."

Instead of opening or closing the petter-statue:

    say "The sculpture has no moving parts. Its mouth is less than an inch deep."

Instead of examining the petter-statue:

    now the petter-statue is petter-examined;

    if the petter-statue is petter-clean:

        say "The parrot looks almost at peace since you cleaned it. Now you imagine that its green eyes are looking kindly at you and that the mouth is singing[run paragraph on]";

    otherwise:

        if the petter-statue is petter-rooty:

            now the petter-statue-wings are part of the petter-statue;

            now the petter-statue-eyes are part of the petter-statue;

            now the petter-statue-roots are part of the petter-statue;

            say "This looks like some kind of garden ornament in the shape of a parrot. Through a web of roots and a yellow lichen that covers the white stone, two intensely red eyes made of some translucent material glare at you. The beak is open as if uttering a squawk. A pair of wings has apparently been broken off[run paragraph on]";

        otherwise:

            say "Through a yellow lichen that covers the white stone, two intensely red eyes made of some translucent material glare at you. The beak is open as if uttering a squawk. But the parrot actually looks less hostile since you removed the roots. Still not actually friendly, though[run paragraph on]";

    say "."

Instead of entering the petter-statue:

    say "The entire statue is only about half your height, and its mouth is only an inch deep."

Instead of attacking or cutting the petter-statue:

    if the petter-statue is petter-clean:

        say "You don't want to ruin your hard work to clean up the sculpture.";

    otherwise:

        say "[one of]You strike down hard on the sculpture. A yellow cloud of spores billows up, dense enough to make you cough and your eyes run. But the sculpture itself seems unaffected[or]You'd rather not try that again[stopping]."

Instead of vaguely petter-praying when the petter-statue is in location and the petter-statue is petter-examined:

    try petter-praying to the petter-statue.

The petter-statue-wings are plural-named scenery. Understand "wings/wing/bits/broken" or "pair of" as the petter-statue-wings. The printed name of the petter-statue-wings is "broken remains". The description of petter-statue-wings is "The wings that once adorned the parrot sculpture are thoroughly broken to bits, whether by roots and damp or by deliberate vandalism is hard to tell."

Instead of taking the petter-statue-wings:

    say "The wings are utterly broken. You certainly don't want to fill your pockets with gravel."

The petter-statue-eyes are plural-named scenery. Understand "eyes/eye" or "translucent material/stone" as the petter-statue-eyes. The printed name of the petter-statue-eyes is "eyes".

Understand "red" or "red material/stone" as the petter-statue-eyes when the petter-statue is not petter-clean.

Understand "green" or "green material/stone" as the petter-statue-eyes when petter-statue is petter-clean.

Instead of examining the petter-statue-eyes:

    if the petter-statue is petter-rooty:

        say "The red stare is tortured and hostile[run paragraph on]";

    otherwise:

        if the petter-statue is petter-fungy:

            say "The red eyes are a little less hostile now, if not entirely pleased[run paragraph on]";

        otherwise:

            say "The green eyes look at you kindly[run paragraph on]";

    say "."

Instead of taking or taking off or pulling the petter-statue-eyes:

    say "The eyes are firmly set in the statue. You can't get them out."

Instead of pushing the petter-statue-eyes:

    say "The eyes do not move when you push them."

Understand "pry [petter-statue-eyes]" or "pry out [petter-statue-eyes]" as a mistake ("The eyes are firmly set in the statue. You can't get them out.").

The petter-statue-crack is scenery. Understand "crack/break" as the petter-statue-crack. The printed name of the petter-statue-crack is "crack". The description of petter-statue-crack is "It is a clean break from head to toe."

Instead of petter-praying to the petter-statue:

    if the petter-statue is petter-rooty:

        say "[one of]You are filled with an incomprehensible dread[or]Your dread becomes more intense[stopping][run paragraph on]";

    otherwise:

        if the petter-statue is petter-fungy:

            say "You get a sense of demanding displeasure, and a desire for cleansing[run paragraph on]";

        otherwise:

            say "[one of]You are overcome with an inner sense of calm[or]The parrot doesn't answer[stopping][run paragraph on]";

    say "."

Instead of petter-hugging the petter-statue:

    say "There is a slight trembling in the sculpture at your display of affection. Or did you just imagine it?[run paragraph on]";

    if the petter-statue is not petter-clean:

        say " Somehow you feel a desire for cleansing emanating from the parrot.[run paragraph on]";

    say paragraph break.

Section - Cleaning the parrot

The petter-statue can be petter-rooty, petter-fungy or petter-clean. The petter-statue is petter-rooty.

Instead of inserting something into the petter-statue:

    say "There is nowhere on the sculpture to insert [the noun]."

Instead of inserting a petter-sharp petter-machete into the petter-statue-roots:

    try cutting the petter-statue-roots.

Instead of cutting the petter-statue-roots when the player carries a petter-sharp petter-machete:

    now the petter-statue-roots are nowhere;

    now the petter-statue is petter-fungy;

    say "After cutting of a couple of roots from the statue, you realize that you can insert the machete blade under the weave of roots and sawing through it from inside, as if cutting up a fish. A milky fluid oozes from the cuts, as if trying to heal them. When you toss the roots aside, you get the strange impression that the statue is relieved."

Instead of rubbing the petter-statue when the petter-statue is petter-rooty:

    say "You try to scrape off some of the fungus and lichen growing on the sculpture, but the stubborn roots keep getting in the way. Perhaps you should deal with them first.";

Instead of rubbing the petter-statue when the petter-statue is petter-fungy:

    say "[one of]You scrape off some of the fungus and lichen growing on the sculpture with your nails, creating clouds of spores that sting in your eyes, but you really need some kind of tool if you are going to get it all off[or]There is too much fungus and dirt on the sculpture to scrape it off with your nails[stopping]."

Instead of rubbing or touching or squeezing the petter-statue when the petter-statue is petter-clean:

    say "You stroke the clean stone of the parrot sculpture."

Instead of tasting or eating the petter-statue:

    say "You plant your lips on the stone parrot. There is a slight trembling at this display of affection. Or did you imagine it?"

Instead of touching or squeezing the petter-statue:

    say "There is a slight trembling through the sculpture at your touch. Or was it only your imagination?"

Instead of smelling the petter-statue:

    say "There is the faintest smell of bird."

Instead of vaguely petter-sharpening the petter-statue:

    if the petter-whetstone is visible:

        try petter-sharpening the petter-statue with the petter-whetstone;

    otherwise:

        if the petter-statue is petter-clean:

            say "[The noun] doesn't seem to need sharpening.";

        otherwise:

            say "[The noun] looks like it could do with some sharpening. Unfortunately you lack the right tool."

Instead of petter-sharpening the petter-statue with the petter-whetstone:

    unless the petter-statue is petter-clean:

        say "[The noun] could do with some sharpening. [run paragraph on]";

    try petter-rubbing the petter-statue with the petter-whetstone.

Instead of putting the petter-whetstone on the petter-statue:

    try petter-rubbing the petter-statue with the petter-whetstone.

Instead of petter-rubbing the petter-statue with the petter-whetstone:

    if the petter-statue is petter-rooty:

        say "You try to clean off some of the fungus and lichen growing on the sculpture, but the stubborn roots keep getting in the way. Perhaps you should deal with them first.";

    otherwise:

        if petter-statue is petter-fungy:

            say "You do your best with the tools at hand, and clean off most of the fungus, lichen and bird droppings, occasionally stopping to cough and wipe the spores from your eyes. After that, you don't want to stop, so you sharpen its beak and polish the statue all over. [italic type]Much[roman type] nicer this way.[paragraph break]And to your astonishment, its eyes now look green.";

            now the petter-statue is petter-clean;

        otherwise:

            say "The parrot sculpture looks pretty good as it is[one of]. You don't really see how it could be improved[or][stopping]."

Instead of petter-rubbing the petter-statue with the petter-sharp petter-machete:

    if the petter-statue is petter-rooty:

        say "You try to scrape off some of the fungus and lichen growing on the parrot, but the stubborn roots keep getting in the way. Perhaps you should deal with them first.";

    otherwise:

        if the petter-statue is petter-fungy:

            say "You do the best you can with the tools at hand and clean off the fungus and lichen and bird droppings, occasionally stopping to cough and wipe the spores from your eyes. After that, you don't want to stop, so you sharpen its beak and improve some of the finer lines on its feathers. [italic type]Much[roman type] nicer this way.[paragraph break]And to your astonishment, its eyes now look green.";

            now the petter-statue is petter-clean;

        otherwise:

            say "The parrot sculpture looks pretty good as it is[one of]. You don't really see how it could be improved[or][stopping]."

Instead of petter-rubbing the petter-statue with the petter-dull petter-machete:

    say "Rubbing the sculpture with the rusty, dull machete would only make things worse."

Chapter - Greenhouse mesh walkway (MGR3a)

MGR3a is a petter-room in MGR.

MGR3a is above MGR3. The printed name of MGR3a is "Greenhouse (Petter Sjölund) (on the mesh walkway)". The description of MGR3a is "You're up the mesh walkway circling the greenhouse partway up the wall. The roots have grown into the iron mesh and railing as well, twisting it and breaking it apart. Between the roots and sharp metal edges there is hardly room to stand, but the branches stretching finger-like from the lower part of tree look sturdy and climbable.[paragraph break]The spiral staircase leads back down."

Instead of going up when the location is MGR3a:

    if MGR3b is not visited:

        try examining up;

    otherwise:

        try going east.

Instead of examining up when the location is MGR3a:

    say "There seems to have once been a second walkway like this higher up the wall, but the growth of the tree and the roots has destroyed both this and the stairs leading up to it. There are a couple of branches that look sturdy enough to climb from here, though."

Instead of climbing the petter-tree when the location is MGR3a:

    try going east.

Understand "bridge" as the petter-branches when the location is MGR3a.

Before going to MGR3b from MGR3a:

    say "You hold onto one of the more sturdy-looking branches and carefully move toward the tree at the center of the room.";

    continue the action.

Section - Machete

The petter-machete is in MGR3a. The petter-machete can be petter-sharp or petter-dull. The petter-machete is petter-dull.

Instead of tasting the petter-machete when the location is a petter-room:

    say "It has the metallic taste of rust."

The printed name of the petter-machete is "[if the petter-machete is petter-sharp]sharp[otherwise]dull[end if] machete". The initial appearance of the petter-machete is "A strange rootlet-covered wooden handle sticks out from the rubble of roots and twisted metal."

Instead of examining the petter-machete when the petter-machete is not handled:

    say "It is hard to tell among the roots, but it looks like the handle of a knife. Perhaps it could be pulled out."

The description of the petter-machete is "The blade is long and rusty[if the petter-machete is petter-sharp], but the edge looks clean and sharp[end if]. The dirty wooden handle is still covered in a mesh of rootlets, providing a nice grip[if the petter-whetstone is not handled].[paragraph break]You wish you had something to sharpen it with[end if]."

Instead of taking or pulling or taking off the petter-machete when the petter-machete is not handled:

    now the player carries the petter-machete;

    say "You pull on the wooden handle. It gives an inch, and some of the roots that hold it snap. You pull again, harder this time, and with a metallic screech and a cloud of spores you find yourself holding a machete in your hand."

Does the player mean taking the petter-machete:

    it is very unlikely.

Instead of rubbing the petter-machete when the petter-whetstone is enclosed by location and the petter-machete is handled:

    try petter-sharpening the petter-machete with the petter-whetstone.

Instead of swinging or waving the petter-sharp petter-machete when the location is a petter-room:

    if the location is MGR3f:

        say     "You swing the machete through the air but miss the birds.";

    otherwise:

        say "You take a wide swing with the machete[one of][if the location is MGR3 or the location is MGR3a or the location is MGR3b], slicing off a couple of roots. A milky fluid squirts from the cuts[otherwise], cutting off some of the weaker branches[end if][or][stopping]."

Instead of swinging or waving the petter-dull petter-machete:

    say     "You carelessly swing the machete through the air. Fortunately it is too dull to make any damage."

Understand "machete/rusty/blade/knife" or "wooden/-- handle" as the petter-machete.

Understand "dull" as the petter-machete when the petter-machete is petter-dull.

Understand "sharp" as the petter-machete when the petter-machete is petter-sharp.

Chapter - Greenhouse tree first level (MGR3b)

MGR3b is a petter-room in MGR.

MGR3b is east of MGR3a. The printed name of MGR3b is "Greenhouse (Petter Sjölund) (up the tree)". The description of MGR3b is "You're on one of the thick lower branches of the tree. The strangler fig roots cover the host tree completely. A sturdy, root-covered branch has grown into the walkway circling the greenhouse[if MGR3b is unvisited].[paragraph break]The branches above you look surprisingly climbable[end if]."

After looking or vaguely petter-turning when the location is MGR3b and Petter-invisible-bird is happening:

    say "[one of]What was that? It almost sounded like wings[or]The odd acoustics of this place makes every little rustle of leaves echo from all directions[stopping].";

    now petter-ghost is petter-noisy.

Below the MGR3b is MGR3.

Before going down from MGR3b:

    say "You carefully hang from one of the lower branches and drop to the greenhouse floor below.";

Before going to MGR3c from MGR3b:

    say "[one of]Heights have always frightened you. Steeling yourself, you grab hold of the sturdiest branch you can find and pull yourself up. Your hands are trembling and slippery with sweat[or]You climb higher up the tree[stopping].";

Chapter - Greenhouse tree second level (MGR3c)

MGR3c is a petter-room in MGR.

MGR3c is above MGR3b. The printed name of MGR3c  is "Greenhouse (Petter Sjölund) (higher up the tree)". The description of MGR3c  is "You are among the murkier branches higher up the tree. Trying your best not to look down, it is still obvious that you would not survive a fall from this height. Here, gaps between the strangler fig roots reveal the original host tree, which looks like an African fern pine. Through a small hole in the host tree, you can see the strangler fig growing like a spinal cord through its hollow trunk. The tree continues upwards."

Before going to MGR3d from MGR3c:

    if the petter-condition of the player is petter-unscratched:

        now the petter-condition of the player is petter-scratched;

    say "[one of]Ignoring your sweaty palms and pounding heart, you force yourself higher. It's getting difficult to even find room to move between the branches and pointy twigs. You are starting to feel dizzy[or]You climb even higher up the tree[stopping].";

Before going to MGR3b from MGR3c:

    say "You carefully descend, trying not to look down too much."

After looking or vaguely petter-turning when the location is MGR3c and Petter-invisible-bird is happening:

    say "[one of]You hear something flapping behind you again, much closer this time. You look behind you, but there is nothing[or]You think you heard a bird squawking somewhere[or]There are strange echoes coming from everywhere[stopping].";

    now petter-ghost is petter-noisy;

The petter-hole is scenery in MGR3c. The printed name of petter-hole is "hole in the tree". Understand "hole/hollow/column" or "spinal cord" as the petter-hole. The description of the petter-hole is "Through the hole, you can see the strangler fig growing like a spinal cord through the hollow trunk of the dead host tree."

Instead of entering the petter-hole:

    say "The hole is much too small for you to enter."

Instead of entering the petter-tree when the location is MGR3c:

    try entering the petter-hole.

Instead of inserting something into the petter-hole:

    say "There isn't a lot of room between the central root column and the hollow trunk[if the player carries the noun]. Beside, you wouldn't want to lose [the noun][end if]."

Instead of cutting the petter-hole when the player carries a petter-sharp petter-machete:

    say "[one of]You strike the central root of the tree with the machete, but only make a tiny dent that is quickly healed by a milky fluid[or]There doesn't seem to be much point[stopping]."

Chapter - Greenhouse tree third level (MGR3d)

MGR3d is a petter-room in MGR.

MGR3d is above MGR3c. The printed name of MGR3d  is "Greenhouse (Petter Sjölund) (even higher up the tree)". The description of MGR3d  is "Up here the tree is more like a thicket of thin, sharp, dead twigs, with flowering roots spiraling between them. There are some huge bones among the twigs and leaves [ps--] the skeleton of some prehistoric aquatic beast once mounted here, suspended from the ceiling by metal wires, now twisted and broken by the relentless growth of the tree. It seems possible to climb still higher from here."

Before going to MGR3e from MGR3d:

    if the petter-condition of the player is petter-scratched:

        now the petter-condition of the player is petter-cut-up;

    say "[one of]You climb higher. It feels like crawling through a thorny bush. The entire crown of the tree sways along with your every move, and the glass ceiling crackles like thin ice. Sweat trickles into your eyes. Did you black out there for a moment? You feel like throwing up[or]You climb still higher up the tree[stopping].";

After looking or vaguely petter-turning when the location is MGR3b and Petter-invisible-bird is happening:

    say "[one of]That flapping noise again! You look around thoroughly, but don't see anything that could have made that sound [or]The odd acoustics of this place makes every little rustle of leaves echo from all directions[stopping].";

    now petter-ghost is petter-noisy.

Before going to MGR3c from MGR3d:

    say "You climb down, very carefully so as not to slip."

Section - Flowers

The petter-flowers are a plural-named petter-backdrop. The petter-flowers are in MGR3d and MGR3e. The printed name of the petter-flowers is "fig flowers". Understand "flower/flowers/petals/red/circle" as the petter-flowers. The description of the petter-flowers is "The strangler fig flowers are large and white with a blood red circle across the petals.".

Instead of cutting the petter-flowers when the player carries a petter-sharp petter-machete:

    say "You don't need any flowers."

The petter-fruit are a plural-named backdrop. Every petter-room contains the petter-fruit. The printed name of the petter-fruit is "fruit". Understand "fruit/fruits" as the petter-fruit. The description of the petter-fruit is "The strangler fig seems to bear no fruit."

Instead of doing something when the noun is the petter-fruit or the second noun is the petter-fruit:

    say "[description of petter-fruit][line break]";

Instead of throwing something at the petter-fruit:

    say "[description of the second noun][line break]"

Section - Dinosaur bones

The petter-dinosaur-bones are plural-named scenery in MGR3d. The printed name of the petter-dinosaur-bones is "prehistoric bones". Understand "bones/bone/dinosaur/aquatic/beast/prehistoric/skeleton/plesiosaur/elasmosaurus/plaster/interior" as the petter-dinosaur-bones. The description of petter-dinosaur-bones is "The bones are black with yellow fungal growth, and swing unnervingly from their wires. [if petter-plaster is in MGR3]One of the bones shows its white plaster interior where you cut it off[otherwise]Probably made of painted plaster of Paris, they might once have formed the skeleton of some kind of elasmosaurus[end if]."

Instead of cutting the petter-dinosaur-bones when the player carries a petter-sharp petter-machete:

    now the petter-plaster is in MGR3;

    say "[one of]You carefully climb up to one of the bones, what actually looks like a number of huge vertebra molded together as one, and hit it with the machete. Spores billow up, dense enough to make you cough, and about half the bone comes off, bounces through the branches and [if the petter-statue is in MGR3]shatters on top of the parrot sculpture[otherwise]crashes to the ground[end if] below in a cloud of plaster.[paragraph break]You lose your footing and barely manage to grab hold of the other half of the bone, still swinging from its steel wire. Nearly blacking out with vertigo and fear, you make your way back to some reasonably safe branches further in[or]You cut off another piece of bone. It bounces through the branches and [if the petter-statue is in MGR3]shatters on top of the parrot sculpture[otherwise]crashes to the ground[end if] below in a cloud of plaster[or]You don't see any other bones you could reach in a reasonably safe way[stopping]."

Instead of vaguely petter-praying when the petter-dinosaur-bones are in location:

    try petter-praying to the petter-dinosaur-bones.

Instead of pushing the petter-dinosaur-bones:

    say "You give one of the bones a push, and it barely misses you on the rebound."

Instead of pulling the petter-dinosaur-bones:

    say "You try pulling one of the bones, but there is not a lot of room for it to move here."

Instead of taking or taking off the petter-dinosaur-bones:

    say "The bones are still firmly attached to their wires, and far too bulky to carry anyway."

The petter-dinosaur-wires are plural-named scenery in MGR3d. The printed name of the petter-dinosaur-wires is "metal wires". Understand "metal/wires/wire/string" as the petter-dinosaur-wires. The description of petter-dinosaur-wires is "The wires run through holes drilled through the bones. They seem to be attached to the greenhouse ceiling."

Instead of climbing or swinging the petter-dinosaur-wires:

    say "Even trying to get onto one of those wires seems like a sure way to fall to your death. Also, there are some alarming cracks in the glass where the wires are attached to the ceiling."

Instead of climbing or swinging the petter-dinosaur-bones:

    say "Even trying to get onto one of those bones seems like a sure way to fall to your death. Also, there are some disconcerting cracks in the glass where the wires are attached to the ceiling."

Understand "do a/-- trapeze number" as a mistake ("As a child, you always dreamed about running away with a circus. But this is not the time or place for practice.") when the location is MGR3d.

Instead of pushing petter-dinosaur-wires:

    try pushing the petter-dinosaur-bones.

Instead of taking or taking off or pulling the petter-dinosaur-wires:

    say "The wires are firmly attached."

Instead of cutting the petter-dinosaur-wires when the player carries a petter-sharp petter-machete:

    now the petter-plaster is in MGR3;

    say "[one of]You carefully make your way to one of the nearest wires and strike it with the machete. It takes several cuts until it snaps, and the bone it was attached to swings away, still attached to a wire at the other end.[paragraph break]You lose your balance and just barely make it back to some reasonably safe branches, sweating profusely[or]Against your better judgment, you climb out to the second wire and hack it off. The bone it was attached to bounces through the branches and [if the petter-statue is in MGR3]shatters on the parrot sculpture[otherwise]crashes to the ground[end if] below in a cloud of plaster[or]Again you climb out to a wire and cut it off. The bone it was supporting bounces through the branches and [if the petter-statue is in MGR3]shatters on the parrot sculpture[otherwise]crashes to the ground[end if] below in a cloud of plaster[or]You don't see any other wires you could reach in a reasonably safe way[stopping]."

Chapter - Greenhouse tree top level (MGR3e)

MGR3e is a petter-room in MGR.

MGR3e is above MGR3d. The printed name of MGR3e  is "Greenhouse (Petter Sjölund) (top of the tree near the ceiling)". The description of MGR3e  is "The entire treetop sways from your weight, up and down, this way and that. You are close enough to the glass ceiling to see the blue sky and bright sunshine outside."

After looking or vaguely petter-turning when the location is MGR3e:

    say "[one of][run paragraph on][or]You hold your breath. It is eerily quiet.[or][run paragraph on][stopping]";

    now petter-ghost is petter-noisy;

    continue the action.

Before going to MGR3d from MGR3e:

    say "You descend slowly, trying your best not to look down."

Instead of going up when the location is MGR3e:

    say "There is no way you could or would ever want to climb higher than this."

Instead of going outside when the location is MGR3e:

    say "There is no way out of the greenhouse up here."

Section - First fall scene

Petter-first-fall is a scene. Petter-first-fall begins when the location is MGR3e and the petter-statue is not petter-clean. Petter-first-fall ends when the location is MGR3b.

When Petter-first-fall begins:

    now the petter-condition of the player is petter-bruised;

    say "There is a loud squawk next to your ear. Everything goes black. You fall.";

    say "[5 petter-paragraph breaks]Then consciousness returns. Only a second has passed. You are still falling. Instinctively you reach for something to grab onto, but every time you think you've got a hold on the sharp twigs and slithery leaves they slip out of your grasp.";

    say "[line break]But you keep trying, and eventually your fall slows down and the branches stop giving way below you. With a final lurch you find yourself swinging astride one of the lower branches of the tree, cut and bruised and in shock but still breathing.";

    move the player to MGR3b.

To say (X - a number) petter-paragraph breaks:

    repeat with N running from 1 to X:

        say paragraph break.

Chapter - Birdcage

The petter-cage is a closed openable enterable transparent fixed in place container. Understand "cage/birdcage/iron/latch/bars" as the petter-cage. The printed name of petter-cage is "birdcage". The description of the petter-cage is "It is a wrought-iron cage[if the location is MGR3], battered and bent from the fall[end if], large enough to fit a human."

Instead of taking or taking off the petter-cage when the location is MGR3e:

    say "The cage is attached to the greenhouse ceiling with a thick metal wire. Even trying to detach the huge cage would likely make you fall to your death."

Instead of smelling the petter-cage:

    say "It reeks of death and rotten eggs."

Instead of examining the petter-cage:

    say "[description of petter-cage] [if the petter-cage is closed]It is closed with a small latch. Through the bars you see what looks like[otherwise]Inside there is[end if] a bird's nest."

Instead of entering the petter-cage:

    if the petter-cage is closed:

        try opening the petter-cage;

    if the location is MGR3e:

        say "[one of]You grab the bars and put one foot on the floor of the cage, but a loud cracking noise from where the cage is attached to the glass ceiling makes you change your mind. You let go of the cage[or]You'd rather not try that again[stopping].";

    otherwise:

        say "[one of]You get into the cramped cage. The eggshells crack under your feet. The reek in here is unbearable. Suddenly you get the vague feeling that someone is coming outside, someone who is going to lock you inside the cage. You can't actually see or hear anyone, but decide to get out as fast as humanly possible[or]You rather not try that again[stopping]."

Instead of climbing or swinging the petter-cage when the location is mgr3e:

    Say "[one of]You grab the bars and lift yourself up, but a loud cracking noise from where the cage is attached to the glass ceiling makes you change your mind. You let go of the cage[or]You'd rather not try that again[stopping]."

Instead of climbing or swinging the petter-cage-wire:

    try climbing the petter-cage.

Instead of attacking or cutting the petter-cage when the location is MGR3e:

    say "[one of]You strike the side of the cage. It sways away on its steel wire. A yellow cloud of spores billows up, dense enough to make you cough and your eyes run. But the cage itself seems unaffected[or]You'd rather not try that again[if the harrison-cardboard-box is not handled], but the wire look like it might be possible to cut[end if][stopping]."

Instead of pushing or pulling the petter-cage when the location is MGR3e:

    say "It swings away when you let go, and you barely manage to avoid it on the way back. Then it stops. There is not a lot of room for it to move here."

Rule for writing a paragraph about the petter-cage:

    now everything in the petter-nest is mentioned;

    now the petter-nest is mentioned;

        say "There is a [if the location is MGR3e]human-size birdcage suspended from the ceiling [otherwise]battered human-size birdcage [end if]here. [if the petter-cage is open]Through the open door[otherwise]Between the wrought-iron bars[end if] you see something inside that looks like a bird's nest."

The petter-nest is a fixed in place container in the petter-cage. Understand "nest" or "bird's/twigs" as the petter-nest. The printed name of petter-nest is "bird's nest".

The harrison-cardboard-box is in petter-nest.

After opening the petter-cage:

    say "You open the door. [run paragraph on]";

    try examining the petter-nest.

Instead of examining the petter-nest:

    if the petter-cage is closed:

        say "You can't see much through the bars of the birdcage.";

    otherwise:

        say "A bird's nest made of dry twigs fills the bottom of the cage. It is full of broken eggshells and small bird bones[if the harrison-cardboard-box is in petter-nest and harrison-cardboard-box is not handled]. Hidden among the bones is a strangely clean and intact small cardboard box[end if].";

        let L be a list of things;

        repeat with N running through things in petter-nest:

            if (N is not harrison-cardboard-box or harrison-cardboard-box is handled) and N is not scenery:

                add N to L;

        unless L is empty:

            say "[line break]In the nest you can also see [L with indefinite articles]."

Instead of taking the petter-nest:

    say "You'd prefer not to touch it."

Instead of petter-digging the petter-nest:

    try searching the petter-nest.

Instead of smelling the petter-nest:

    say "It reeks of death and rotten eggs."

Instead of inserting something into the petter-cage:

    try inserting the noun into the petter-nest.

Instead of examining something which is in the petter-nest when the petter-cage is closed:

    say "You can't see much through the bars of the birdcage."

The petter-eggshells are plural-named scenery in the petter-nest. The printed name of  petter-eggshells is "eggshells". Understand "eggshells/eggshell/egg/eggs" as the petter-eggshells. The description of petter-eggshells is "The eggshells have blue spots."

Instead of taking the petter-eggshells:

    say "You don't even want to touch them."

Instead of eating or tasting the petter-eggshells:

    say "Only the shells remain."

Instead of smelling the petter-eggshells:

    say "They reek of death and rot."

Instead of petter-digging the petter-eggshells:

    try searching the petter-eggshells.

Instead of cutting the petter-eggshells when the player carries a petter-sharp petter-machete:

    say "The eggshells are too tiny to even hit with the machete."

The petter-bird-skeletons are plural-named scenery in the petter-nest. The printed name of  petter-bird-skeletons is "bird bones". Understand "bones/bone/chicken/chick/skeleton/skeletons/beak/beaks/skull/skulls" as the petter-bird-skeletons. The description of petter-bird-skeletons is "The bones are tiny and the skulls have little beaks."

Instead of taking the petter-bird-skeletons:

    say "You don't even want to touch them."

Instead of cutting the petter-bird-skeletons when the player carries a petter-sharp petter-machete:

    say "The bones are too tiny to even hit with the machete."

Instead of eating or tasting the petter-bird-skeletons:

    say "You'd prefer not to touch them. There doesn't seem to be any meat left on them anyway."

Instead of smelling the petter-bird-skeletons:

    say "They reek of death and rot."

Instead of petter-digging the petter-bird-skeletons:

    try searching the petter-bird-skeletons.

The petter-parrots is a petter-non-existent. The printed name of the petter-parrots is "memory of parrots". Understand "parrots/birds/feathers/pandemonium" as the petter-parrots. The description of the petter-parrots is "There is no sign of those parrots you saw before."

The petter-shards are a plural-named petter-non-existent. The printed name of the petter-shards is "glass shards". Understand "glass/window/ceiling/-- shards" or "broken glass" as the petter-shards. The description of the petter-shards is "You can't find any of the broken glass from the ceiling here. In fact you're not altogether sure that the ceiling is damaged at all."

Section - The cage when hidden

[The petter-hidden-cage is a dummy object that catches attempts to do something to the cage or the leaves that hide it before it is revealed.]

The petter-hidden-cage is plural-named and fixed in place in MGR3e. Understand "cage/birdcage/hidden/thing/something/object/branches/branch/leaves/woven/mesh/weave/tangled/tangle/twigs" as petter-hidden-cage. The printed name of petter-hidden-cage is "tightly woven branches and leaves". The initial appearance of petter-hidden-cage is "Something is hidden behind the tightly woven branches and leaves here.". The description of the petter-hidden-cage is "[one of]Is there some kind of cage hidden behind there? You are not sure.[or]Did you see something move in there?[cycling]"

Instead of searching or looking under the petter-hidden-cage:

    try examining the petter-hidden-cage.

Does the player mean doing something to the petter-hidden-cage:

    it is very likely.

Instead of pulling or taking or taking off or pushing or attacking or turning or opening the petter-hidden-cage:

    say "[one of]You only succeed in hurting your hands on the sharp twigs[or]The branches are too tightly tangled[cycling]."

Instead of listening to the petter-hidden-cage:

    say "[one of]Was that the squawk of a bird you heard in there?[or]Was that a flutter of wings?[or]Perhaps it was nothing.[cycling]".

Instead of doing something when (the noun is petter-hidden-cage or the second noun is petter-hidden-cage) and the petter-statue is petter-clean:

    now the petter-hidden-cage is nowhere;

    now the petter-cage is in location;

    say "As you approach, you hear strange harmonic birdsong, and the leaves and branches part, almost like curtains being drawn, revealing a human-size birdcage suspended from the ceiling."

Section - The wire holding up the cage

The petter-cage-wire is scenery. It is part of the petter-cage. The printed name of the petter-cage-wire is "metal wire". Understand "metal/steel/-- wire/fibres/fibre/fibers/fiber" as the petter-cage-wire.

The petter-cage-wire can be petter-undamaged, petter-half-off or petter-nearly-off. The petter-cage-wire is petter-undamaged.

Instead of examining the petter-cage-wire:

    if the petter-cage-wire is petter-undamaged:

        say "One end of the wire is attached to the birdcage and the other to the ceiling.";

    otherwise:

        if the petter-cage-wire is petter-half-off:

            say "The wire is frayed where you hit it. Many of the metal fibers have been cut.";

        otherwise:

            say "The wire is nearly cut off. The cage hangs on a single metal fiber."

Instead of pushing the petter-cage-wire:

    try pushing the petter-cage.

Instead of taking or taking off or entering or climbing or swinging or opening or attacking or cutting or pushing or pulling the petter-cage when the petter-cage-wire is petter-nearly-off:

    say "The wire holding up the birdcage snaps at first touch. ";

    cause the birdcage to fall.

Instead of taking or taking off or swinging or pushing or pulling the petter-cage when the location is MGR3:

    say "The cage seems to be firmly stuck in the ground."

Instead of taking or taking off or pulling the petter-cage-wire:

    if the petter-cage-wire is petter-nearly-off:

        say "The wire snaps as soon as you touch the birdcage. ";

        cause the birdcage to fall;

    otherwise:

        if the petter-cage-wire is petter-undamaged:

            say "The wire is firmly attached. Even trying to detach the huge cage would likely make you fall to your death.";

        otherwise:

            say "The wire is frayed, but not enough to snap yet."

Understand "detach [petter-cage]" or "detach [petter-cage-wire]" as a mistake ("Trying to detach the huge metal cage would likely make you fall to your death.").

Instead of cutting the petter-cage-wire when the player carries a petter-sharp petter-machete:

    if the petter-cage-wire is petter-undamaged:

        say "The wire is tough and the strike seem to have little effect, but when you look closer you see that a couple of metal fibers are loose.";

        now petter-cage-wire is petter-half-off;

    otherwise:

        if the petter-cage-wire is petter-half-off:

            say "Another cut, and you're almost through. The cage nearly hits you on the rebound and you lose your balance, but you regain it by grabbing hold of the cage for a moment. New cracks appear in glass ceiling up where the wire is attached.";

            now petter-cage-wire is petter-nearly-off;

        otherwise:

            say "You grab the cage to steady it before placing the cut, and the last fiber of the wire snaps. ";

            cause the birdcage to fall.

Section - Falling through the air (MGR3f)

MGR3f is a petter-room in MGR.

Yourself can be petter-falling-too-fast. Yourself is not petter-falling-too-fast.

The printed name of MGR3f is "Falling through the air". The description of MGR3f is "A pandemonium of albino parrots is squawking and flapping all around you, their wings whipping your face along with the air. The ground is approaching rapidly."

The petter-fall-parrots are scenery in MGR3f. The printed name of petter-fall-parrots is "parrots". Understand "parrots/parrot/bird/birds/albino/beak/beaks/talon/talons/feather/feathers/tail/tails/wing/wings/white/leg/legs/eyes/red/pandemonium" as the petter-fall-parrots.

The description of the petter-fall-parrots is "Impossibly large and white and numerous. Their red eyes burn with hate."

Instead of taking or pulling or attacking or climbing or petter-riding the petter-fall-parrots:

    now the player is not petter-falling-too-fast;

    say "Somehow you manage to grab hold of one of the parrots in mid-air. It screams and flaps its wings viciously, trying to get away from you. Some of the other parrots attack you with their claws and beaks from below. This actually seems to slow your fall just a bit."

Instead of listening to the petter-fall-parrots:

    try listening to location.

Instead of touching or examining the petter-air when the location is MGR3f:

    say "The wind whips your face."

Instead of listening to MGR3f:

    say "The rush of the wind, the squawks and flapping wings of the parrots, your beating heart [ps--] it is a macabre cacophony."

Instead of taking or climbing or pulling or petter-riding a backdrop when the location is MGR3f and the noun is not petter-insubstantial:

    if the noun is petter-branches or the noun is petter-tree:

        say "You reach blindly for anything to hold onto, and your fingers close around a dry branch. It snaps right off, but not before slowing your fall a little.";

        now the player is not petter-falling-too-fast;

    otherwise:

        if the noun is petter-roots or the noun is petter-leaves:

            say "You reach blindly for anything to hold onto, and your fingers close around a soft root. It snaps right off, squirting sticky latex over your hand, but not until it has slowed your fall a little.";

             now the player is not petter-falling-too-fast;

        otherwise:

            say "You try to grab hold of [the noun], but it is impossible."

Instead of cutting something when the location is MGR3f and the player carries a petter-sharp petter-machete:

    say "You swing the machete through the air but miss."

Instead of examining down when the location is MGR3f:

    say "You see the ground rushing toward you."

Instead of going down when the location is MGR3f:

    say "You are going that way whether you like it or not."

Instead of petter-falling when the location is MGR3f:

    say "You can't help doing that."

Check throwing something at the petter-fall-cage when the location is MGR3f:

    try dropping the noun instead.

After dropping something when the location is MGR3f:

    if the noun is in location:

        move noun to MGR3;

        now the player is not petter-falling-too-fast;

        say "You hurl [the noun] downward. In theory this will slow your fall a tiny bit, but so tiny that it could not possibly matter. Or could it?"

Instead of petter-flying when the location is MGR3f:

    now the player is not petter-falling-too-fast;

    say "You flap your arms in desperation. There is no way that could possibly help. Or could it?"

Understand "slow the/-- fall" as a mistake ("You will have to say how.") when the location is MGR3f.

Understand "laugh" as a mistake ("This is not Mary Poppins.") when the location is MGR3f.

The petter-fall-cage is scenery in MGR3f. Understand "cage/birdcage/iron/latch/bars" as the petter-fall-cage . The printed name of petter-cage is "birdcage". The description of the petter-fall-cage  is "You see the cage from above, falling at about the same speed as you."

Instead of looking under the petter-fall-cage:

    say "You can't look under it from here."

Instead of doing something to the petter-fall-cage when the action requires a touchable noun:

    say "You can't reach it."

Instead of cutting the petter-fall-cage when the player carries the petter-machete:

    now the player is not petter-falling-too-fast;

    say "You somehow manage to hit the cage below with the machete. In theory this will slow your fall a tiny bit, but so tiny that it could not possibly matter. Or could it?"

To cause the birdcage to fall:

    now the petter-cage is in MGR3;

    now the petter-statue is nowhere;

    now the petter-cage-wire is petter-undamaged;

    now the petter-cage-wire is nowhere;

    say "As the cage falls, it snags on the branch you are standing on and pulls you down with it.";

    move the player to MGR3f;

    now the player is petter-falling-too-fast;

    the player petter-hits the ground in 1 turn from now.

At the time when the player petter-hits the ground:

    say "The parrots all scream in horrible unison as the cage crashes into the stone parrot right below you, shattering it. A split-second later you hit the cage head first, and everything goes dark.";

    if the player is petter-falling-too-fast:

        cause death by falling;

    otherwise:

        repeat with N running through things carried by the player:

            unless N is worn:

                move N to MGR3;

        say 12 petter-paragraph breaks;

        say "When you open your eyes you are on the greenhouse floor, resting your head on the side of the battered birdcage.";

        move player to MGR3;

        now the petter-parrots are in MGR3;

        now the petter-wire2 is in MGR3;

        now the petter-wire3 is in MGR3e;

        now the petter-parrot-shards are in MGR3;

        now the petter-condition of the player is petter-battered;

        say "You slowly get up, your body aching all over. But nothing seems to be broken."

The petter-wire2 is petter-non-existent. Understand "metal/steel/-- wire/fibres/fibre/stump/fiber/fibers" as the petter-wire2. The printed name of petter-wire2 is "wire stump". The description of petter-wire2 is "There is hardly anything left of the wire that held up the cage."

The petter-wire3 is petter-non-existent. Understand "metal/steel/-- wire/fibres/fibre/fiber/fibers/stump" as the petter-wire3. The printed name of petter-wire3 is "wire stump". The description of petter-wire3 is "You can barely see what is left of the wire that held up the cage."

The petter-parrot-shards are a plural-named petter-non-existent. Understand "statue/sculpture/broken/parrot/beak/garden/ornament/bird/parrot/shards" or "white stone" as the petter-parrot-shards. The printed name of petter-parrot-shards is "sculpture remains". The description of petter-parrot-shards is "There is hardly anything left of the parrot sculpture."

Section - Deaths and victories

Before opening the harrison-cardboard-box when the player does not carry the harrison-cardboard-box:

    say "(first taking [the harrison-cardboard-box].)[command clarification break]";

    try taking the harrison-cardboard-box.

Instead of taking the harrison-cardboard-box when harrison-cardboard-box is not handled and the location is MGR3:

    move harrison-cardboard-box to player;

    now harrison-cardboard-box is handled;

    say "Taken.[paragraph break][bracket]Congratulations! You have reached the violent conclusion of this room.[close bracket][line break]";

Instead of taking the harrison-cardboard-box when harrison-cardboard-box is not handled and the location is MGR3e:

    say "You reach in through the birdcage door. As soon as your hand closes around the cardboard box, [run paragraph on]";

    if the petter-statue is petter-clean:

        say "you hear a soft flapping of wings coming from every direction, accompanied by a strangely beautiful song of hoarse harmonies. Huge white parrots surround you. At first you are alarmed, but their kindly gaze calms you down. The parrots lift you with their beaks [ps--] somehow holding onto your clothes everywhere without hurting you, dropping you, or ripping the fabric. They give you a nice tour of the greenhouse, circling the tree and the glass walls. The view is breathtaking, and their song stills your vertigo. They gently carry you down to the ground and let go. Then they are gone.";

        move the harrison-cardboard-box to player;

        now the harrison-cardboard-box is handled;

        move player to MGR3;

        move the petter-parrots to MGR3;

        say "[bracket]Congratulations! You have reached the peaceful conclusion of this room.[close bracket][line break]";

    otherwise:

        say "it seems to get darker outside. You hear a distant sound as from a thousand squawking birds, and it is getting louder.[paragraph break]There is a huge crash and sharp pieces of glass shower down all around you. Then the air is full of parrots. A pandemonium of red-eyed albino parrots, thousands of them, circling through the greenhouse like the water in a washing machine. They land on your back and in your hair, wherever you can't wave them off. Their sharp beaks peck at your skin, pinching it, pulling it, going for your eyes [ps--]";

        cause death by falling.

To cause death by falling:

    say 12 petter-paragraph breaks;

    say "When you open your eyes you are on your back on the greenhouse floor, feeling your clothes soaking up blood. The parrots land on you and around you, their talons and beaks tearing into your flesh, but as you try to wave them off, you find that you are unable to lift a finger. [if the player is petter-falling-too-fast]If only you could have found a way to slow down the fall somehow, is your last rational thought. [end if]The pain is unimaginable, yet you cannot make a sound, not even as one of them pecks out your eye.";

    end the story saying "Death comes as a relief".