Cragne Manor room M3F7: The Observatory (Joey Jones)

This file is part of the Cragne Manor source code collection. Posted with the author's permission. All rights reserved.


"The Observatory" by Joey Jones
 
[Include Cragne Suite by Ryan Veeder.]
 
Chapter M3F7
 
Corridor is a room. Corridor is northwest of M3F7.
 
M3F7 is a room. The printed name of M3F7 is "The Observatory (Joey Jones)".
 
Before going to M3F7 for the first time:
    say "You make your way into the observatory. Your head pounds with the incoherent horror of the day, but here among the stars there is calm."
 
The description of M3F7 is "The observatory is a cramped domed room[if the joey-portal is not in M3F7] cluttered with all manner of mechanical contrivance[end if]. The way out is northwest.
 
[if the joey-portal is not in M3F7][the device text][otherwise]A flickering hole in space-time hovers in the center of the room, displacing all that was previously there[end if].
 
To one side of the dome is a worn wooden lectern, set before a large chalk circle[if something is in the jj-chalk circle] (in which [is-are the list of things contained by the jj-chalk circle])[end if].[if the joey-portal is not in M3F7]
 
The device is projecting a star sign upon the walls of the dome.[end if]".
 
To say the device text:
    say "At the top of the dome is a large telescope. Immediately beneath it is [if the joey-device is jj-unexamined]a huge device of brass and gears and dozens of multifaceted lenses[otherwise]a vast projector, bristling with obscure controls[end if]"
 
A joey-telescope is scenery in M3F7. The description of the joey-telescope is "The telescope is huge and it juts out of the dome into the night sky. Rather than having an eyepiece, a series of mirrors reflects the output into the device beneath it.". The Printed name of joey-telescope is a "telescope". Understand "telescope" and "scope" as the joey-telescope.
 
Instead of searching the joey-telescope:
    say "You can't look directly into a view-piece: the stars which the telescope points to are projected upon the walls of the observatory."
 
A joey-device is scenery in M3F7. Understand "device" and "orrery" and "planetarium" and "mirror" and "mirrors" and "projector" and "lenses" and "multifaceted lenses" and "brass" and "gears" as the joey-device. The description of the joey-device is "[one of]The device appears to be a planetarium projector. It[or]The projector[stopping] reflects the stars from the telescope onto a series of mirrors that bounce them through an internal orrery which links them up into star signs to project onto the dark walls of the dome.
 
Sticking out prominently from the device are a crank and a dial for turning, a toggle for pushing, and a lever and a pulley for pulling."
 
Understand "all mannner of mechanical contrivance" and "clutter" and "mechanical contrivance" and "machine" and "machinery" and "contrivance" and "mechanism" as the joey-device.
 
The joey-device can be jj-examined or jj-unexamined.  The joey-device is jj-unexamined.
 
After examining the joey-device:
    now the joey-device is jj-examined.
 
The printed name of the joey-device is the "[if the joey-device is jj-examined]projector[otherwise]device[end if]".
 
Understand "wiggle [something]" as pushing when the location is M3F7..
 
The jj-lectern is scenery in M3F7. The jj-lectern is a supporter. Understand "lectern" and "lecturn" and "pedestal" and "stand" as the jj-lectern.
 
The description of the jj-lectern is "The wooden lectern is worn smooth at the top. Evidently in the long history of the Manor, many books have been placed upon it.".
 
The printed name of the jj-lectern is the "lectern".
 
Instead of examining the player when the location is M3F7 (this is the Joey PC description rule):
    if the joey-portal is in M3F7:
        say "The colour from your skin is drawn towards the portal.";
    else:
        say ìAs you walk through the observatory, stars twinkle across your skin.î
 
The joey-star sign is a scenery in M3F7. Understand "star sign" and "walls" and "star" and "wall" as the joey-star sign.
 
The printed name of the joey-star sign is the "star sign".
 
The description of the joey-star sign is "[one of]Lines light up novel connections between the stars, making an uncanny new star signs that spread across the walls of the observatory.
 
T[or]You decipher the star signs lining the walls: t[stopping]he [sign corresponding to a Crankno of jj-cranking in the Table of JJ-Cranking] is [movement corresponding to a Pulleyno of jj-pulleying in the Table of JJ-Pulleying] [movement corresponding to a leverno of jj-levering in the Table of JJ-Levering] the [sign corresponding to a Dialno of jj-dialing in the Table of JJ-Dialing].".
 
Instead of taking the joey-star sign, say "Your hands pass through the projected star sign."
 
The joey-crank is a part of the joey-device.. Understand "crank" as the joey-crank.
 
The description of the joey-crank is "The crank is crooked and appears to only turn in one direction."
 
The printed name of the joey-crank is the "crank".
 
jj-cranking is a number which varies. jj-cranking is 1.
 
Instead of turning the joey-crank:
    say "You turn the crank one step,";
    increase jj-cranking by one;
    if jj-cranking is 21:
        now jj-cranking is 1;
    say " revealing upon the wall the sign of the [sign corresponding to a Crankno of jj-cranking in the Table of JJ-Cranking].".
 
Table of JJ-Cranking
Crankno    Sign
1    "Broken Tower"
2    "Wheel"
3    "Beggar"
4    "Prophet"
5    "Ennui"
6    "Spider"
7    "Fly"
8    "Sleeper"
9    "Mouth"
10    "Tendril"
11    "Vessel"
12    "Spiral"
13    "Turncoat"
14    "Liar"
15    "Adept"
16    "Despair"
17    "Watcher"
18    "Hook"
19    "Needle"
20    "Toad"
 
Table of JJ-Dialing
Dialno    Sign
1    "Scourge"
2    "Throne"
3    "Penitent"
4    "Hanged Man"
5    "Noose"
6    "Tome"
7    "Stranger"
8    "Phylactery"
9    "Vial"
10    "Eyes"
11    "Gate"
12    "Chain"
13    "Mask"
14    "Fortune Teller"
15    "Nemesis"
16    "Pyre"
17    "Baleful Hound"
18    "Crown"
19    "Abyss"
20    "Key"
 
The joey-dial is a part of the joey-device. Understand "dial" as the joey-dial.
 
The description of the joey-dial is "The dial is rugose and appears to only turn in one direction."
 
The printed name of the joey-dial is the "dial".
 
jj-dialing is a number which varies. jj-dialing is 1.
 
Instead of touching the joey-device:
    say "As you nudge this monstrosity of brass and lenses, it swivels on its well-oiled castors, pointing itself vaguely in the direction of the roof.";
    now jj-cranking is a random number between 7 and 12;
    now jj-pulleying is a random number between 3 and 4;
    now jj-levering is a random number between 3 and 4;
    now jj-dialing is a random number between 7 and 12.
 
Instead of attacking the joey-device:
    say "You kick the projector and it swivels on its castors, pointing vaguely towards the floor.";
    now jj-cranking is a random number between 1 and 6;
    now jj-pulleying is a random number between 1 and 2;
    now jj-levering is a random number between 1 and 2;
    now jj-dialing is a random number between 1 and 6.
 
Understand "kick [something]" and "punch [something]" and "swivel [something]" as attacking when the location is M3F7.
 
Instead of pushing the joey-device:
    try touching the joey-device.
 
Instead of pulling the joey-device:
    try touching the joey-device.
 
Instead of turning the joey-device:
    try touching the joey-device.
 
Instead of squeezing the joey-device:
    try touching the joey-device.
 
Instead of taking the joey-device:
    try touching the joey-device.
 
Understand "wall" and "ceiling" and "roof" as the joey-star sign.
 
Understand "castors" as the joey-device.
 
Instead of turning the joey-dial:
    say "You turn the dial one step,";
    increase jj-dialing by one;
    if jj-dialing is 21:
        now jj-dialing is 1;
    say " unveiling the sign of the [sign corresponding to a Dialno of jj-dialing in the Table of JJ-Dialing].".
 
Understand "toggle [something]" as pushing it when the location is M3F7.
 
The joey-pulley is a part of the joey-device. Understand "pulley" as the joey-pulley.
 
The description of the joey-pulley is "The pulley is squamous and is of the sort that returns to its initial position once pulled."
 
The printed name of the joey-pulley is the "pulley".
 
jj-pulleying is a number which varies. jj-pulleying is 1.
 
Instead of pulling the joey-pulley:
    say "You pull the pulley and the projector turns 45 degrees:";
    increase jj-pulleying by one;
    if jj-pulleying is 5:
        now jj-pulleying is 1;
    say " now the [sign corresponding to a Crankno of jj-cranking in the Table of JJ-Cranking] is [movement corresponding to a Pulleyno of jj-pulleying in the Table of JJ-Pulleying].".
 
Table of JJ-Pulleying
Pulleyno    Movement
1    "ascending"
2    "in motion"
3    "descending"
4    "in stasis"
 
The joey-lever is a part of the joey-device.. Understand "lever" as the joey-lever.
 
The description of the joey-lever is "The lever is lopesided and is of the sort that returns to its initial position once pulled."
 
The printed name of the joey-lever is the "lever".
 
Understand "signs" and "stars" as the joey-star sign.
 
jj-levering is a number which varies. jj-levering is 1.
 
Instead of pulling the joey-lever:
    say "You pull the lever and the projector adjusts its focus:";
    increase jj-levering by one;
    if jj-levering is 5:
        now jj-levering is 1;
    say " now the [sign corresponding to a Crankno of jj-cranking in the Table of JJ-Cranking] is [movement corresponding to a leverno of jj-levering in the Table of JJ-Levering] the [sign corresponding to a Dialno of jj-dialing in the Table of JJ-Dialing].".
 
Table of JJ-Levering
leverno    Movement
1    "under"
2    "opposing"
3    "above"
4    "in the house of"
 
First true sign is a number which varies.
 
Second true sign is a number which varies.
 
First true movement is a number which varies.
 
Second true movement is a number  which varies.
 
When play begins:
    now first true sign is a random number between 1 and 20;
    now second true sign is a random number between 1 and 20;
    now first true movement is a random number between 1 and 4;
    now second true movement is a random number between 1 and 4;
    now jj-cranking is a random number between 1 and 20;
    now jj-pulleying is a random number between 1 and 4;
    now jj-levering is a random number between 1 and 4;
    now jj-dialing is a random number between 1 and 20.
 
To say joey's true sign:
    say "the [sign corresponding to a Crankno of first true sign in the Table of JJ-Cranking] [movement corresponding to a Pulleyno of first true movement in the Table of JJ-Pulleying] [movement corresponding to a leverno of second true movement in the Table of JJ-Levering] the [sign corresponding to a Dialno of second true sign in the Table of JJ-Dialing]".
 
The joey-toggle is a part of the joey-device. Understand "toggle" as the joey-toggle.
 
The printed name of the joey-toggler is the "toggle".
 
Understand "button" and "switch" as the joey-toggle.
 
Instead of switching on the joey-toggle:
    try pushing the joey-toggle.
 
Instead of switching off the joey-toggle:
    try pushing the joey-toggle.
 
 
The description of the joey-toggle is "The toggle is red and is of the sort that returns to its initial position once pushed."
 
Instead of pushing the joey-toggle:
    now jj-cranking is a random number between 1 and 20;
    now jj-pulleying is a random number between 1 and 4;
    now jj-levering is a random number between 1 and 4;
    now jj-dialing is a random number between 1 and 20;
    say "With a [one of]squeal[or]sudden crunch[or]shudder[or]clunk of gears[cycling], the whole projector swivels to a new position. Now the [sign corresponding to a Crankno of jj-cranking in the Table of JJ-Cranking] is [movement corresponding to a Pulleyno of jj-pulleying in the Table of JJ-Pulleying] [movement corresponding to a leverno of jj-levering in the Table of JJ-Levering] the [sign corresponding to a Dialno of jj-dialing in the Table of JJ-Dialing].".
 
Instead of dropping the grimoire when the location is M3F7:
        try putting the grimoire on the jj-lectern instead.
 
After putting the grimoire on the jj-lectern:
    say "You place the grimoire on the lectern and it falls to the page of the ritual. The stars from the projector dance across its pages."
 
The printed name of jj-lectern is a "lectern". The carrying capacity of the jj-lectern is 1.
 
After putting something on the jj-lectern:
    if the noun is a book and the noun is not the grimoire:
        say "[The noun] flips open to a random page when you place it upon the lectern." instead.
 
The jj-chalk circle is scenery in M3F7. The jj-chalk circle is a container. Understand "chalk", "circle" and "chalk circle" as the jj-chalk circle.
 
The printed name of the jj-chalk circle is the "chalk circle".
 
The description of the jj-chalk circle is "A chalk circle spreads out on the floor below the lectern, perfectly round. The chalk is accreted upon layer-upon-layer of earlier circles."
 
Understand "floor" as the jj-chalk circle.
 
Instead of putting something on the jj-chalk circle:
    try inserting the noun into the jj-chalk circle.
 
Instead of dropping the memento when the location is M3F7:
        try inserting the memento into the jj-chalk circle instead.
 
Instead of dropping the cyst when the location is M3F7:
        try inserting the cyst into the jj-chalk circle instead.
 
Understand "blow [the black horn]" as kissing.
 
Instead of kissing the black horn:
    say "You try to draw some sound from the horn, putting it to your lips. It lets out a low shuddering sound, like a thousand goats crying out in slow motion.";
    if the location is M3F7 and the grimoire is on the jj-lectern:
        say "[line break]The grimoire shakes upon the lectern.";
    if the location is M3F7 and the memento is in the jj-chalk circle:
        say "[line break]The chalk circle glows.";
    if the location is M3F7 and the cyst is in the jj-chalk circle:
        say "[line break]The cyst starts to bubble.";
    if the stars are aligned:
        say "[line break]The stars shine brighter upon the observatory's walls,";
        If the memento is not in the jj-chalk circle or the grimoire is not on the jj-lectern or the cyst is not in the jj-chalk circle:
            say " but then dim again. Something is missing.";
        otherwise:
            say " and the whole room ripples.";
            wait for any key;
            say the rift is nigh;
    otherwise:
        say "[line break]But nothing else happens. Something is wrong here.".
 
To decide whether the stars are aligned:
    if jj-cranking is first true sign and jj-pulleying is first true movement and jj-levering is second true movement and jj-dialing is second true sign, yes;
    no.
 
To say the rift is nigh:
    say "The horn cracks and crumbles to dust in your hands. The cyst bursts and evaporates into the ruin in a greasy haze. The photograph in the chalk circle burns to ash. Something perpendicular to this plane of existence worms its way through into the observatory.[paragraph break]There is a crack in existence; a portal taking up the space in the center of the room where the device once stood.";
    now the black horn is nowhere;
    now the cyst is nowhere;
    now the memento is nowhere;
    now the joey-device is nowhere;
    now the joey-star sign is nowhere;
    now the joey-telescope is nowhere;
    now the joey-portal is in M3F7.
 
The joey-portal is enterable scenery container. The description of the joey-portal is "Peering through you catch brief glimpses of impossible geography beyond[first time]. If the ritual has worked, entering the portal will be the way to reach your husband at last[only]."
 
The printed name of the joey-portal is the "portal".
 
Instead of entering the joey-portal when the location is M3F7:
    say "You take a deep breath and step outside of the world[first time]. Your senses curdle. You see yourself outside of yourself, as if you were a second person. Your memories of the last day (or night? or season? or year?) shuffle like the star signs across the observatory, with dozens of competing possible versions of yourself juxtaposed incoherently.
 
    You try to grasp at what the true memory was. A woman, searching a house for her husband? A trip to the library to return overdue books? But now in your mind you only have a patchwork of impossible moments. Of bizarre creatures, unlikely tasks and glimpses at the precipice of madness[only].";
    wait for any key;
    clear the screen;
    say "You arrive somewhere else.";
    now the player is in Other Dimension.
 
Understand "hole", "rift", "tear" and "portal" as the joey-portal.
 
 
To say jj-grimoire:
    say "The grimoire in open on a page describing peeling open the way to someone lost, whether they be in this world or not. You gather from the prelimaries that the ritual involves the horn of a black goat and a cyst from a god, as well as the lost one's true star sign and their most treasured memento. How the ritual is actually performed is further in the book on the pages you currently cannot see.".
 
To say jj-grimoire free:
    say "Now you can flick through the yellowing pages of the grimoire, you learn that to open a way to your lost husband, you must:[line break]blow the horn of the black goat,[line break]while the stars are reflecting upon the grimoire,[line break]with the stars falling under his true star sign,[line break]and his most treasured memento,[line break]and a divine pustule,[line break]placed in a chalk circle beneath the raised grimoire.[paragraph break]Only then will the way open."
 
Understand "sing" or "hum" or "whistle" as a mistake ("You hum to yourself, [italic type]tekeli-li, tekeli-li...[roman type]").
 
 
 
Chapter Testing Stuff - Not For Release
 
Test M3F7 with "put cyst in circle / put memento in circle / put grimoire on lectern / calibrate device / blow the horn / enter the portal".
 
Understand "calibrate [something]" as closing.
 
Instead of closing the joey-device:
    say "You calibrate the device...";
    now jj-cranking is first true sign;
    now jj-pulleying is first true movement;
    now jj-levering is second true movement;
    now jj-dialing is second true sign.
 
Include Basic Screen Effects by Emily Short.
 
The memento is a thing carried by the player.
 
The black horn is a thing carried by the player.
 
The grimoire is a thing carried by the player. The description of the grimoire is "[jj-grimoire]".
 
Other Dimension is a room.
 
The display case is a container.
 
After examining the joey-star sign:
    say "[paragraph break](It wants to be [joey's true sign].)"
 
The cyst is a thing. The cyst is carried by the player.
 
A book is a kind of thing. The grimoire is a book.