"Cragne Manor Pantry" by Chris Conley

Chapter 1 - Do Not Change Any Of This

Include Cragne Suite by Ryan Veeder.

[Don't mess with other people's rooms!]

MBF is a region.

MBF3 is a room in MBF. MBF3 is east from MBF1.

MBF4 is a room in MBF. MBF4 is east from MBF3.

[Your room is MBF3. This is a pantry in the Cragne Manor basement. The rest of the basement is west. Another room is further east. For your Jupiter track puzzle, the player needs to bring a piece of information that you choose, which will be the reward of someone else's puzzle, to get some other information, which will be decided by someone else.

The attached text file can be used as a project template for your room. When you want to submit an update, email a similar text file to us.]

Part 1 - MBF3 Pantry

Chapter 0 - Niceties

The verb to be cc-described implies the description property.

To say regarding it: now the prior named object is nothing.

To say this:

    if the story tense is:

        -- present tense:

            say "this";

        -- perfect tense:

            say "this";

        -- otherwise:

            say "that".

To say 'll:

    if the story tense is:

        -- present tense:

            say "[']ll";

        -- perfect tense:

            say "[']d";

[        -- past tense: ] [no]

        -- past perfect tense:

            say "[']d";

        -- future tense:

            say "[']ll";

To say helping-have:

    if the story tense is:

        -- past perfect tense:

            say "had";

        -- perfect tense:

            say "[adapt the verb have in present tense]";

        -- otherwise:

            say "[have]";

To say 's:

    if the story tense is:

        -- present tense:

            say "[']s";

        -- perfect tense:

            say "[']d";

        -- past tense:

            say "[']d";

        -- past perfect tense:

            say "[']d";

        -- future tense:

            say "[']ll have";

To decide if we have multiple personalities:

    if the story viewpoint is first person plural or

     the story viewpoint is second person plural or

     the story viewpoint is third person plural:

        decide yes;

    otherwise:

        decide no.

To say multi-person s:

    if we have multiple personalities, say "s".

cc-testing is initially false.

Section 0.1 - begin button - not for release

When play begins:

    now cc-testing is true;

    say "Hey, thanks for testing! [paragraph break]Check your inventory to get started with the puzzle proper.[paragraph break] -CC[paragraph break]" [ryan: probably delete this]

The wax cylinder is carried by the player, cc-described "This is clearly what you need to play to start the pantry puzzle."

The phonograph is a container carried by the player, cc-described "This must be what you need to start the pantry puzzle."

Definition: a thing is non-cylindrical if it is not the wax cylinder.

To fit is a verb.

Instead of inserting something non-cylindrical into the phonograph, say "[The noun] [don't fit]."

Instead of putting something on the phonograph, try inserting the noun into the phonograph.

Playing is an action applying to one thing. Understand "play [something]" as playing[ when the location is MBF3].

Check playing: say "[The noun] [aren't] playable." instead.

Instead of switching on the phonograph, wax cylindrically.

Instead of playing the phonograph, wax cylindrically.

To wax cylindrically:

    if the wax cylinder is in the location or the wax cylinder is carried:

        attempt the message;

    perhaps complain about playability;

Instead of playing the wax cylinder:

    if the phonograph is in the location or the phonograph is held:

        attempt the message;

    perhaps complain about playability.

To attempt the message:

    say "(first putting the wax cylinder in the phonograph)[command clarification break]";

    try inserting the wax cylinder into the phonograph;

To perhaps complain about playability:

    if the wax cylinder is not in the phonograph, say "There's nothing to play." instead;

    [don't complain if the message was properly played, only if something else went wrong]

After inserting the wax cylinder into the phonograph:

    say "You INSERT the WAX CYLINDER into the PHONOGRAPH and TURN IT ON: [paragraph break][cc-puzzle-text][paragraph break]Then the WHOLE MACHINE + CYLINDER VANISHES ~gasp~ ~horror~[line break]";

    now the phonograph is nowhere;

    now the phonograph is unseen;

    now the wax cylinder is unseen.

Chapter 1 - The Pantry

MBF3 has printed name "Pantry (Chris Conley)". The commentary is "I asked for something involving fruit, possibly preserved fruit, expecting I might get something like a pantry. I didn't know what I was going to do with it, and... I still don't know what this is. Enjoy.[paragraph break](Apologies for not being able to think of a good Soup Cans joke.)[paragraph break]And of course, a Very [cc-superlative] [cc-superlative] Thanks to my testers: Lucian Smith, Matt Weiner, Daniel Ravipinto, Chandler Groover, Carl Muckenhoupt, Sean M. Shore, Andrew Schultz, Michael Fessler, Mike Spivey, Jeremy Freese, Baldur Brückner, Hanon Ondricek, and Robert Colnaghi. [line break] --CC".

[After jumping, showme commentary of MBF3.]

To lie is a verb. To walk is a verb. To beckon is a verb.

MBF3 is cc-described "[We] [are] in a pantry lined with [metal shelves] stretching the entire length of both walls. Most of [the shelves]['] contents [lie] deep in shadow, as the room [regarding it][are] lit by only a single bare bulb hanging three feet above [our] head[multi-person s]. [The dark stones] echo as [we] [walk], and [the cc-air] down here [are] cold and damp.[paragraph break]The rest of the basement [lie] off to the west. A dark doorway [beckon] to the east."

Instead of going inside when the location is MBF3: try going east.

Instead of going outside when the location is MBF3: try going west.

A cc-imagination is a kind of thing. Cc-imaginations are usually scenery.

The cc-air is a privately-named cc-imagination in MBF3 with printed name "air". Understand "cold/damp/air" as the cc-air. It is cc-described "The air is cold and damp. It clings to you like cobwebs." Instead of touching the cc-air, say "Somehow both cold and damp."

Some cc-cobwebs are a cc-imagination in MBF3 with printed name "cobwebs". Understand "cobweb/spiderweb/spider/web/webs/spiderwebs/webbing" as the cc-cobwebs. Instead of doing something with the cc-cobwebs, say "No, there [aren't] any actual cobwebs [here]."

To try is a verb.

Instead of examining yourself when the location is MBF3, say "[We] absolutely [look] the same as [we] usually do. Well, more or less, considering what['s] happened lately. But [we] [try] not to dwell on that.[paragraph break][We] [are] feeling a bit peckish."

Cc-message-printed is initially false.

Last every turn when the location is MBF3:

    now cc-message-printed is false.

Section 1.1 - roots

To branch is a verb. To break is a verb.

Some dangling roots are a fixed in place thing in MBF3. "Pale roots of some unknown plant [regarding the dangling roots][helping-have] broken through the ceiling in one corner, dangling halfway to the floor." Understand "plant/plants/root" and "hanging" as the dangling roots.

They are cc-described "[The roots] are tan-colored, nearly white, thick and veiny. They [branch] off at strange, sharp angles, ultimately terminating in wispy strands that [hang] halfway to the floor."

Instead of taking the dangling roots, say "[The roots] [are] surprisingly resilient. You [can't] [break] off any piece."

Instead of attacking the dangling roots, try taking the noun. Instead of pulling the dangling roots, try taking the noun.

To wave is a verb.

Instead of pushing the dangling roots, say "[The roots] [wave] slightly."

To seem is a verb.

Some thick white veins are part of the dangling roots, cc-described "They almost seem to... throb.[first time] Or is it your imagination?[only]". Understand "vein/strand/strands/wisp/wisps" as the thick white veins.

After touching the thick white veins, say "It's faint, but... they [regarding the thick white veins][seem] to pulsate under [our] touch."

Instead of taking the thick white veins, try taking the dangling roots.

Instead of touching the dangling roots, try touching the thick white veins.

To achieve is a verb.

Instead of climbing the roots:

    say "That [may be] a decent workout, but [we] [don't achieve] anything by climbing the roots in the corner."

Understand "hang on/onto [something]" as climbing when the location is MBF3.

Section 1.2 - rotting pumpkin

To buzz is a verb.

A disgusting rotting pumpkin is a fixed in place thing in MBF3, cc-described "It [regarding the rotting pumpkin][are] putrid, lying in a puddle of its own innards, sad and crumpled nearly to the floor. Two [fat black flies] [buzz] around [if the limp stem is part of the rotting pumpkin]the stem[otherwise]the top[end if]." Understand "puddle/innards/innard/goo" as the pumpkin. Does the player mean doing something with the pumpkin: it is likely.

To hang is a verb. To sit is a verb.

A limp pumpkin stem is part of the disgusting rotting pumpkin, cc-described "The abbreviated white pumpkin stem [regarding the limp pumpkin stem][if ungrounded][hang] limply[otherwise][sit] out on [pumpkin-surface] like some pitiful still life[end if]."

Understand "piece/portion" as the limp stem.

Definition: the limp pumpkin stem is ungrounded if it is carried or it is part of the disgusting rotting pumpkin.

To say pumpkin-surface:

    if the holder of the limp pumpkin stem is a room:

        say "the floor";

    otherwise:

        say "[the holder of the limp pumpkin stem]";

To shlorp is a verb.

Instead of pulling the limp pumpkin stem, try taking the noun. Instead of pushing the limp pumpkin stem, try taking the noun.

Before taking the limp pumpkin stem for the first time:

    say "[There] [are] a wet [italic type]pop[roman type] and [we] [are] left holding the pumpkin stem as the greater mass of the fruit [regarding it][shlorp] back down to the floor.";

    now the player holds the limp pumpkin stem;

    rule succeeds.

To succeed is a verb.

Instead of taking or pushing or pulling the disgusting rotting pumpkin:

    say "[We] [succeed] only in coating [our] arms in pumpkin goo."

To send is a verb.

After smelling the disgusting rotting pumpkin, say "The decaying pumpkin stench nearly [regarding it][send] [us] reeling."

After smelling the limp stem, say "Not nearly as bad as the pumpkin it came from."

Instead of smelling something when the location is MBF3 and the noun is not the disgusting rotting pumpkin:

    say "The rotting pumpkin smell overwhelms anything else in here."

Before attacking the disgusting pumpkin:

    say "[It] already [look] like [it's] been smashed into a small pile of putrid debris. Let's not add insult to injury." instead.

Section 1.3 - flies

Some fat black flies are a scenery animal in MBF3, cc-described "Big black globs of buzzing annoyance." Understand "insect/insects/bug/bugs/fly/glob/globs" as the fat black flies.

Understand "swat [something]" and "whack [something]" and "whallop [something]" as attacking when the location is MBF3.

To arise is a verb.

Instead of taking the fat black flies, say "[regarding the fat black flies][They] [prove] far too nimble for [us] to catch."

Instead of attacking the fat black flies, say "[We] swat one down. [We] [could] swear it [regarding it][look] like two more [regarding the fat black flies][arise] to take its place."

After listening to the fat black flies, say "Buzzzzzz." [OK Roberto]

Section 1.4 - shelving

To run is a verb.

Some metal shelves are a scenery supporter in MBF3, cc-described "Eight stark [metal shelves] [run] the length of each wall between the two entrances of [this] room. They [are] about a foot deep, and absolutely stacked to the brim with dozens of aluminum cans, jars, jugs, and other containers. They [are] mostly labeled, or their contents easy enough to determine if you blow away the dust[if cc-puzzle is false], but [we] [have] no idea what, if anything, in them might be of interest. [We] wouldn't even know where to start[end if].[paragraph break]They [regarding the metal shelves][are][if cc-puzzle is false], at least,[end if] organized by size, shape, and container material[if cc-puzzle is true]. You [might find] the peaches mentioned in Edmund's message somewhere in the jar section[end if]." Understand "shelving/shelf" as the shelves.

Instead of searching the metal shelves, say "[There] [regarding the shelves][are] cans, jars, and jugs of all shapes and sizes on the shelves. [We]['ll] [need] to be more specific."

Section 1.5 - shelf detritus

A metal-shelf-detritus is a kind of thing. A metal-shelf-detritus has a text called the randomdesc. A metal-shelf-detritus is usually scenery.

Instead of taking a metal-shelf-detritus (called the sample): say the randomdesc of the sample.

Instead of searching a metal-shelf-detritus, try taking the noun.

Understand "random/one/container/containers" as a metal-shelf-detritus.

Section 1.6 - cans

cc-colors printed is initially 0.

cc-content-count is initially 0. [let's cut down on the length of some of these content strings]

half-modifier is initially false.

Some dusty aluminum cans are a metal-shelf-detritus on the metal shelves. They are cc-described "Silver aluminum cans of various sizes (though all cylindrical). None stands out in particular; you could just pick one out to see what it says." They are ambiguously plural.

They have randomdesc "[We] [cc-taking] a [cc-size] can. [cc-can-desc][cc-can-label-desc][cc-final-can].[line break]".

Understand "can/silver" as the dusty aluminum cans.

To pick out is a verb. To grab is a verb. To collect is a verb. To select is a verb. To lift up is a verb. To heft is a verb. To nab is a verb. To consider is a verb. To examine is a verb. To choose is a verb.

Understand [the command] "pick [something]" as taking when the location is MBF3. [Graham! ✊] Understand "choose [something]" as taking when the location is MBF3.

To say cc-taking:

    now cc-content-count is 0;

    say "[one of][pick out][or][grab][or][collect][or][pick] up[or][select][or][take][or][lift up][or][heft][or][nab][or][look] at[or][examine][or][consider][or][choose][at random]"

To say cc-size:

    say "[one of]tall[or]squat[or]short[or]wide[or]narrow[or]nondescript[or]average-sized[or]tiny[or]cute little[or]half-height[or]very large[or]large[or]normal sized[or]typical[or]usual-looking[or]fist-sized[or]bite-sized[or]voluminous[or]tremendously large[or]large[or]massive[or]thin[at random]"

To say cc-can-desc:

    say "[regarding it]It['re] [one of]silver[or]a dull silver[or]tarnished[or]a bit scratched up[or]a bit discolored[or]black on one end[or]black at both ends[or]rusting[or]growing mold on its top[as decreasingly likely outcomes]";

To say cc-can-label-desc:

    now cc-colors printed is 0;

    say "[one of] and missing a label[or], and the [cc-color]label reads [cc-can-label][or], and the label is too faded to read[or], and the [cc-color][cc-color]label reads: [cc-can-label][or], and the [cc-color]label has faded somewhat, but you can just make out [cc-can-label][or], and the label [helping-have] been scribbled over in crayon, but is still legible: [cc-can-label][or] and the label [have] words crossed off in black marker, but you can still make out [cc-can-label][or], and there is no label[or], and the label has been torn off[or] and [cc-color][if cc-colors printed is positive]with [else]has [end if]a [erase color count][cc-color]label that says: [cc-can-label][at random]";

To say cc-color:

    let the old color count be cc-colors printed;

    if a random chance of 2 in 5 succeeds:

        say colorful-and;

        say "[one of]red[or]blue[or]white[or]yellow[or]black[or]green[or]orange[or]brown[or]white[or]silver[or]gold[or]purple[or]gray[or]clear[at random]";

        increment cc-colors printed;

    otherwise if a random chance of 1 in 2 succeeds: [= 3/10 chance from the top]

        say colorful-and;

        say "[one of]sable[or]chartreuse[or]gilded[or]iridescent[or]magenta[or]cyan[or]aqua[or]emerald green[or]pink[or]salmon[or]sepia[or]off-white[or]canary[or]flaxen[or]bronze[or]rose[or]garnet[or]scarlet[or]fuchsia[or]mauve[or]violet[or]lavender[or]lilac[or]periwinkle[or]amethyst[or]slate gray[or]sky blue[or]navy blue[or]indigo[or]teal[or]cobalt[or]sea green[or]azure[or]cerulean[or]sapphire[or]chartreuse[or]lime green[or]olive green[or]seafoam[or]coffee[or]mocha[or]caramel-colored[or]chocolate brown[or]cinnamon[or]pewter[or]slate[or]flint[or]charcoal[or]ebony[or]midnight[or]ink black[or]onyx[or]pitch black[or]sable[or]jet black[or]coal black[or]obsidian[or]jade[or]faint[or]cream[or]chocolate[or]rainbow[or]dingy[or]speckled[or]glittery[or]golden[at random]";

        increment cc-colors printed;

    if cc-colors printed is greater than the old color count, say " ".

To say colorful-and:

    if cc-colors printed is greater than 0:

        say "and ";

To say erase color count:

    now cc-colors printed is 0.

To say cc-can-label:

    say "'[cc-label-first][cc-can-contents]'[cc-label-closer]";

[-------------------------------------------------------------------------------------------------------------------------------]

To say cc-label-first:

    if a random chance of 3 in 5 succeeds:

        say "[one of][cc-superlative][or][cc-owner][or][cc-locative][purely at random] ";

To say cc-superlative:

    if a random chance of 3 in 5 succeeds:

        say "[one of]Fine[or]Quality[or]Excellent[or]Superlative[or]Notable[or]Refined[or]Tasty[or]Delicious[or]High-Quality[or]Prime[or]Premium[or]New[or]New and Improved[or]Classic[or]Original[or]Original Flavor[or]New! Reformulated[or]Same Great Taste[or]Spectacular[or]Delectable[or]Glistening[or]Superb[or]Ideal[or]Photogenic[or]Irradiated[or]Fresh[or]Freshly Harvested[or]Non-Toxic[or]Approved[or]Successfully Passed[or]Passing Grade[or]Top-Grade[or]Kosher[or]Halal[or]Haram[or]Non-Kosher[or]Lent-Safe[or]Not For Lent[or]Heirloom[or]Pure[or]Unrefined[or]Imitation[or]Authentic[or]Wow![run paragraph on][or]Supreme[or]All-Natural[or]Synthetic[or]Moist[or]Luscious[or]Decadent[or][']Talking['][or]Sensible[or]Genuine[or]Family Recipe[or]Farm Fresh[or]Impressive[or]Effervescent[or]Instant[or]Easy-Prep[or]No-Bake[or]Molecular[at random]";

    otherwise:

        say "[one of]Unthinkable[or]Certainly not Poisonous[or]Unimaginable[or]Extra-Sensory[or]Telekinetic[or]DNA-Modifying[or]Radioactive[or]Unobtainable[or]Rotting[or]Decaying[or]Putrid[or]FDA-Adjacent[or]Hollow[or]Anecdotal[or]Imaginary[or]Hypothetical[or]Eerie[or]Non-Potable[or]Sexually Ambiguous[or]Forbidden[or]Writhing[or]Disinterred[or]Graveside[or]Insensate[or]Barking Dogs[or]Surely Healthful[or]Guaranteed Edible[or]Gelatinous[or]Deconstructed[or]Atomic[or]Radium[at random]";

    if a random chance of 1 in 4 succeeds:

        say " [cc-locative]";

To say cc-owner:

    if a random chance of 1 in 4 succeeds:

        say "[cc-location] ";

    if a random chance of 1 in 3 succeeds:

        say "[one of]Gentle[or]Howlin['][or]Big[or]Little[or]Lil['][or]Mr.[run paragraph on][or]Mrs.[run paragraph on][or]Sr.[run paragraph on][or]Sra.[run paragraph on][or]Tiny[or]Handsome[or]Ugly[or]American[or]Killin['][or]Sir[or]Madam[or]Madame[or]Señor[or]Señora[or]Señorita[or]Mysterious[or]General[or]Colonel[or]Captain[or]Professor[or]Admiral[or]Ragin['][or]Killer[or]Wizard[or]Lord[or]Lady[or]The Indomitable[or]Indefatigable[or]Good[or]Bad[at random] ";

    if a random chance of 4 in 11 succeeds:

        say cc-firstname;

    otherwise if a random chance of 4 in 7 succeeds:

        say cc-lastname;

    otherwise: [3/11 chance from top]

        say "[cc-firstname] [cc-lastname]";

    if a random chance of 1 in 3 succeeds:

        say "[one of] the Pirate[or] the Knife[or], esq.[run paragraph on][or] of the Knife[or] the Lost[or] the Found[or] the Eye[or] the Wolf[or] Jr.[run paragraph on][or] Sr.[run paragraph on][or] Jr.[run paragraph on][or] Sr.[run paragraph on][or] III[or] IV[or] V[or] VI[or] the Snake[or] the [cc-loc-adjective][or] of [cc-location][or] from [cc-location][at random]";

    say "[']s";

    if a random chance of 1 in 4 succeeds:

        say " [cc-superlative]";

To say cc-firstname:

    say "[one of]Stoke[or]John[or]Bill[or]Giger[or]Jordham[or]Zileas[or]Tam[or]Sam[or]Pam[or]Roger[or]Tina[or]Fae[or]Jon[or]Yossarian[or]Lee[or]Jardon[or]Herman[or]Willie[or]Susie[or]Tom[or]Satoshi[or]Ash[or]Robel[or]Lois[or]Napoleon[or]Lace[or]Bri[or]Mopsy[or]Verbal[or]Wint[or]Edward[or]Arnold[or]Vervit[or]Vetval[at random]";

To say cc-lastname:

    say "[one of]Willis[or]DaFoe[or]Blix[or]Zinjebal[or]Roget[or]Cunningham[or]Bierline[or]Cordelay[or]Chavez[or]Berkowitz[or]Yardley[or]Vasser[or]Neilsen[or]Hernandez[or]Gold[or]Santa[or]Bluetooth[or]Eckman[or]Freis[or]Maharabi[or]Zanahorias[or]Pepperpot[or]Blackback[or]Bluebeard[or]Sakamoto[or]Cummingham[at random]";

To say cc-locative:

    if a random chance of 3 in 5 succeeds:

        say cc-loc-adjective;

    otherwise:

        say cc-location.

To say cc-loc-adjective:

    if a random chance of 3 in 5 succeeds:

        say "[one of]American[or]All-American[or]Made in America[or]Canadian[or]Mexican[or]Honduran[or]Nicaraguan[or]Cuban[or]Haitian[or]Dominican[or]Venezuelan[or]Togolese[or]Tongan[or]Puerto Rican[or]Hawaiian[or]Bolivian[or]Argentinian[or]Brazilian[or]Ethiopian[or]Eritrean[or]South African[or]Djiboutan[or]Moroccan[or]Nigerian[or]Tunisian[or]Algerian[or]Egyptian[or]Libyan[or]Congolese[or]British[or]Irish[or]Scotch[or]French[or]Spanish[or]Portuguese[or]Occitan[or]Catalonian[or]Breton[or]Vatican[or]Belgian[or]Dutch[or]Danish[or]Swedish[or]Finnish[or]Sami[or]Norwegian[or]Czech[or]Romanian[or]Italian[or]Corsican[or]Sicilian[or]Arabian[or]Croatian[or]Emirati[or]Syrian[or]Iraqi[or]Iranian[or]Pakistani[or]Afghan[or]Indian[or]Bangladeshi[or]Nepalese[or]Mongolian[or]Russian[or]Ukrainian[or]Hungarian[or]Chinese[or]Japanese[or]Korean[or]Laotian[or]Vietnamese[or]Thai[or]Cambodian[or]Icelandic[or]Australian[or]New Zealand[or]Californian[or]Alaskan[or]Florida[or]Cypriot[or]Abyssinian[at random]";

    otherwise:

        say "[one of]Solar[or]Lunar[or]Arrakeen[or]Beyond[or]Out of Time[or]Out of Space[or]Beyond Time and Space[or]Beyond Space and Time[or]Orangian[or]Atlantan[or]Blefuscudian[or]Brobdingnagian[or]Lilliputian[or]Cardassian[or]Romulan[or]Vulcan[or]Akkadian[or]Axumite[or]Babylonian[or]Byzantine[or]Confederate[or]Hunnic[or]Katangese[or]Livonian[or]Manchurian[or]Papal[or]Prussian[or]Rhodesian[or]Roman[or]Siamese[or]Sumerian[or]Soviet[or]Transylvanian[or]Wallachian[or]Yugoslav[or]Zulu[or]Aetolian[or]Aetherian[or]Etherlunar[or]Satanic[or]Pharaonic[or]Ptolemaic[or]Hellenic[or]Persian[or]Achaemenidean[or]Parthian[or]Sassanid[or]Safavid[or]Crusader[or]Exarchate[at random]";

To say cc-location:

    if a random chance of 3 in 5 succeeds:

        say "[one of]Paris[or]Berlin[or]Napa Valley[or]Washington[or]D.C.[run paragraph on][or]Baltimore[or]Boston[or]Madrid[or]Barcelona[or]Lima[or]Santa Domingo[or]Port-au-Prince[or]Havana[or]Kabul[or]Algiers[or]Pago Pago[or]St. John's[or]Yerevan[or]Buenos Aires[or]Georgetown[or]Canberra[or]Perth[or]Vienna[or]Minsk[or]Sarajevo[or]Brasilia[or]Sofia[or]Ottawa[or]Bogotá[or]San José[or]Prague[or]Djibouti[or]Quito[or]Cairo[or]San Salvador[or]Suva[or]Helsinki[or]Accra[or]Gibraltar[or]Athens[or]St. George's[or]Guatemala City[or]Panama City[or]Hong Kong[or]Singapore[or]Bissau[or]Budapest[or]Reykjavík[or]Baghdad[or]Dublin[or]Douglas[or]Jerusalem[or]Rome[or]Kingston[or]Tokyo[or]Nairobi[or]Kuwait City[or]Beirut[or]Monrovia[or]Tripoli[or]Valdez[or]Luxembourg[or]Mexico City[or]Monaco[or]Venice[or]Corsica[or]Ulaanbaatar[or]Maputo[or]Wellington[or]Saipan[or]Islamabad[or]Asunción[or]Port Moresby[or]Lima[or]Manila[or]Warsaw[or]Lisbon[or]Kingstown[or]Queenstown[or]Victoria[or]Belgrade[or]Bratislava[or]Ljubljana[or]Mogadishu[or]New York[or]Dallas[or]Houston[or]Hollywood[or]Los Angeles[or]San Francisco[or]Miami[or]Detroit[or]Minneapolis[or]Juba[or]Madrid[or]Khartoum[or]Stockholm[or]Damascus[or]Taipei[or]Bangkok[or]Tunis[or]Ankara[or]Kiev[or]Abu Dhabi[or]London[or]Montevideo[or]Vatican City[or]Caracas[or]Hanoi[or]Harare[or]Moscow[at random]";

    otherwise:

        say "[one of]Mirror[or]Arkham[or]Abyss[or]Elysium[or]Utopia[or]Dystopia[or]Erewhon[or]Purple Cloud[or]Robot[or]Kallocain[or]Animal Farm[or]Null-A[or]Heliopolis[or]Oz[or]Fahrenheit 451[or]Steel Cave[or]Atlas[or]Babylon[or]Naked Sun[or]Sodom[or]Gomorrah[or]High Castle[or]Asylum[or]R'lyeh[or]Neo Tokyo[or]New New York[or]Lathe of Heaven[or]Iron Dream[or]Forever War[or]Highrise[or]Dark Tower[or]Dark Scanner[or]Fatherland[or]Motherland[or]Atlantis[or]Amnesia Moon[or]Snow Crash[or]Giver[or]Cloud Atlas[or]Road[or]Incarceron[or]Sapphique[or]Rondo[or]Shimoneta[or]Bone Season[or]Metropolis[or]Alphaville[or]Omega Man[or]Zardoz[or]Outland[or]Terminator[or]Headroom[or]Millennium[or]Freejack[or]Fortress[or]Stand[or]Ghost in the Machine[or]Mnemonic[or]Matrix[or]Gattaca[or]Dark City[or]Existenz[or]Matrix[or]Equilibrium[or]District 9[or]Fallout[or]Wasteland[or]Oblivion[or]Unbreakable[or]Nadsat[or]Gaol[or]Dune[or]Asteroid[or]Planetoid[or]Moon[or]Sun[or]Carthage[or]Korhal[or]Gormenghast[or]Lud[or]Pandemonium[or]Malgudi[or]Mariposa[or]Opar[or]Yian[or]El Dorado[or]Hell[or]Shangri-La[at random]";

[-------------------------------------------------------------------------------------------------------------------------------]

To say cc-can-contents:

    say cc-adj-modifier;

    say "[one of][cc-fruit][or][cc-veg][or][cc-fruit][or][cc-veg][or][cc-meat][or][cc-misc][purely at random]";

    if a random chance of 1 in 5 succeeds, say cc-can-termination-with-in;

To say cc-adj-modifier:

    if a random chance of 2 in (4 + cc-content-count) succeeds: [prevent some of the most ludicrous extended food-item descriptors]

        if half-modifier is true:

            increment cc-content-count;

            now half-modifier is false; [toggle this count every time we print a modifier]

        otherwise:

            now half-modifier is true;  [toggle: only every other food-adjective increases the count, since I do want some doubling up of them]

        say "[one of]Spiced[or]Cinnamon[or]Pepper[or]Deviled[or]Pickled[or]Diced[or]Chopped[or]Fine[or]Halved[or]Quartered[or]Sliced[or]Cubed[or]Assorted[or]Reconstituted[or]Salt[or]Peeled[or]Non-Euclidean[or]Fully Cooked[or]Whole[or]Shaved[or]Sugar Free[or]Fried[or]Breaded[or]Chocolate[or]Vanilla[or]Sodium Free[or]No Sugar Added[or]Grilled[or]Congealed[or]Candied[or]Toasted[or]Roasted[or]Parboiled[or]Boiled[or]Steamed[or]Fermented[or]Distilled[or]Filtered[or]Reconstructed[or]Cored[or]Dessicated[or]Dried[or]Mechanically Separated[or]Hydroponic[or]Cage-Free[or]Free-Range[or]Curdled[or]Caramel[or]Sugared[or]Double Boiled[or]Double Cooked[or]Raw[or]Peanut Butter[or]Shredded[or]Baked[or]Broiled[or]Roast[or]Sun-Dried[or]Braised[or]Non-Cartesian[or]Sour[or]Sweet[or]Bitter[or]Bittersweet[or]Maple[or]Espresso[or]Coffee[or]Cappuccino[or]Macchiato[or][at random] ";

        if a random chance of 2 in 5 succeeds: [= 4/25 chance from top]

            say cc-adj-modifier;

        otherwise if a random chance of 1 in 4 succeeds: [= 6% chance from top]

            say "[cc-locative] ";

To say cc-fruit:

    increment cc-content-count;

    if a random chance of 3 in 5 succeeds:

        say "[one of]Pear[or]Peach[or]Plum[or]Apricot[or]Apple[or]Applesauce[or]Pineapple[or]Tomato[or]Orange[or]Tangerine[or]Banana[or]Grapes[or]Blackberry[or]Blueberry[or]Raspberry[or]Strawberry[or]Date[or]Mango[or]Coconut[or]Coconut Milk[or]Coconut Water[or]Kiwifruit[or]Lemon[or]Lime[or]Honeydew[or]Cantaloupe[or]Grapefruit[or]Watermelon[or]Pomegranate[or]Pecan[or]Walnut[or]Almond[or]Cashew[or]Licorice[or]Peanut[or]Rhubarb[or]Mixed Fruit[or]Mixed Berry[or]Melon[at random]";

    otherwise:

        say "[one of]Starfruit[or]Sunfruit[or]Cinnamon Sticks[or]Durian[or]Jackfruit[or]Papaya[or]Passionfruit[or]Dragon Fruit[or]Feijoa[or]Tamarind[or]Loquat[or]Longan[or]Lychee[or]Mulberry[or]Blackcurrant[or]Breadfruit[or]Ice Cream Fruit[or]Miracle Fruit[or]Kiwano[or]Mangosteen[or]Kumquat[or]Cupuaçu[or]Rambutan[or]Snake Fruit[or]Langsat[or]Cucamelon[or]Soursop[or]Sour Plum[or]Aguaje[or]Pepino[or]Plantain[or]Persimmon[or]Sasparilla[or]Sapodilla[or]Pomelo[or]Guava[or]Water Apple[or]Horned Melon[or]Ackee[or]Akebi[or]Pitaya[or]Salak[or]Buddha's Hand[or]Chocolate Pudding Fruit[or]Jaboticaba[or]Achiote[or]Markut Lime[or]Peria[or]Custard Apple[or]Sawo[or]Physalis[or]Dandalan[or]Calamansi[or]Kepel Fruit[or]Watermelon Radish[or]Puhala[or]False Banana[or]Fruit[or]Tapioca[or]Manioc[or]Blood Orange[or]Persimmon[at random]";

    if a random chance of 1 in (4 + cc-content-count) succeeds:

        say " [cc-also] [cc-adj-modifier][cc-fruit]";

    otherwise if a random chance of 1 in (4 + cc-content-count) succeeds:

        say " [cc-also] [cc-adj-modifier][cc-veg]";

    otherwise if a random chance of 1 in (4 + cc-content-count) succeeds:

        say " [cc-also] [cc-meat]";

    otherwise if a random chance of 1 in (5 + cc-content-count) succeeds:

        say " [cc-meat]";

To say cc-also:

    say "[one of]and[or]with[or]plus[or]&[or]+[or]y[or]et[or]de[or]of[as decreasingly likely outcomes]";

To say cc-veg:

    increment cc-content-count;

    if a random chance of 3 in 5 succeeds:

        say "[one of]Potato[or]Sweet Potato[or]Spinach[or]Carrots[or]Pepper[or]Paprika[or]Chili[or]Green Bean[or]Broccoli[or]Cauliflower[or]Peas[or]Ginger[or]Garlic[or]Onion[or]Leek[or]Corn[or]Wheat[or]Spelt[or]Rye[or]Barley[or]Buckwheat[or]Rice[or]Cabbage[or]Artichoke[or]Brussels Sprouts[or]Red Bean[or]Kidney Bean[or]Lima Bean[or]Mixed Bean[or]Chickpea[or]Mushroom[or]Tofu[or]Olive[or]Cucumber[or]Pickle[or]Brown Rice[or]Whole Wheat[or]Sesame Seed[or]Poppyseed[or]Avocado[or]Mixed Nuts[or]Mint[or]Vanilla Bean[or]Cloves[or]Nutmeg[at random]";

    otherwise:

        say "[one of]Radish[or]Green Onion[or]Green Tomato[or]Samphire[or]Purple Carrot[or]Parsnip[or]Turnip[or]Ghost Pepper[or]Eggplant[or]Purple Sweet Potato[or]Artichoke[or]Romanesco Broccoli[or]Chives[or]Bay Leaf[or]Rose Petals[or]Nettles[or]Poison Ivy[or]Poison Oak[or]Poison Sumac[or]Honeysuckle[or]Banana Leaf[or]Willow[or]Oak[or]Reed[or]Lilac[or]Lemongrass[or]Switchgrass[or]Rubber Plant[or]Dandelion[or]Nuts[or]Flaxseed[or]Kimchi[at random]";

    if a random chance of 1 in (4 + cc-content-count) succeeds:

        say " [cc-also] [cc-veg]";

    otherwise if a random chance of 1 in (4 + cc-content-count) succeeds:

        say " [cc-also] [cc-fruit]";

    otherwise if a random chance of 1 in (4 + cc-content-count) succeeds:

        say " [cc-also] [cc-meat]";

    otherwise if a random chance of 1 in (5 + cc-content-count) succeeds:

        say " [cc-meat]";

To say cc-meat:

    increment cc-content-count;

    if a random chance of 3 in 5 succeeds:

        say "[one of]Beef[or]Chicken[or]Chicken Breast[or]Chicken Leg[or]Lamb[or]Goat[or]Chicken[or]Beef[or]Ground Beef[or]Hen[or]Corned Beef[or]Pork[or]Bacon[or]Ham[or]Chili[or]Fish[or]Tuna[or]Salmon[or]Oyster[or]Sardine[or]Mussel[or]Calamari[or]Venison[or]Clam[or]Fish[or]Salami[or]Sausage[or]Ground Pork[or]Shrimp[or]Duck[at random]";

    otherwise:

        say "[one of]Dog[or]Cat[or]Cow[or]Bull[or]Rooster[or]Rat[or]Mouse[or]Snake[or]Gator[or]Crocodile[or]Earthworm[or]Ox[or]Longpig[or]Demon[or]Cricket[or]Cockroach[or]Centipede[or]Millipede[or]Rattlesnake[or]Human[or]Adult Male[or]Adult Female[or]Infant[or]Newborn[or]Neverborn[or]Toddler (Male)[or]Toddler (Female)[or]Hellhound[or]Imp[or]Spider[or]Fly[or]Unicorn[or]Giant[or]Leprechaun[or]Dragon[or]Dragonfly[or]Centaur[or]Leviathan[or]Owl[or]Hawk[or]Eagle[or]Sparrow[or]Crow[or]Raven[or]Roadrunner[or]Wolf[or]Grizzly[or]Musk Ox[or]Yak[or]Fox[or]Kangaroo Mouse[or]Snail[or]Pigeon[or]Squid[or]Muskrat[or]Dove[or]Sea Sponge[or]Sea Cucumber[or]Meat[or]Poultry[or]Peacock[or]Ostrich[or]Veal[or]Foie Gras[or]Blood Sausage[or]Blue Whale[or]Giant Squid[or]Orca[or]Jellyfish[or]Man-o-War[or]Pufferfish[or]Stork[or]Vulture[or]Viper[at random]";

    if a random chance of 1 in 4 succeeds, say " [one of]Chunks[or]Pieces[or]Skin[or]Gristle[or]Bone[or]Tail[or]Collar[or]Fat[or]Marrow[or]Feet[or]Milk[or]Cheese[or]Butter[or]Nail[or]Hair[or]Blood[or]Venom[or]Pustules[or]Buboes[or]Pus[or]Leakings[or]Nipples[or]Shavings[or]Scrapings[or]Dirt[or]Extract[or]Plasma[or]Screams[or]Knuckles[or]Innards[or]Maw[or]Stomach[or]Offal[or]Liver[or]Lungs[or]Brains[or]Eyeballs[or]Wings[or]Tendons[or]Gelatin[or]Excrement[or]Saliva[or]Rump[or]Shanks[or]Chops[or]Tentacles[or]Husks[or]Egg[or]Grease[or]Smear[or]Scales[or]Blood[or]Squeezings[or]Leakage[or]Heart[or]Spleen[or]Pancreas[or]Gullet[or]Steaks[or]Ankles[or]Neck[or]Gut[or]Haunches[or]Sausage[or]Blood Sausage[at random]";

    if a random chance of 1 in (3 + cc-content-count) succeeds:

        say " [cc-also] [cc-adj-modifier][cc-meat]";

    otherwise if a random chance of 1 in (4 + cc-content-count) succeeds:

        say " [cc-also] [cc-adj-modifier][cc-veg]";

    otherwise if a random chance of 1 in (3 + cc-content-count) succeeds:

        say " [cc-also] [cc-adj-modifier][cc-fruit]";

    otherwise if a random chance of 1 in (4 + cc-content-count) succeeds:

        say " [cc-also] [cc-misc]";

To say cc-misc:

    increment cc-content-count;

    if a random chance of 3 in 5 succeeds:

        if a random chance of 2 in 5 succeeds:

            say "[cc-fruit] ";

        otherwise if a random chance of 2 in 3 succeeds:

            say "[cc-veg] ";

        say "[one of]Bread[or]Fruitcake[or]Pound Cake[or]Cake[or]Pie[or]Cookies[or]Chips[or]Fries[or]Lasagna[or]Pasta[or]Spaghetti[or]Noodles[or]Fettuccine[or]Omelette[or]Dumplings[or]Casserole[or]Spread[or]Gravy[or]Dip[or]Salsa[or]Topping[or]Pâté[or]Frosting[or]Relish[or]Chutney[or]Crème Brûlée[or]Cereal[or]Muesli[or]Trail Mix[or]Upside-Down Cake[or]Salad[or]Flakes[or]Fudge[at random]";

    otherwise:

        say extremely unusual things to preserve;

    [why did I add these things down here:]

    if a random chance of 1 in (3 + cc-content-count) succeeds:

        say " [cc-also] [cc-adj-modifier][cc-meat]";

    otherwise if a random chance of 1 in (4 + cc-content-count) succeeds:

        say " [cc-also] [cc-adj-modifier][cc-veg]";

    otherwise if a random chance of 1 in (3 + cc-content-count) succeeds:

        say " [cc-also] [cc-adj-modifier][cc-fruit]";

    otherwise if a random chance of 1 in (4 + cc-content-count) succeeds:

        say " [cc-also] [cc-misc]";

To say extremely unusual things to preserve:

    say "[one of]Dust[or]Torment[or]Human Tears[or]Despair[or]Desperate Longing[or]Forgotten Dreams[or]Lost Hope[or]Crushing Defeat[or]Disgust[or]Used Dishrag[or]Misplaced Housekeys[or]Cries of a Small Child[or]Revenge[or]Loss[or]Murderous Intent[or]Manslaughter[or]Poison[or]Withdrawal[or]Reproach[or]Burning Rage[or]Pain[or]Concentrated Misery[or]Loathing[or]Charcoal[or]Ash[or]Spent Battery[or]Depleted Uranium[or]Buckshot[or]Baptismal Water[or]Soap[at random]";

To say cc-can-termination-with-in:

    if a random chance of 2 in 5 succeeds:

        increment cc-content-count;

        if a random chance of 1 in (2 + cc-content-count) succeeds:

            say cc-largely-liquid-noun;

        say " [one of]in Brine[or]in[if a random chance of 2 in 5 succeeds] [cc-meat][end if][cc-terminal-jar-modifier][or]in Juice[or]in Syrup[or]in Oil[or]in Water[or]in Spring Water[or]in Aspic[or]in Tomato Sauce[or]in Vinegar[or]in Coconut Milk[or]in Coconut Water[or]in Distilled Water[or]in Ionized Water[or]in Rosewater[or]in Gin[or]in Bourbon[or]in White Wine[or]in Red Wine[or]in Milk[at random]";

        if a random chance of 1 in (2 + cc-content-count) succeeds, say cc-can-termination-without-in;

    otherwise:

        say cc-can-termination-without-in;

To say cc-can-termination-without-in:

    increment cc-content-count;

    if a random chance of 1 in (2 + cc-content-count) succeeds:

        say cc-largely-liquid-noun;

    say " [one of]with Skin[or](water added)[or]Spirals[or]Slices[or]Knobs[or]Curls[or]Waves[or]Butter[or](artificial flavor)[or](plus natural and artificial flavor)[or]Rind[or]Mix[or]Jelly[or]Slurry[at random]";

    if a random chance of 1 in (2 + cc-content-count) succeeds, say cc-can-termination-without-in;

To say cc-largely-liquid-noun:

    increment cc-content-count;

    say " [one of]Juice[or]Brine[or]Drink[or]Syrup[or]Oil[or]Water[or]Extract[or]Pureé[or]Milk[or]Sauce[or]Liquid[or]Drippings[or]Sauce[or]Distillation[or]Broth[or]Gravy[or]Nectar[or]Ambrosia[or]Marmalade[or]Preserves[or]Potion[or]Pudding[or]Soda[or]Wine[or]Beer[or]Vodka[or]Kombuchea[or]Tea[or]Coffee[or]Cream[or]Milkshake[or]Froth[or]Reduction[or]Horchata[or]Margarita[or]Gimlet[or]Julep[or]Daiquiri[or]Ice[or]Sour[or]Draught[or]Imbibement[or]Tonic[or]Slush[or]Zest[or]Foam[at random]";

[-------------------------------------------------------------------------------------------------------------------------------]

To hang is a verb. To make is a verb. To squirm is a verb.

To say cc-label-closer:

    if a random chance of 2 in 5 succeeds:

        say ". [regarding it][one of]The label [are] scuffed[or]The label [are] cracked and peeling[or]The label [are] discolored[or]The label [hang] off at an angle[or]The font [make] [us] uneasy[or]The text [squirm] when [regarding yourself][we] [don't] [look] directly at it[or]The illustration [are] disgusting[or]The image printed on it [are] all wrong[at random]";

To feel is a verb. To rattle is a verb.

To say cc-final-can:

    now cc-colors printed is 0;

    if a random chance of 3 in 5 succeeds:

        say ". [regarding it][one of]It [are] otherwise unremarkable[or]It [are] fairly scuffed up[or]It [are] exceptionally shiny[or]It [are] dented on the side[or]The lid [are] bulging[or]There['re] a black streak down one side[or]It [feel] oddly heavy[or]It [feel] entirely too light[or]It [rattle] in [our] hand[or]The can [are] dented on two sides[or]It [are] ugly and misshapen[or]Something [cc-color][are] oozing from one end[as decreasingly likely outcomes]";

    say cc-final-final.

To replace is a verb.

To say cc-final-final:

    if a random chance of 2 in 3 succeeds:

        say ". [one of]Then [we] [put] it back[or][We] [replace] it[or]Useless. [We] [put] it back[or]No value to [us][or][We]['re] not interested[or]Obviously worthless[as decreasingly likely outcomes]"

Section 1.7 - jars

To stand is a verb.

Some dusty glass jars are a metal-shelf-detritus on the metal shelves. They are ambiguously plural. Understand "jar/glasses/plastic/ceramic/clay" and "jar/jars section" as the dusty glass jars.

They are cc-described "Jars of a dizzying array of sizes and shapes and colors. At least [regarding the jars][they] [seem] to be organized by contents; fruit here, vegetables there, liquids on the bottom[if cc-puzzle is false]. Nothing [regarding it][stand] out, so [we] [could] just pick one at random[end if]."

They have randomdesc "[We] [cc-taking] a [cc-size] jar. [cc-jar-desc][cc-jar-label-desc][cc-final-jar].[line break]".

Instead of taking the dusty glass jars when cc-puzzle is true and the jar of peaches is not cc-avail, try searching the noun.

To say cc-jar-desc:

    now cc-colors printed is 0;

    say "[regarding it]It[one of]['re] made of [cc-jar-surface][or]['re] made from [cc-jar-surface][or]s surface [are] [cc-jar-surface][or] is of [cc-jar-surface][as decreasingly likely outcomes] [cc-color][cc-color][one of]plastic[or]glass[or]ceramic[or]clay[as decreasingly likely outcomes]";

To say cc-jar-surface:

    say "[one of]thin[or]thick[or]translucent[or]transparent[or]opaque[at random]";

To say cc-jar-label-desc:

    now cc-colors printed is 0;

    say "[one of] and missing a label[or], and the [cc-color]label reads [cc-jar-label][or], and the label is too faded to read[or], and the [cc-color]label reads: [cc-jar-label][or], and the [cc-color]label has faded somewhat, but you can just make out [cc-jar-label][or], and the label [helping-have] been scribbled over in crayon, but it['re] still legible: [cc-jar-label][or] and the label [have] words crossed off in black marker, but you can still make out [cc-jar-label][or], and there is no label[or], and the label has been torn off[or] and [cc-color][if cc-colors printed is positive]with [else]has [end if]a [erase color count][cc-color]label that says: [cc-jar-label][or], and unlabeled[or], and the hand-written label reads: [cc-jar-label][or], and in thick, scrawling handwriting, the jar is labeled: [cc-jar-label][at random]";

To slosh is a verb. To cut is a verb.

To say cc-jar-label:

    say "'[cc-label-first][cc-jar-contents]'[cc-label-closer]";

To say cc-jar-contents:

    if a random chance of 2 in 5 succeeds, say cc-adj-modifier;

    say "[one of][cc-fruit][or][cc-veg][or][cc-meat][or][extremely unusual things to preserve][as decreasingly likely outcomes]";

    if a random chance of 4 in 5 succeeds, say cc-terminal-jar-modifier;

To say cc-terminal-jar-modifier:

    increment cc-content-count;

    if a random chance of 1 in (7 + cc-content-count) succeeds, say cc-can-termination-with-in;

    if a random chance of 3 in 4 succeeds:

        say cc-largely-liquid-noun;

    otherwise:

        say " [one of]Stew[or]Curry[or]Spread[or]Congee[or]Porridge[or]Gruel[or]Custard[or]Flan[or]Soup[at random]";

    if a random chance of 1 in (5 + cc-content-count) succeeds, say cc-terminal-jar-modifier.

To say cc-final-jar:

    now cc-colors printed is 0;

    if a random chance of 3 in 5 succeeds:

        say ". [regarding it][one of]It [are] otherwise unremarkable[or]Its sides [regarding the dusty glass jars][are] fairly scuffed[or]The jar's surface [are] exceptionally rough[or]It [are] scratched on one side[or]A long scratch [cut] all the way around the center of the jar[or]The lid [are] bulging[or]There['re] a dark [cc-color]streak down one side[or]It [feel] oddly heavy[or]It [feel] entirely too light[or]It [rattle] in [our] hand[or]The jar [are] chipped in two places[or]It [are] misshapen and deformed[or]The contents [regarding the dusty jars][slosh] in [our] hand[or]It [are] scratched all over[or]Its sides [regarding the dusty glass jars][are] deeply scored[or]The top [are] cracked[or]The lid [are] stuck shut[or]A crack [run] along the bottom[or]Something [cc-color][are] oozing from the bottom[or]The jar [are] cracked down the middle[as decreasingly likely outcomes]";

    say cc-final-final.

Section 1.8 - jugs

Some dusty clay jugs are a metal-shelf-detritus on the metal shelves. They are ambiguously plural. Understand "ceramic/clay" as the dusty jugs.

They are cc-described "Jugs of many different sizes, shapes, and colors. Most are too large to fit on the shelves, so they're arranged below them on the floor. None of them [regarding it][stand] out, so [we] [could] just choose one at random."

They have randomdesc "[We] [cc-taking] a [cc-size] jug. [cc-jug-desc][cc-jug-label-desc][cc-final-jug].[line break]".

Understand "jug/ceramic/porcelain" as the dusty jugs.

To say cc-jug-desc:

    now cc-colors printed is 0;

    say "[regarding it]It[one of]['re] made of [cc-jug-surface][or]['re] made from [cc-jug-surface][or]s [cc-jug-surface] surface [are][or] is of [cc-jug-surface][as decreasingly likely outcomes] [cc-color][cc-color][one of]ceramic[or]clay[or]porcelain[as decreasingly likely outcomes]";

To say cc-jug-surface:

    say "[one of]thin[or]thick[or]reflective[or]pitted[or]scorched[or]glazed[or]raw, unglazed[or]dark[or]light[or]clear-coated[or]painted[at random]";

To say cc-jug-label-desc:

    now cc-colors printed is 0;

    say "[one of] and missing a label[or], and the [cc-color]label reads [cc-jug-label][or], and the label is too faded to read[or], and the [cc-color]label reads: [cc-jug-label][or], and the [cc-color]label has faded somewhat, but you can just make out [cc-jug-label][or], and the label [helping-have] been scribbled over in crayon, but it['re] still legible: [cc-jug-label][or] and the label [have] some words crossed off in black marker, but you can still make out [cc-jug-label][or], and there is no label[or], and the label has been torn off[or] and [cc-color][if cc-colors printed is positive]with [else]has [end if]a [erase color count][cc-color]label that says: [cc-jug-label][or] and unlabeled[or], and the hand-written label reads: [cc-jug-label][or], and in thick, scrawling handwriting, the jug is labeled: [cc-jug-label][at random]";

To slosh is a verb. To cut is a verb.

To say cc-jug-label:

    say "'[cc-label-first][cc-jug-contents]'[cc-label-closer]";

To say cc-jug-contents:

    if a random chance of 2 in 5 succeeds, say cc-adj-modifier;

    say "[one of][cc-fruit][or][cc-veg][or][cc-meat][or][extremely unusual things to preserve][as decreasingly likely outcomes]";

    if a random chance of 4 in 5 succeeds, say cc-terminal-jug-modifier;

To say cc-terminal-jug-modifier:

    increment cc-content-count;

    if a random chance of 1 in (6 + cc-content-count) succeeds, say cc-terminal-jar-modifier;

    say cc-largely-liquid-noun;

    if a random chance of 1 in (4 + cc-content-count) succeeds, say cc-terminal-jug-modifier.

To say cc-final-jug:

    now cc-colors printed is 0;

    if a random chance of 3 in 5 succeeds:

        say ". [regarding it][one of]It [are] otherwise unremarkable[or]Its sides [regarding the dusty jugs][are] fairly scuffed[or]The jug's surface [are] exceptionally rough[or]It [are] scratched on one side[or]A long scratch [cut] all the way around the center of the jug[or]The stopper [are] bulging[or]There['re] a dark [cc-color]streak down one side[or]It [feel] oddly heavy[or]It [feel] entirely too light[or]The jug [are] chipped in two places[or]It [are] misshapen and deformed[or]The contents [regarding the dusty jugs][slosh] in [our] hand[or]It [are] scratched all over[or]Its sides [regarding the dusty jugs][are] deeply scored[or]The top [are] cracked[or]The cork [are] stuck tight[or]A crack [run] along the bottom[or]Something [cc-color][are] oozing from the bottom[or]The jug [are] cracked down the middle[as decreasingly likely outcomes]";

    say cc-final-final.

Section 1.9 - stones

Some flat dark stones are scenery in MBF3, cc-described "Each stone [regarding it][are] about the size of [our] hand, smooth, and somewhat rounded." Understand "floor" as the dark stones. Understand "stone" as the dark stones.

Section 1.10 - light bulb

The cc-light bulb is a lit scenery fixed in place privately-named thing in MBF3, cc-described "Just a bare bulb suspended on a wire from the ceiling." Understand "bare/light/bulb" as the cc-light bulb. It has printed name "bare light bulb".

To find is a verb.

Instead of switching off the cc-light bulb: say "[We] [can't find] any light switch."

Instead of doing something other than examining to the cc-light bulb, say "[We] [don't need] to change the bulb[first time]. Nor [do] [we] want to[only]."

The cc-thin wire is part of the cc-light bulb. It is cc-described "A thin wire helix running from the ceiling down to the bulb." It has printed name "thin suspended wire". Understand "thin/suspended/wire/line/helix" as the cc-thin wire.

Instead of doing something other than examining to the cc-thin wire, say "[It's] too delicate."

Section 1.11 - ceiling

To appear is a verb.

The cc-ceiling is a scenery fixed in place thing in MBF3, cc-described "[regarding it]Actually, it [appear] to be the exposed floorboards of the level above [us]. Every so often, a bit of dust filters down from above." It has printed name "ceiling".

Instead of doing anything other than examining with the cc-ceiling, say "It's too high above you." Understand "ceiling" as the cc-ceiling.

Section 1.12 - dust

The cc-dust is a scenery thing in MBF3, cc-described "It's everywhere." Understand "dust" as the cc-dust. It has printed name "dust".

Instead of taking the cc-dust, say "Too late for that."

Understand "blow [something]" as rubbing when the location is MBF3. Instead of rubbing the cc-dust, say "Futile. It's everywhere."

Chapter 2 - Peach Puzzle

Section 2.1 - the jar of peaches

The jar of peaches is an openable closed container. It is cc-described "A squat glass jar of a reddish hue, a bit larger than your hand, with a red metal top. The label has long since faded into unintelligibility, but there is no doubt that the oblong shapes suspended in the golden liquid are peeled and quartered peaches." It is undescribed. Understand "pickle/picked/reagent/container" as the jar of peaches.

Does the player mean taking the not handled jar of peaches: it is very likely.

Does the player mean eating the jar of peaches: it is very unlikely.

Does the player mean entering the jar of peaches: it is likely.

Instead of searching the dusty jars when cc-puzzle is true and the jar of peaches is not handled:

    say "Soon enough, you stumble across what must be [the jar of peaches] mentioned in Edmund's message. You pick it up.";

    now the player carries the jar of peaches;

    set pronouns from the jar of peaches.

Instead of searching the metal shelves, try searching the dusty jars.

Section 2.2 - golden peach liquid

The golden peach liquid is in the jar of peaches. It has indefinite article "some[first time] sort of[only]". Understand "juice/pickle-juice/water/goo/pickle/pickling/brine/salt/salty/water/gold" as the golden peach liquid. It is cc-described "A strange golden-hued liquid, shimmering in the light of [the random visible lit thing]."

Instead of taking the golden peach liquid, say "You have an inkling, somehow, tickling the back of your skull that emptying out this container would have a negative effect on the world, and your place in it. You refrain."

Instead of eating the golden peach liquid, try tasting the noun. Instead of drinking the golden peach liquid, try tasting the noun. Instead of drinking the open jar of peaches, try drinking the golden peach liquid.

Does the player mean drinking or tasting the golden peach liquid: it is likely.

Instead of drinking the closed jar of peaches:

    say "(first opening [the noun])[command clarification break]";

    silently try opening the noun;

    if the noun is open, try drinking the golden peach liquid instead.

Instead of tasting the golden peach liquid, say "You bring the shimmering golden pickle-juice to your lips and take a sip. It is both salty and sweet. And... something else. Something you can't quite place[first time].[paragraph break]Great. Now you're the type of person who drinks from a jar.[paragraph break]Also, the type of person who drinks ancient pickled fruit brine of uncertain provenance[only]."

Instead of inserting something into the golden peach liquid, try inserting the noun into the jar of peaches.

To pop is a verb. To bite is a verb.

Section 2.3 - the pickled peaches

Some pickled peaches are fixed in place in the golden peach liquid, cc-described "Orange pickled peach quarters. They [regarding the pickled peaches][look] delectable." Understand "peach/pickle/pickles/quarter/quartered/quarters/orange" as the pickled peaches.

Does the player mean doing something with the pickled peaches: it is very likely.

Instead of eating the pickled peaches, say "[We] [pop] one into [our] mouth. The pickled quarter of peach [regarding it][are] small and delicate, silky smooth, and as [we] [bite] into it it releases an incredible juice[first time].[paragraph break][We] [feel] energized[only]."

Instead of taking the pickled peaches, say "[We][']d rather not."

Instead of tasting the pickled peaches, try eating the noun.

To want is a verb. To stick is a verb. To wish is a verb.

Understand "climb into/in/inside [something]" and "jump in/into/inside [something]" as entering when the location is MBF3.

Section 2.4 - diving

The enticing peach brine count is initially 0. The pickle peach spacer is initially 1.

Every turn when the open jar of peaches is enclosed by the location and MBF3jar is unvisited:

[    say "epb [enticing peach brine count]; pps [pickle peach spacer]; ";]

    if a random chance of the enticing peach brine count in (pickle peach spacer + the enticing peach brine count) succeeds and cc-message-printed is false:

        now the enticing peach brine count is 0;

        now cc-message-printed is true; [Don't display both of these hint messages in a single turn]

        increment the pickle peach spacer; [The more peach urge messages you've already seen, the less often you should see more]

        increment the jar-spacer;

        say "[one of][We] [feel] drawn to [the jar of peaches][or][We] [want] to stick [our] face in that peach brine[or][We] [have] an irrational urge to climb inside [the jar of peaches][or][We] wish [we] could just climb inside that [jar of peaches][or][We] [have] a craving to dive inside [the jar of peaches][or][We] [want] to just curl up inside that [jar of peaches][cycling].";

    otherwise:

        increment the enticing peach brine count.

Understand "dive [something]" and "dive in/into/inside [something]" as entering when the jar of peaches is cc-avail.

Instead of entering the closed jar of peaches:

    say "The lid[regarding it]['re] still on it."

Understand "face/head/skull/self" and "my face/head/skull/self" as yourself when the location is MBF3.

Understand "stick [something] in/inside/into [something]" as inserting it into when the location is MBF3.

Before inserting yourself into the open jar of peaches, try entering the jar of peaches instead.

Before entering the open jar of peaches:

    say "You stick your head in, and suddenly you find yourself falling down, down, down...";

    say paragraph break;

    say "Splash.";

    now the jar of peaches is in the location;

    now the jarful place of the gilded room is word number 1 in the substituted form of "[the location]";

    let JF2 be punctuated word number 2 in the substituted form of "[the location]";

    if JF2 is part of a room name:

        now the jarfuller place of the gilded room is " [JF2]";

        let JF3 be punctuated word number 3 in the substituted form of "[the location]";

        if JF3 is part of a room name:

            now the jarfullest place of the gilded room is " [JF3]";

        otherwise:

            now the jarfullest place of the gilded room is "";

    otherwise:

        now the jarfuller place of the gilded room is "";

        now the jarfullest place of the gilded room is "";

[    showme the jarful place of the gilded room;]

    now the player is Pickled Naomi;

    try looking.

To decide if (T - a text) is part of a room name:

    if T is empty, decide no;

    if T matches the regular expression "^\p", decide no;

    decide yes.

    [ya'll better not have any non-conforming room names I tell you what]

Instead of entering the golden peach liquid, try entering the jar of peaches.

Instead of entering the pickled peaches, try entering the jar of peaches.

Instead of entering the dusty jars when the jar of peaches is cc-avail, try entering the jar of peaches.

Chapter 3 - The Pickling

Definition: a thing is non-cc if it is not yourself and it is not the jar of peaches and it is not cc-imagination and it is not the fat black flies.

[Whoops shouldn't see your former self, or the jar of peaches itself, or the air or fake things like the lack of cobwebs, from inside the jar...]

[also the flies keep eating the implicit-greeting, stop that]

Section 3.0 - Pickle-room

There is a room called MBF3jar. "[We] [are] immersed in peach pickling brine. Everything around [us] [Regarding it][are] a brilliant golden hue. [We] [have] no idea how exactly [we] got in here or how [we] could possibly fit. And even though [we] have not made a particular habit of failing to breathe underwater, right now it just feels unnecessary. [paragraph break]The looming shapes of [the random non-cc thing in the location of the jar of peaches] and the rest of the [full-jar place-name of the gilded room in lower case] are barely recognizable through the gilded distortions of the brine and intervening glass." It has printed name "Inside the Jar of Pickled Peaches".

The gilded room is a scenery thing in MBF3jar. It is cc-described "All [we] can see of the [full-jar place-name in lower case] outside the jar [are] just so many shapeless golden blobs."

It has a text called the jarful place. The jarful place is initially "pantry". Understand the jarful place property as describing the gilded room.

It has a text called the jarfuller place. Understand the jarfuller place property as describing the gilded room.

It has a text called the jarfullest place. Understand the jarfullest place property as describing the gilded room.

It has a text called the full-jar place-name. The full-jar place-name is initially "[jarful place][jarfuller place][jarfullest place]".

After deciding the scope of the player when the location is MBF3jar:

    repeat with thingus running through non-cc things in the location of the jar of peaches:

        place the thingus in scope.

        [I have had very little excuse to play around with scope. This gonna be fun]

To say (T - a text) in lower case:

    say T in lower case. [🙄]

Instead of listening when the location is MBF3jar:

    say "You can't really hear anything in this muck. All sounds are dulled, bassy and unclear."

Section 3.1 - pickled naomi

To prove is a verb.

Pickled Naomi is a woman in MBF3jar. She is cc-described "[We] [are] [now], apparently, a miniscule pickled woman. [We]['re] practically a weakling in [this] form; taking something out of inventory [regarding it][prove] impossible. On the bright side, [our] skin [regarding it][helping-have] never looked more radiant." Understand "skin/radiant" as Pickled Naomi.

To swim is a verb. To break is a verb. To emerge is a verb.

Instead of going up when the location is MBF3jar:

    say "[We] [swim] up... and up... and [break] the surface... And suddenly [we] [emerge], wet and dripping, in...";

    now the player is yourself;

    reset the interlocutor;

    try looking.

Instead of going outside when the location is MBF3jar, try going up.

Instead of going nowhere when the location is MBF3jar, say "Eventually, you hit a glass wall and turn back. Seems like there's only one way out of here."

Understand "swim" as a mistake ("Well, yes. [We]['ll] [helping-have] to pick a direction.") when the location is MBF3jar.

Understand "swim [direction]" as going when the location is MBF3jar.

To make is a verb.

Instead of taking inventory when the location is MBF3jar:

    say "[We] [are] carrying:[line break]  Nothing [we] [can make] use of."

Instead of jumping when the location is MBF3jar:

    say "[We] [can't get] a solid foothold."

Definition: a thing is cc-golden if it is enclosed by the location of the jar of peaches and it is not a cc-imagination and the location is MBF3jar.

Instead of examining something cc-golden when the location is MBF3jar:

    say "[We] [can] barely see [the noun] from inside here. [They]['re] just a big jumbled blob."

To reach is a verb.

Rule for reaching inside MBF3 when the location is MBF3jar:

    say "[We] [can't reach] [the noun] from in here. [We][']d never be able to do anything with [regarding the noun][them] at this size, anyway.";

    deny access.

Section 3.2 - golden blobs

Some shapeless golden blobs are scenery in MBF3jar, cc-described "[The shapeless blobs] outside the jar are almost indistinguishable." Understand "shapes/shape/blob" as the shapeless blobs.

Section 3.3 - peach boulders

To bob is a verb.

Some giant orange boulders are fixed in place in MBF3jar. "A great many [giant orange boulders] [bob] lazily in the brine." They are cc-described "These [regarding the orange boulders][are] giant things, larger than [us], floating suspended in the brine. They [must be] the pickled peaches." Understand "peach/peaches/many/great/pickle/pickled/boulder" as the orange boulders.

Instead of eating the orange boulders, say "Each one [regarding it][are] bigger than [us]. [We] [don't have] all day."

Instead of tasting when the location is MBF3jar, say "Everything [regarding it][taste] like peach brine, here."

[Li]

Section 3.4 - brine

To constitute is a verb.

A golden peach brine is scenery, here. It is cc-described "[We] [can't] see [regarding the brine][them], per se; [regarding it][they] [constitute] [our] entire experience in [here]. It surrounds you, penetrates you. It IS you."

Understand "gold/liquid/salt/salty/water/single/singular/reagent" as the golden peach brine.

Does the player mean drinking the golden peach brine: it is likely.

Part 4 - Reconstitution

Cc-reconstituting is an action applying to one visible thing. Understand "reconstitute [any reconstitutable thing]" as cc-reconstituting when Considerability is happening. Understand "reconstitute [something]" as cc-reconstituting when Considerability is happening.

[Understand]

Instead of inserting something into the jar of peaches when Considerability is happening: try cc-reconstituting the noun.

Instead of cc-reconstituting yourself when Considerability is happening, try entering the jar of peaches.

Instead of cc-reconstituting the jar of peaches, say "If you could manage that, the jar would likely consume itself and vanish. And with it, the universe."

Instead of cc-reconstituting the pickled peaches, say "[regarding the pickled peaches][They] already [are]. Oh, [are] [they] ever."

Definition:

    a thing is reconstitutable if it is edible

     and it is off-stage

     and it is seen.

Definition:

    the jar of peaches is cc-avail:

        if it is not handled and it is closed and we have not examined it, no;

        if it is held or it is in the location, yes;

        no.

Jar-con nag is initially 0. Jar-spacer is initially 2.

Every turn when considerability is not happening and the jar of peaches is cc-avail and the location of the pumpkin stem is a room:

    if a random chance of jar-con nag in (jar-spacer + jar-con nag) succeeds and cc-message-printed is false:

        now cc-message-printed is true;

        say "[one of][There's] something about that [jar of peaches].[or]What if [we] [put] something in that jar?[or]Something... alive? [We] [feel] an urge to put something alive in the jar.[or]Or, actually, not alive. What if [we] [put] something that [italic type]had been[roman type] alive in the jar?[or]Something like... a piece of that rotting pumpkin? In the jar?[or][regarding it][Are in title case] [there] some piece of the pumpkin [we] [could put] in the jar?[stopping]";

        increment jar-spacer;

        increment the pickle peach spacer;

        now jar-con nag is 0;

    otherwise:

        increment jar-con nag.

To say Are in title case:

    say "[are]" in title case. [🙄🙄]

Check cc-reconstituting when the jar is not cc-avail:

    say "You need [the jar of peaches] to do that." instead.

To pick up is a verb.

Check cc-reconstituting when the noun is in the location and the noun is not portable:

    say "[We] probably [should try] that with something that [we] [can] actually pick up." instead.

Check cc-reconstituting when the noun is not reconstitutable:

    say "[The noun] [get] a little wet. [They] must not be a good candidate for reconstitution." instead.

Carry out cc-reconstituting:

    now the player holds the noun.

To flick is a verb. To manage is a verb. To pop is a verb.

Report cc-reconstituting something portable:

    say "[reconstitute-text][one of][We]['re] ready for it this time, and [we] manage to grab [regarding the noun][them] in mid-air[or][We] [manage] to hold on to [regarding the noun][them][stopping]."

Report cc-reconstituting something fixed in place: [who makes edible fixed in place things??]

    say reconstitute-text;

    say line break.

To say reconstitute-text:

    say "[We] [flick] a crumb into the jar, and within seconds [if the noun is plural-named]the[otherwise]a[end if] familiar [noun] [pop] out. "

Section 4.1 - Consideration

Considerability is a recurring scene. Considerability begins when the jar of peaches is cc-avail and the location of the whole large pumpkin is a room. Considerability ends when the jar of peaches is not cc-avail.

Cc-considering is an action applying to nothing. Understand "consider old/past/eaten/-- food/meal/meals/--" as cc-considering when Considerability is happening.

[Understand "consider [something]" as a mistake ("Just CONSIDER.") when Considerability is happening.]

Announced reconstitution is initially false.

Some crumbs of past meals are a thing. Understand "drip/drips/dripping/drippings/crumb" as the crumbs past.

Instead of examining the crumbs, try cc-considering.

Instead of taking the crumbs past, say "But what if [we] got hungry later?" Instead of rubbing or pushing the crumbs past, try taking the noun.

To boggle is a verb.

When Considerability begins:

    if announced reconstitution is false:

        now announced reconstitution is true;

        say "The mind [regarding it][boggle]. What else could be reconstituted in this way?[paragraph break][bold type](You may now CONSIDER possible candidates.)[roman type]";

        say line break;

    now the crumbs are part of the player;

Carry out cc-considering:

    do nothing.

To check is a verb.

Report cc-considering:

    say "[We] [check] [our] clothes for stray drips and crumbs and [try] to remember what meals they must have come from. Let's see...[line break]";

    if there is a reconstitutable thing:

        repeat with past glory running through reconstitutable things:

            say "  [a past glory][line break]";

    otherwise:

        say "Nothing comes to mind.";

    say "[first time][line break][bold type](You may now RECONSTITUTE previously eaten meals.)[roman type][line break][only]";

Section 4.2 - Past meals

A big slice of cold pizza is an edible seen thing. It is cc-described "Pepperoni and anchovies.  Looks just as good as it did this morning." After eating the big slice of pizza: say "Tastes just as good as the last time you had it."

A pistachio ice cream cone is an edible seen thing. It is cc-described "Pistachio? Yuck. It's so...green. You hate pistachio.[paragraph break]What drove you to eat this last night?" Instead of eating the pistachio ice cream: say "Blecch. You would never willingly eat pistachio. There's no way you had that for dessert last night."

Section 4.3 - Giant pumpkin

To want is a verb.

The whole large reddish-orange pumpkin is a thing. It is cc-described "A beautiful giant pumpkin. It [regarding it][look] perfect. The only thing [it] [have] in common with the decaying mess in the pantry [are] [their] color.[paragraph break]Probably best not to dwell on where the mass of [this] thing could have come from." Understand "beautiful pumpkin" and "red/orange" and "red-orange" as the whole large pumpkin.

Does the player mean doing something with the whole large pumpkin: it is very likely.

Instead of eating the whole large pumpkin, say "[We] could probably [grab] a kitchen knife and do the dirty deed... but no. [We] [would not] mar its beauty."

[To fit is a verb. To pop is a verb.] To roll is a verb. To come is a verb.

Instead of inserting the pumpkin stem into the jar of peaches:

    say "[There] [are] a [italic type]thunk[roman type] as the stem [are] sucked inside the jar.[paragraph break]Then, suddenly, rising up out of the jar [come] a whole, large, beautiful pumpkin. It['s] impossible, far too large to fit inside the jar, but as it [pop] out and [roll] across the ground ([we] [are] too surprised to react), [we] [can't] deny what just happened.";

    now the whole large pumpkin is in the location;

    now the pumpkin stem is nowhere;

    now the pumpkin stem is unseen.

Chapter 5 - Jupiter puzzle

cc-puzzle is initially false.

Section 5.0 - inciting text

To say cc-puzzle-text:

    say "[italic type]'My dearest [Salona]:'[roman type] There's a rustling noise, followed by a crash. [italic type]'Apologies, I have still not yet familiarized myself with this phonographic contraption. I hope this message finds you well, or, as well can be expected given the circumstances. I must be brief, as I am not certain to tarry long in this fearful place. I have instructed my man to send you with this missive your most favorite varietal of peaches, newly pickled in a jar with a most singular reagent that, I am told, shall restore to you life and vitality. I only pray this does not reach you too late.[paragraph break]'Until next we rejoin, I remain, [cc-Edmund]--'[roman type] And the voice [regarding it][cut] off.[make cc-edmund known][make Salona known]";

    now cc-puzzle is true;

[    now the jar of peaches is in MBF3.]

Section 5.1 - to let this compile - not for release

To say biggles-recites-a-poem:

    say "O great one[line break][']Mumble mumble mumble[line break][']Next person's poetry goes here";

Section 5.2 - tiny conversant

The tiny flitting thing is a scenery animal in MBF3jar. It has initial appearance "A small speck floats in front of you, waiting." Understand "flit/dart/darting/mote/speck/spark/fleck/dot/spot/white/light/light-colored/white-colored/colored/coloured/light-coloured/white-coloured" as the tiny flitting thing.

It is cc-described "A small speck of something light-colored. It's hard to get a good look at something so small in this situation. When [we] [try] to swim closer to get a better look, [it] [dart] away, only to pop up again a second later[first time].[paragraph break]A feeling of intense curiosity [flood] [our] mind. The mote [regarding the tiny flitting][do] a kind of flip in the brine and then [bob] in front of you, waiting.[paragraph break][We] [feel] compelled to say something[only]."

Understand "itself/himself/herself" as the tiny flitting thing.

After examining the tiny flitting: set pronouns from the tiny flitting; continue the action.

To dart is a verb. To catch is a verb.

Instead of taking the tiny flitting thing, say "The spot [dart] away before [we] [can catch] [it]. Then, a moment later, [it's] back."

Flitting thing note count is initially 1. Flitting thing spacer is initially 0. [always display the message on turn 1]

To flit is a verb. To dart is a verb. To do is a verb. To circle is a verb. To stop is a verb.

Every turn when the location is MBF3jar and we have not examined the tiny flitting thing and the tiny flitting thing is scenery:

    if a random chance of flitting thing note count in (flitting thing note count + flitting thing spacer) succeeds:

        increment flitting thing spacer;

        now flitting thing note count is 3; [Most turns should mention the mote, at least early on]

        say "[Regarding the flitting thing][one of]Something white [flit] past your view[or]The tiny light-colored speck [dart] by once more[or]The small flitting thing [do] a quick spiral in the brine[or]The tiny mote [circle] around you once[or][final mote note][stopping]."

To say final mote note:

    say "The small speck [stop], floating a foot (err, a relative foot, if [we] were at [our] original proportions) in front of [us]";

    now the tiny flitting thing is not scenery.

To circle is a verb. To zoom is a verb.

Every turn when the location is MBF3jar and the tiny flitting is not scenery and Heard Edmund's poem is false and the tiny flitting is not the current interlocutor and a random chance of 1 in 2 succeeds:

    say "[regarding it][one of]The fleck [throb] twice[or]The spot [zoom] past [us], then [regarding it][return][or]The tiny flitting thing [make] a spiral in the brine[or]The fleck [circle] [our] head[at random]."

[First before implicit-conversing when the location is MBF3jar:

    try saying hello to the tiny flitting thing.

    [don't try to greet the flies from inside the jar!]]

To flood is a verb. To suffuse is a verb.

After saying hello to the tiny flitting thing:

    say "[We] [try] to greet it, but [we] [don't have] much luck forming words, immersed as [we] [are] in this liquid.[paragraph break]But the mote [regarding the tiny flitting thing][seem] to understand. It bobs once, and a gentle warmth [suffuse] [our] mind.";

    now the tiny flitting is not scenery.

Definition:

    a thing is non-edmundial if it is not cc-edmund.

To fill is a verb.

Instead of quizzing the tiny flitting thing about something non-edmundial (called cc-topic):

    say "A feeling of confusion [regarding it][fill] [our] mind. [regarding it][one of][line break][or]Apparently this creature [helping-have] never heard of [a cc-topic].[or] There must be something this thing [helping-have] heard of.[or] There must be something this thing [helping-have] heard of. Something from back when this jar was first filled...[stopping]"

To wash is a verb.

Instead of quizzing the tiny flitting thing about a direction, say "A feeling of confusion [wash] over [us]. [regarding it]That [must be] too abstract for the thing."

To throb is a verb.

Instead of quizzing the tiny flitting thing about the tiny flitting thing:

    say "[It] [throb] three times, then [cut] a quick circle around you."

Instead of quizzing the tiny flitting thing about the orange boulders:

    say "The spot... shrugs. Somehow."

To bob is a verb. To return is a verb.

Instead of quizzing the tiny flitting thing about cc-edmund:

    say "[regarding the tiny flitting]The tiny dot [bob] up and down eagerly, then [turn] blue.[paragraph break]And then, as if [we]['re] hearing a recording made many decades ago, tinny and echoing, [we] [hear] what must be Edmund's voice once more, this time inside [our] mind:[paragraph break]'If you will indulge me, I wish to recite this poem I have oft enjoyed...' [There] [are] the sound of rustling papers. 'Here we are. [paragraph break][italic type]['][biggles-recites-a-poem][']'[roman type][paragraph break][There] [are] a sharp bang, followed by a wet choking sound, and then silence.[paragraph break]The dot [return] to its usual off-white color and [make] a lazy figure eight in the brine.[paragraph break]Somehow, [we] [have] the feeling that [we] ought to remember that poem he recited.";

    now Heard Edmund's poem is true;

    if cc-testing is true:

        say line break;

        say "[bold type](That's the end of this room's puzzle.)[roman type][line break]"

Instead of informing the tiny flitting thing about something:

    try quizzing the tiny flitting thing about the second noun.

Quizzing it randomly about is an action applying to one thing and one topic.

Carry out quizzing the tiny flitting about: say "A feeling of confusion [regarding it][fill] [our] mind. [regarding it][one of][line break][or]Apparently this creature [helping-have] never heard of [a topic understood].[or] There must be something this thing [helping-have] heard of. Something from back when this jar was first filled...[stopping]"

To wobble is a verb. To spin is a verb.

Instead of requesting the tiny flitting for, say "The mote [regarding it][spin] a quick circle in the brine[one of][or]. Maybe you should stick to simple questions[stopping]."

Instead of imploring the tiny flitting for, say "The dot [regarding it][wobble] unhelpfully[one of][or]. [It] [don't] seem to have any possessions[stopping]."

Understand "ask [someone] about [text]" and "tell [someone] about [text]" as quizzing it randomly about when the location is MBF3.

To blink is a verb.

Instead of quizzing the tiny flitting thing about the vitality of life:

    say "[regarding tiny flitting]The thing [blink] blue for a brief moment. [We] [might be] on the right track, but that's not quite it..."

To slink is a verb.

Before going from MBF3jar when the current interlocutor is the tiny flitting, abide by the say goodbye when moving rule.

After saying goodbye to the tiny flitting thing:

    say "[regarding the tiny flitting]The mote turns dark red and [slink] back behind a pickled peach."

Section 5.3 - topics of conversation

Salona is an unfamiliar subject.

cc-Edmund is an unfamiliar subject. It has printed name "Edmund". Understand "edmund/ed/eddie/eddy/edy/edie/edward" as cc-edmund.

Heard Edmund's poem is initially false.

Vitality of life is a subject. Understand "healing/heal/health/sickness/sick/ill/illness" as vitality of life.

Part The Last - Tests - not for release

Test me with "test MBF3-cheat". [Ryan: comment this line out]

Test MBF3-cheat with "play cylinder/test MBF3"

Test MBF3 with "abstract me to MBF3/get jar/open it/enter it/ask speck about edmund/out"

MBF3 nope this is the very most last final.txt

Displaying MBF3 nope this is the very most last final.txt.