This file is part of the Cragne Manor source code collection. Posted with the author's permission. All rights reserved.
"CHU2" by Hanon Ondricek
[2018.08.05]
Chapter 1 - Do Not Change Any Of This
Include Cragne Suite by Ryan Veeder.
[Don't mess with other people's rooms!]
CHU is a region.
CHU1 is a room in CHU. CHU1 is south of RRS6 and southeast from WOO1 and west from SPO1.
CHU2 is a room in CHU.
CHU3 is a room in CHU. CHU3 is up from CHU2.
CHU4 is a room in CHU. CHU4 is west from CHU2.
Door2a is a closed locked scenery door. Door2a is inside from CHU1 and outside from CHU2. Key2 unlocks Door2a.
Door2b is a closed locked scenery door. Door2b is north from CHU5 and south from CHU4. Key2 unlocks Door2b.
Key2 is in MGR7.
[old code:]
[CHUdoor12 is a closed locked scenery door. CHUkey unlocks CHUdoor12. CHUdoor12 is inside from CHU1 and outside from CHU2.]
Section 1 - Not for release
[Delete this section if necessary]
[I included this because the code order started the player in CHU1 behind a locked door. Please delete if necessary.]
[After looking in CHU1, say "[italic type]Use testing command TEST HANON to move to the correct room.[roman type]"]
[I included this so I could release for testing and the player could go to chu2 - I wasn't sure who would be testing and if they would understand debug commands]
Test Hanon with "gonear CHU2".
A library book has some text called official title. The official title of a library book is usually "[the printed name]".
Part 1 - CHU2 Narthex
Chapter 1 - Naomi
Printed name of CHU2 is "Church Lobby-Space (Hanon Ondricek)".
Instead of examining the player when the location is chu2 or the location is hano-restroom (this is the Hanon PC description rule):
say “You stop and take stock: yes, you [italic type]are still Naomi Cragne[roman type] despite everything that has happened and who you may or may not have been up to this point. Your husband needs you to help him, and you are bound and determined to do [italic type]exactly that[roman type], no matter [italic type]what horrors[roman type] lie in wait for you going forward.[if the player wears something][line break]You are wearing [a list of things worn by the player].[end if][if the player carries more than 9 things][paragraph break]You are also lugging around a [italic type]whole lot[roman type] of stuff.[end if]"
Instead of smelling in chu2, say "A wood-y, wallpapery-scent lingers, with just a hint of snickerdoodles and coffee."
The commentary of chu2 is "So, welcome to the Narthex! If I understand correctly, it's behind a locked door in either direction, so congratulations for making it here...however you manged to do it! I had to look up 'narthex' so that was the first thing I did - I made the room name change after Naomi learns what it means.[paragraph break]Ryan said we didn't have to go [italic type]crazy[roman type] in our rooms if we didn't want to, so I envisioned doing a quick and easy, atmospherically appealing room about the subtle creeping dread of objects vanishing and reappearing. It was going to take a good hour to write, maybe two if I wanted to get fancy, and not take too much time from the other project I was working on.[paragraph break]Then I got my assignment, and EVERYTHING CHANGED.[paragraph break]Sorry Ryan and Jenni, for (compiles to check) the 16697-word source text in a world with 13 rooms and 73 things. Only [italic type]five[roman type] of those are my added rooms, I swear.[roman type][paragraph break]I put a commentary in each location. If there's not, then Ryan or Jenni may have put their individual feet down on not increasing the PROP_TABLE_SIZE or the MAX_DESCRIPTIVE_FOODLUMS or someothersuch limit in Inform 7.[paragraph break][italic type]Thank you, testers: Andrew Schultz, Jeremy Freese, Mike Spivey, Rachel Spitler, Eric W. Brown, Lucian Smith, Christopher Conley. Special thanks to Andrew Plotkin and everyone on the #Slack community for tech help, support, and fungal bloom jokes. Also thanks Ryan and Jenni for letting us do this crazy thing.[roman type]"
Chapter 2 - Church-Lobby Area AND Narthex - CHU2
Description of CHU2 is "[if hano-readarticle is true]The [italic type]narthex[roman type][otherwise]This shallow space[end if] extends the width of the church. [first time][italic type]What do you call this? The church-lobby? Surely there's a better name for it... [roman type][only]Despite the gloominess, it's not that unwelcoming[one of]. You'd guess renovations happened mid-1980s--the color scheme is that sponge-painted beigy-peach which goes [italic type]great[roman type] with[or] except for the eye-watering pattern of[stopping] industrial linoleum floor tiles. They checkerboard underfoot in grayish green and grayish white squares with dark speckles[one of][or], stopping only at the margin marked by a wall border at waist level[stopping].[first time] A stamped powder-blue accent border provides a homey feel for church-lady potlucks.[only][paragraph break]The chapel proper opens to the [bold type]west[roman type] and a set of double doors leads [bold type]out[roman type] of the building.[paragraph break][first time]Also good to note: t[only][one of][or]T[stopping]wo side by side openings lead [bold type]in[roman type] to restrooms[first time]. Now's probably a good time to go--this place is quite a bit tidier than many of the locations you've visited, and who knows when you might next encounter a clean bathroom that isn't filled with skeletons, or making scary noises, or holding a contraption that dispenses a key, or a portal to a pocket dimension full of snakes with baby-faces or something worse..[only]."
Every turn when the location is chu2 and hano-restroom is not visited and hano-setgender is false:
if a random chance of 1 in 3 succeeds:
say "[italic type][one of]You know, you could use a quick restroom break about now.[or]That restroom looks rather safe--might as well make use of the facilities while you're here, for good measure.[or]You don't know when you're going to be trapped again. Probably a good idea to hit the restroom real quick while you're here.[or]You do kind of need to pee. Fortunate you spotted that restroom.[cycling][roman type]";
a hano-border is scenery in CHU2. The description is "An endless repeating design of [one of][or]166 [or][stopping]blue-stamped [one of]geese[or]children[or]geese[stopping] that alternately [one of]honk[or]scream[or]honk[stopping] '[one of]Welcome[or]Help[or]Welcome[stopping]' and '[one of]Jesus Saves[or]Save Us[or]Jesus Saves[stopping]' runs around the room at belly-button height." The printed name is "blue border". Understand "powder/blue/accent/border" as hano-border.
Instead of listening when the location is chu2:
say "You hold very still and [italic type]listen[roman type]...";
wait for any key;
if a random chance of 1 in 3 succeeds:
say "... [one of]breathing[or]a cough[or]footsteps[or]faint choral singing[or]a cycling refrigerator[or]trickling water[or]wind whistling[or]whispering[in random order]?";
otherwise:
say "...only hearing the blood rushing in your ears."
Section 1 - Tiled Floor [hano-floor]
a hano-floor is a backdrop. It is in CHU2 and hano-past-CHU2. It is scenery. The printed name is "tiled floor". Understand "floor/tiles/tiled/pale/grayish/greyish/green/white/industrial/checkered/checkerboard/flecked/squares/square/linoleum" as hano-floor. The description is "The floor [expand] underneath; a bewildering checkerboard of pale green and white linoleum tiles."
Section 2 - Black Tile [hano-blacktile]
hano-ladderfoot is a backdrop. It is in CHU2 and hano-past-CHU2. Understand "foot/bottom/base/under of/-- the/-- ladder" and "floor near/by the/-- ladder" as hano-ladderfoot. The printed name is "floor near the ladder". The description is "[We] [notice] one odd black tile near the foot of the ladder."
[The backdrop is so the tile container attached to it can be manipulated in two locations, past and present.]
a hano-blacktile is a closed, openable container. It is part of hano-ladderfoot. The printed name is "black tile". Understand "odd/tile/black/loose/hollow/space/hole/dark/inky/cold" as hano-blacktile. Understand "under/underneath/in/beneath the/-- black/-- tile/square" and "space/hole/-- under/underneath/beneath the/-- black/-- tile/square" and "hiding place" and "hole" as hano-blacktile when hano-blacktile is open. The description is "[if hano-blacktile is open][We] [have] moved aside one[else]One[end if] odd black tile near the foot of the ladder.[if the player is not hano-jessica] They must have run out of green and white during a repair.[end if][if hano-blacktile is open] There [are] a small hollow in the floor under the tile.[end if]"
Rule for printing the name of hano-blacktile when taking something or inserting something into or examining:
say "the space under the tile".
After opening hano-blacktile:
say "The black tile [open] like a lid, revealing a dark space underneath.[if the player is not hano-jessica and hano-blacktile contains something][italic type][line break]Low on the horizon, the mercurial sliver of moon doubles, passing mirrored through itself to illuminate the fiendish scribble the eye gazes down to comprehend.[roman type][line break]Black thoughts in an inky square, revealed by colored moonlight glinting through the church window glass.";
if the player is not hano-jessica and hano-library-book is in hano-blacktile and hano-noose is off-stage:
now hano-noose is in chu2;
hano-putting-it-under is an action applying to two things. Understand "put [something] under [something]" and "put [something] underneath [something]" and "put [something] beneath [something]" and "hide [something] under [something]" and "hide [something] underneath [something]" and "hide [something] beneath [something]" as hano-putting-it-under when the player is hano-jessica or the location is chu2.
Instead of hano-putting-it-under:
try inserting the noun into the second noun.
Instead of pulling or taking hano-blacktile, try opening hano-blacktile.
Understand "replace [something]" as closing when the location is CHU2 or the player is hano-jessica.
Understand "lift [something]" as opening when the location is CHU2 or the player is hano-jessica.
Instead of inserting something into hano-blacktile when the location is chu2 (this is the thwart inconvenient time travel rule):
say "You hesitate. Inky darkness hides the bottom[first time]. Yeah...when you reach in your hand just gets cold and doesn't find any solid surface[only]. If you drop something in there, it may remain till the end of time."
Section 3 - Photos [hano-photos]
some hano-photos is in chu2. "A collection of framed photos is arranged on one wall, and a woodstained ladder bolted nearby leads [bold type]up[roman type] through a square opening in the ceiling.[if hano-heels are in present-hano-stall][paragraph break]The hair on your neck prickles...[italic type]Was that a cough? Someone in the restroom?[roman type][end if]". Understand "collection/frame/frames/framed/modern/photo/photos/photograph/photographs/picture/pictures/wall/walls/collage/arrangement" as hano-photos. It is fixed in place. The description is "Black and white photos of generations of religious folk and church social gatherings. Included are four or five class photos of students in tweed blazers, pressed slacks, and plaid skirts. The newest is inscribed [italic type]1978[roman type].[if hano-readarticle is true][italic type] Goodness, some of those kids might not have survived to graduation...[roman type][end if][paragraph break]A yellowed newspaper article in a more modern frame catches your attention.". The printed name of hano-photos is "photo arrangement".
hano-students is part of hano-photos. The description is "Vague monochrome faces with feathered hair. Curious... One specific student's face is obscured with red wax...or--scribbled red lipstick?". Understand "student/students/jessica/dawn/whitford/thelma/groffley/meredith/mulroney/sister/mary/marcia/girl/girls/student/students/class/classmates/teacher/teachers/nun/nuns/scribble/scribbled/tweed/blazers/pressed/slacks/plaid/skirts/lipstick/faces/face/girl" as hano-students. The printed name is "student faces". It is ambiguously plural.
Instead of rubbing hano-students, say "You only succeed in smearing the lipstick a little more."
a hano-article is scenery in chu2. Understand "article/story/newsprint/newspaper/yellowed/prominent/frame/framed" as hano-article. The printed name of hano-article is "framed newspaper article". The description of hano-article is "From the Backwater Gazette, March 8, 1984. The faded print is hard to read, but the article details the Backwater Historical Society renovation of the [one of][italic type]narthex[roman type][know-narthex][or]narthex[stopping] of the church after a fire five years prior. [italic type]School, library, and gymnasium incinerated to the dirt foundation in an unexplainable inferno during the 1979 Maple Harvest Dance... 166 students, faculty, and neighbors tragically lost...no remains identifiable... The church itself suffered only minor damage in what surviving parishoners describe as a 'divine miracle'...[roman type][hano-read]"
To say know-narthex:
now the printed name of chu2 is "Narthex (Hanon Ondricek)".
[When Naomi learns that a church lobby is called a narthex.]
hano-readarticle is a truth state that varies.
To say hano-read:
now hano-readarticle is true.
Section 4 - Church Exit Doors to CHU1 [Door2a]
Rule for printing the name of Door2a while location is CHU2: [I had to add 'the'-'printing THE name']
say "church exit doors".
Understand "main/entry/double/church/door/doors" as Door2a while location is chu2.
Instead of examining Door2a while location is CHU2:
say "The doors leading out[if door2a is open] are propped wide open, admitting chilly air from outside[otherwise] are firmly shut, the inset stained glass ovals glowing in multiple colors[end if]."
a hano-inset is scenery in chu2. The description is "Each side of the main church entry doors splits a tall semi-oval stained glass inset window depicting...what is that? [one of]Praying people climbing a hill into a burst of light?[or]A deity creating animals with too many legs?[or]A comet with tentacles?[or]The last supper only with food that looks like human limbs?[or]A benevolent face in the sky and people weeping?[or]People harvesting cornstalks that have cute little faces?[or]A man inside a man inside a man inside a man inside...like a matryoshka doll?[or]People drinking from red rivers filled with giant fish?[in random order]". Understand "window/windows/stained/glass/inset/tall/semi/oval/ovals/semi-oval" as hano-inset. The printed name of hano-inset is "stained glass doors".
Section 5 - Chapel opening [hano-chapel] scenery
a hano-chapel is scenery in CHU2. The printed name is "chapel entry". Understand "church/chapel/auditorium/main/opening/entry/entryway/altar" as hano-chapel. Instead of entering hano-chapel, try going west. The description is "The chapel is through the opening that way--west, you think."
Section 6 - Restroom Scenery Containers [hano-wrestroom, hano-mrestroom]
hano-setgender is a truth-state that varies.
to say hano-lgop:
now hano-setgender is true.
a hano-wrestroom is an enterable container in chu2. It is scenery. Understand "opening/openings/restroom/restrooms/rest/room/bathroom/women's/womens/toilet/toilets/loo" as hano-wrestroom. Instead of entering hano-wrestroom, try going inside. The printed name of hano-wrestroom is "women's restroom". Instead of inserting something into hano-wrestroom, say "You'd rather not just toss [the noun] in there.". The description is "[first time]A motion-detector light pops on unexpectedly. [only]It looks innocuous enough--clean, tidy, smells pleasantly of [one of]jasmine-honeysuckle[or]apple-cinnamon[or]wildberry fantasy[or]mango escape[or]citrus splash[or]herbal wildflower[or]fresh spring meadow[in random order] air-freshener. There's nobody in there, as you'd expect."
Does the player mean entering hano-wrestroom: it is likely.
a hano-mrestroom is an enterable container in chu2. It is scenery. Understand "opening/openings/restroom/restrooms/rest/room/bathroom/men's/mens/toilet/toilets/loo" as hano-mrestroom. the description is "[first time]A motion sensor-light pops on inside when you approach. [only]Deserted--sink, urinal, stall, sporty-extreme air-freshener, all in order.". Instead of entering hano-mrestroom, say "[one of][if hano-setgender is false][lgop][otherwise]It's always a little weird going in the other restroom, even when nobody is around.[end if][or]You reconsider; nothing good ever happens in the opposite-gendered restroom in these types of situations.[or]No, seriously. If you've [italic type]at all[roman type] gotten a sense for how things work in Backwater, Vermont, you know you're going to end up trapped in there and some spectre is going to ask you to solve Towers of Hanoi, or rearrange some stupid soup cans to spell a mysterious phrase or...reach into the gnarly sewer pipe. The women's restroom will be plenty to deal with for now.[or]All right, fine. You poke your head in, since there's nobody around. It's as you'd expect: stall, urinal, sink. Tropical Pina-Colada air freshener. Good enough. That's all you need to know about [italic type]that[roman type] location.[stopping]". The printed name of hano-mrestroom is "men's restroom". Instead of inserting something into hano-mrestroom, say "You'd rather not just toss [the noun] in there, cause then you'd [italic type]actually have to enter the men's restroom[roman type] to retrieve it."
To say lgop:
now hano-setgender is true;
say "[bold type]Gents['] Room[roman type][paragraph break]This filthy bathroom belies the existence of disinfectant. A single toilet and sink are the only fixtures. More breathable air can be found outside.[paragraph break]You assume a wide stance. [italic type]Ahhh...[roman type][paragraph break]Now that the 'crisis' has passed, you notice a strong and familiar odor pervading the room.[paragraph break]>";
wait for any key;
say "[user input type]smell[roman type][line break][bracket][italic type]Please scratch and sniff circle #1 on the card included with the game...[roman type][close bracket]";
wait for any key;
say "...your nostrils fill with the heady scent of [one of]Tropical Pina-Colada[or]New Car[or]Alpine Thunderblast[or]Seafarin['] Ocean Spirit[at random] industrial strength air-freshener.[paragraph break]Wait a second...um. No. That didn't happen. Shake it off, Naomi. No. No, [italic type]not like that.[roman type]";
Section 7 - Ladder to CHU3 - Steeple? [hano-ladder]
a hano-ladder is an enterable supporter in chu2. It is scenery. The printed name of hano-ladder is "woodstained ladder". Understand "woodstained/wood/stained/ladder/rung/rungs/opening/ceiling" as hano-ladder when the location is chu2. The description of hano-ladder is "A ladder bolted to the wall leads [bold type]up[roman type] through a finished square opening in the ceiling[if chu3 is not visited], you would presume to the steeple--if the whipping wind and ominous creaking from above is any indication[end if]. A plastic sign at face-height indicates 'STAFF ONLY [italic type]Please! Thank you![roman type]'". Instead of entering hano-ladder, try going up. Instead of climbing hano-ladder, try going up.
Before going up in chu2, say "You mount the ladder, making sure your feet catch each rung[if hano-noose is in chu2]...[otherwise], and climb to the ceiling [italic type]don't look down![roman type] through the square opening...[end if]"
a hano-sign is scenery in chu2. The description is "A plastic sign at face-height between the rungs of the ladder indicates 'STAFF ONLY [italic type]Please! Thank you![roman type]'". Understand "plastic/sign" as hano-sign. The printed name of hano-sign is "plastic sign".
Chapter 3 - Restroom in Present [hano-restroom]
hano-restroom is inside from chu2. "The women's restroom is tidy as church facilities go. There is only one way [bold type]out[roman type], unless you count the bathroom stall door reflected in the mirror above the sink.[hano-lgop][if a random touchable hano-tap is switched on][paragraph break]Water runs steadily into the sink.[end if][if hano-heels is in present-hano-stall and present-hano-stall is closed][paragraph break]From this angle in the mirror, you spy a pair of red shoes under the stall door.[end if]". The printed name of hano-restroom is "Women's Restroom".
Instead of smelling in hano-restroom, say "The room is spritzed every five minutes by a hidden mechanism, so it smells pleasantly (if a bit strongly) of [one of]jasmine-honeysuckle[or]apple-cinnamon[or]wildberry fantasy[or]mango escape[or]citrus splash[or]herbal wildflower[or]fresh spring meadow[in random order] air-freshener."
The commentary of hano-restroom is "I tried to follow the Veeder Credo of not describing superfluous things that the player didn't need to worry about, but a lot of more stuff ended up in here because players always want to try to flushing the toilet."
Section 1 - Sink in Present [hano-sink, hano-mirror]
a hano-sink is a supporter in hano-restroom. It is scenery. Understand "sink" as hano-sink. The printed name of hano-sink is "sink"
a hano-mirror is a transparent, closed container in hano-restroom. It is fixed in place. It is scenery. Understand "mirror/reflection/glass/surface" and "my/-- face/lips/hair" and "bathroom mirror" as hano-mirror. The printed name is "bathroom mirror".
Understand "hands" as yourself when the location is hano-restroom.
Washing is an action applying to one thing. Understand "wash [something]" and "rinse [something]" and "wet [something]" as washing when the location is hano-restroom or the location is hano-past-restroom.
Instead of washing yourself, say "You wash your hands thoroughly and hold them for a minute in the loud but feeble blast of air from the hand dryer on the wall."
Instead of washing hano-mirror, say "You splash some water on your face, then stand in the blast of the hand dryer on the wall, pursing your lips so they don't go [italic type]flobble-lobble-lobble-lobble[roman type]."
a hano-dryer is scenery in hano-restroom. The printed name is "hand dryer". Understand "hand dryer" and "dryer" as hano-dryer. The description is "Good for the environment, but often not great for drying hands."
Instead of searching or examining hano-mirror:
if the player does not wear hano-lipstick:
say "It's you, Naomi Cragne, staring back from the mirror. Good-looking as ever, if maybe a bit frazzled from recent events. [one of]Right then. You look focused, confident; your lips are a bit pale, but what can you do?[or]You stick out your tongue...no odd coloration.[or]You make a cursory attempt to fix your hair, but that won't help things at the moment.[or]Eyes maybe a bit bleary.[or]My goodness, you look more and more like your mother every day...[cycling][if hano-heels is in present-hano-stall][line break]Two red shoes are visible under the bathroom stall door behind you--only visible from this angle in the mirror.[end if]";
otherwise:
now the player is hano-Jessica;
say "Mmm, luscious red lips--ones that total fox [italic type]Brandon Cragne[roman type] might want to kiss...that is, if she played her cards right. Otherwise, the same mousy brown hair pulled back in clips, the same lame grey tweed school uniform. The same pallid complexion. [italic type]Heavy sigh[roman type].";
now the story tense is past tense;
now the story viewpoint is third person singular.
Section 2 - [present-hano-stall]
a hano-stall is a kind of container. A hano-stall is usually scenery. A hano-stall is usually lit. A hano-stall is closed and openable and enterable. The printed name of a hano-stall is "bathroom stall". Understand "stall/partition/partitions/flimsy/cubicle" and "bathroom/restroom stall" and "bathroom/restroom/-- stall/-- door" as a hano-stall. The description is "The flimsy stall partitions afford a modicum of privacy in a public restroom--you can't see over or under them."
a present-hano-stall is a hano-stall in hano-restroom. Instead of entering present-hano-stall, say "[one of]You enter the restroom stall for a time-out and a well-deserved five minute break to 'freshen up' before continuing your adventure.[or]You don't really need to at the moment.[stopping]"
Instead of hanofrobbing a hano-stall, try entering the noun.
A hano-toilet is a kind of thing. It is scenery. It is fixed in place. Understand "toilet/loo/facilities/bowl/stool" as a hano-toilet. The printed name is "toilet". The description is "[one of]Yes, there [are] one.[or]The less said about it the better.[or]Look, I knew [we] would try this, but there is no puzzle involving it, I swear![or]Fine. [We] examined it. It [are] a stellar example of its kind.[stopping]". Instead of hanofrobbing a hano-toilet, say "[one of]Yes, fine. [We] [do] all the things with that you can imagine. Moving on.[or][We] [have] already taken care of every biological need that can be satisfied here.[stopping]"
After deciding the scope of the player when the location is hano-restroom:
place a random hano-toilet enclosed by the location in scope.
Instead of pushing a hano-toilet, say "[if the player is hano-jessica]She hated flushing here because you could hear it all the way in the chapel and that alerted people to her presence, but luckily choir practice was proceeding at full-volume. She pressed the lever with her shoe, and--[italic type]whumph-glorsh-glorsh-foosh... gloggleloggle-forsh-glooshhhhhh whoooshhh (trickle trickle trickle)[roman type]--a torrent of about eight gallons of water purged the porcelain bowl.[otherwise][italic type]Skloosh! [roman type]The bowl flushes efficiently with an eco-friendly nine ounces of water.[end if]"
hano-flushing is an action applying to one thing. Understand "flush [something]" as hano-flushing when the location is hano-restroom or the location is hano-past-restroom.
Check hano-flushing:
say "That [aren't] something [we] [can] flush." instead.
Instead of hano-flushing a hano-toilet:
try pushing a random touchable hano-toilet.
One hano-toilet is in present-hano-stall.
hano-nobody is a person in present-hano-stall. The printed name is "no one".
Carry out entering present-hano-stall:
now hano-nobody is off-stage.
Carry out exiting from present-hano-stall:
now hano-nobody is in present-hano-stall.
Understand "knock on [something]" as attacking when the location is hano-restroom or the player is hano-jessica. Instead of attacking present-hano-stall, say "[if present-hano-stall is open]You can see there's no one in there.[otherwise]You knock politely on the stall door, 'Hello? Anyone in there?'[end if]"
Section 3 - Saucy Siren Lipstick [hano-lipstick]
a hano-lipstick is on hano-sink. "It appears someone has discarded a tube of lipstick on the sink.". The indefinite article is "some". hano-lipstick can be openable. It is openable. It is wearable. The printed name is "lipstick in a tube". Understand "tube of lipstick" and "lipstick/tube/saucy/red/siren/label/stick" as hano-lipstick. Understand "lip/lips/lipstick/saucy/siren" as yourself when hano-lipstick is worn. Instead of opening hano-lipstick, try examining hano-lipstick. The description is "The lipstick is practically new[first time] and appears to never have been used. [italic type]Score[roman type][only]. The label names it 'Saucy Siren'--which of course is a dark shade of red.". After wearing hano-lipstick, say "You meticulously apply the lipstick [italic type]mph...mpoph...[roman type][if the location is chu2 or the location is hano-restroom] You should check it out in the mirror to make sure you didn't get any on your teeth.[end if]". After taking off hano-lipstick, say "You wipe off as much of the lipstick as is humanly possible."
Rule for printing the name of hano-lipstick when taking inventory:
say "Saucy Siren lipstick".
Rule for printing the name of hano-lipstick when examining:
if hano-lipstick is worn:
say "Saucy Siren red lipstick";
otherwise:
say "red lipstick[if the player is hano-jessica and hano-lipstick is worn by yourself] in the exact same color as hers[end if]".
Instead of putting hano-lipstick on something, say "Drawing on [the second noun] sounds like a great way to ruin a perfectly good lipstick. At least try wearing it first experimentally to see if you want to keep it before you turn it into a writing instrument."
Instead of putting hano-lipstick on yourself, try wearing hano-lipstick.
Section 4 - Red high heels [hano-heels]
some hano-heels are a wearable thing. "A pair of red high heels sit side by side on the floor of the restroom stall.". the printed name is "red high heel shoes". Understand "pair of" and "red/high/heel/highheel/highheels/heels/pumps/pump/shoes/shoe/leather/vintage/kicks" as hano-heels. The description is "[if the player is hano-jessica]Jessica had 'borrowed' her sister's treasured 'Wizard of Oz' formal heels [italic type]so shiny bright red![roman type] to try them out. They fit perfectly.[otherwise]These are some vintage kicks--but red leather pumps never go out of style[first time]. Someone must be bummed about forgetting these[only].[end if]"
After deciding the scope of the player when the location is hano-restroom and hano-heels is enclosed by the location:
place hano-heels in scope.
Instead of examining hano-heels when hano-heels are in
present-hano-stall and present-hano-stall is closed:
say "There are definitely some shoes in the bathroom stall, right where they would be if someone were sitting on the--but you don't [italic type]hear[roman type] anyone...breathing...or otherwise..."
After wearing hano-heels when the player is not hano-jessica and hano-jesspower is false:
now the player is hano-jessica;
now the story tense is past tense;
now the story viewpoint is third person singular;
now hano-sisterm is off-stage;
now hano-meredith is off-stage;
now hano-jessica wears hano-heels;
say "You slip off your sensible running shoes and insert your toes into the shiny pumps. They are a little tight and your heel won't go in...unless you exert some force. [italic type]Thunk. Thunk.[roman type] Woo! They fit [italic type]perfectly.[roman type][paragraph break]She pulled the pin from her hair and let it tumble loosely around her shoulders, shaking it out to complete the glamorous tall-model look."
Instead of looking under present-hano-stall when hano-heels are in present-hano-stall and present-hano-stall is closed:
say "Is someone in the stall? You hold your breath and lean down carefully...yep. Two red shoes under there. Your brain cries for oxygen as you listen intently for breathing or any human sound. There is none."
Chapter 4 - Restroom in Past [hano-past-restroom]
hano-past-restroom is a room. "The girl's restroom by the chapel was Jessica's main respite while at school, being a good detour away the main facility in the school hallway. Often she was able to get several minutes to herself away from the other spazz-girls in her class. There was only one way [bold type]out[roman type] through the door back to the Chapel hallway." The printed name of hano-past-restroom is "Girl's Room".
Instead of smelling in hano-past-restroom, say "Industrial disinfectant with iodine, like a hospital."
Commentary of hano-past-restroom is "I decided to mashup Carrie and Heathers. The first reader I showed this scene to said the nun [italic type]wasn't severe enough.[roman type] I was intending to use her to take away stray objects from the player as a ghost, but that ended up not happening.[paragraph break]I used an online R'lyeh generator (https://lingojam.com/RLyehian) but I couldn't find a reverse R'lyeah to English translator so I don't know how grammatical it is! Jessica's line is basically 'By the power of Vaadignephod, lord over the (Earth?) city of Black Water, Vermont!' Thelma's babble is something like 'My head is broken, and I will never be the same.'"
Section 1 - hano-past-sink
a hano-past-sink is a supporter in hano-past-restroom. It is scenery. Understand "sink" as hano-past-sink. The printed name of hano-past-sink is "sink"
Section 2 - cuz you gotta try turning on a sink
a hano-tap is a kind of device. The printed name of a hano-tap is usually "faucet". Understand "faucet/water/tap" as a hano-tap. One hano-tap is part of hano-sink. One hano-tap is part of hano-past-sink.
Instead of switching on hano-past-sink, try switching on a random touchable hano-tap.
Instead of switching off hano-past-sink, try switching off a random touchable hano-tap.
Instead of switching on hano-sink, try switching on a random touchable hano-tap.
Instead of switching off hano-sink, try switching off a random touchable hano-tap.
Section 3 - hano-past-mirror
a hano-past-mirror is a transparent, closed container in hano-past-restroom. It is fixed in place. It is scenery. Understand "mirror" and "bathroom mirror" and "my/her/-- lips/face" as hano-past-mirror. The printed name is "bathroom mirror". The description is "The lighting was really bad or Jessica's eyes were playing tricks on her because the woman reflected back looked nothing like her at all.[if hano-word is in hano-past-mirror] A bizarre word scrawled across the mirror in red lipstick but... only on the opposite side? Her finger squeaked across the glass without affecting it. Weird.[end if]"
Check taking something when the location is hano-past-restroom:
if the noun is in hano-past-mirror:
say "Her hand wouldn't go through the glass, unsurprisingly." instead.
Instead of washing hano-past-mirror, say "Jessica splashed some water on her face and blotted carefully with a crackly brown paper towel."
Instead of washing hano-jessbody, say "Jessica washed her hands and dried them with a crackly brown paper towel."
Instead of searching hano-past-mirror, try examining hano-past-mirror.
Section 4 - hano-vision (in the mirror)
a hano-vision is in hano-past-mirror. "She could see herself reflected in the mirror.". The printed name is "reflection". Understand "reflection/woman" as hano-vision. The description is "[one of]The person in the mirror was [italic type]definitely not her.[roman type] She was at least as old as her mom, staring blankly, occasionally opening and closing her lips as if in a trance.[if yourself wears something] She appeared to be wearing [a list of things worn by yourself].[end if][or]The woman held her gaze and wrote letters with a lipstick on the glass: [italic type]B...A...A...V--what?[roman type][hano-write][or]Where was her reflection? Weirdness.[or]The woman was gone now, the bathroom in the mirror was wallpapered with a tacky blue border on blotchy beige. Lipstick letters were smeared across the surface.[or]Jessica gazed at her reflection. [italic type]Of course[roman type] it was her reflection. She needed to stop listening to all the weird things in her head.[or]Jessica checked herself out in the [italic type]very normal[roman type] mirror.[stopping]".
Instead of examining hano-past-mirror:
try examining hano-vision.
Section 5 - word on the mirror
a hano-word is a thing. "Some backward lipstick letters are smeared across the mirror.". The printed name is "word written in lipstick". Understand "word/written/writing/words/letter/letters/lipstick/smear/smeared" as hano-word. The description is "Letters in smeared lipstick: [italic type]b o h q e n g i b a a v[roman type][hano-write]"
The basic accessibility rule does nothing when the noun is hano-word.
To say hano-write:
now hano-word is in hano-past-mirror.
Instead of rubbing or touching hano-word, say "Jessica's thumb squeaked on the surface. The words seemed to be written on the [italic type]other[roman type] side of the glass. Freaky."
Section 6 - past-hano-stall
a past-hano-stall is a hano-stall in hano-past-restroom.
One hano-toilet is in past-hano-stall.
After deciding the scope of the player when the location is hano-past-restroom:
place a random hano-toilet enclosed by the location in scope.
Instead of looking under past-hano-stall, say "Jessica leaned down to take a leg-check of the stall situation. Nobody was eavesdropping as far as she could tell."
Instead of attacking past-hano-stall, say "Jessica could tell nobody was in there without knocking."
Chapter 5 - Jessica [1961-1979]
hano-Jessica is a woman in hano-past-restroom. The description is "[one of]Jessica experienced an odd moment of disorienting deja-vu where she didn't feel quite herself, but it passed quickly.[or][italic type]If only [roman type]she could be someone else for a while! [or]Nope. Jessica was still herself.[if hano-jessica wears hano-heels]..although she thought she could get used to this three-inch-higher perspective while wearing her sister's high heels.[end if][stopping]"
a hano-hair is part of hano-jessica. Understand "my/her/-- hair" as hano-hair. The printed name is "hair". The description is "It was clipped back out of her face.". hano-hair is ambiguously plural. The indefinite article is "her".
a hano-jessbody is part of hano-jessica. Understand "my/her/jessica's/your/-- body/knee/knees/legs/leg/arms/arm/hands/hand/eyes/eye/feet/foot/corporeal/form/figure/physique/features/blur" as hano-jessbody. The printed name is "body". The description is "At the moment, most of Jessica's features were a plain blur.". The indefinite article is "her".
Does the player mean examining hano-jessbody: it is unlikely.
a hano-uniform is a kind of thing. A hano-uniform is wearable. The description of a hano-uniform is usually "Tweed blazer, very hot, crisp white or off-white blouse buttoned [italic type]all the way up[roman type], flat shoes--at least they were comfortable. Plaid skirt below the knee--no skin above the knee socks. [italic type]Love you, Jesus, but who would ever think this type of getup was a stylish thing for young girls to wear? [first time] In addition, the Backwater Devotional Sisters of Mary Catholic High School colors were gray and light gray. [italic type]My life is a black and white movie. Sigh.[roman type][only]". Understand "uniform/blazer/blouse/button/buttons/plaid/skirt/knee/knees/school" as a hano-uniform. The printed name is "[our] school uniform".
One school uniform is a hano-uniform worn by hano-jessica.
Instead of taking off a hano-uniform, say "She considered streaking down the hallway. The idea was amusing, but [italic type]hell no.[roman type] She'd get [italic type]much more[roman type] than her knuckles rapped for undressing publicly during school hours."
Section 1 - fake library books
some hano-fakebooks are a book carried by hano-jessica. The printed name is "overdue library books". Understand "book/books/overdue/proper/etiquette/practical/handbook/love/spells/card/cards" and "library books/book/card/cards/cover/covers" as hano-fakebooks. The description is "Books from the school library. The stamped cards in the folders glued inside the cover said they were due on [fixed letter spacing]1979 03 16 FRI[variable letter spacing], so she needed to return them ASAP. Mrs. Bowler, the librarian, usually didn't mind letting her slide a couple of days, but... The covers both had stickers on them identifying them as school property.".
[I looked up a 1979 calendar to hit the right days of the week, I didn't get obsessive. I originally had set the incident in 1978, but the Maple Harvest actually happens in Feb-March so it had to be 1979.]
some hano-stickers are part of hano-fakebooks. Understand "sticker/stickers" as hano-stickers. The printed name is "school library stickers". The description is "Every school library book featured a sticker on the back cover: [italic type]This book is on loan from Backwater Devotional Sisters of Mary Catholic High School, Backwater, VT.[roman type] above a graphic representational outline of a nun holding the hands of a boy and girl who seemed way too short to be high school students. Many of the stickers on the books over the years had obtained comical faces added in ballpoint pen. This one, for example, had the nun smoking a joint and children with happy, red-eyed faces. The other book had a dialogue balloon with the nun declaring [italic type]i eat pussy (crossed out) children[roman type] and the kids wearing appropriate expressions of terror."
The passage of hano-fakebooks is "She had read them through already. [italic type]Proper Etiquette for Young Ladies (and Gentlemen!)[roman type] had absolutely no dating advice. [italic type]Practical Handbook of Love Spells for Everyone[roman type] seemed a bit more promising, but she didn't have all the colors of candles for the spell she wanted to use on Brandon Cragne."
Instead of hano-relinquishing when the noun is hano-fakebooks:
say "Jessica didn't want to leave her books laying around since they were due to be returned to the school library."
Section 2 - Jessica's Sister's lipstick [hano-lipstick2]
hano-lipstick2 is carried by hano-jessica. The description is "She swiped her sister's new lipstick--just to try out. Of course she was going to give it back.". The printed name is "her sister's lipstick". Understand "lipstick/red/saucy/siren/sister's/tube/stick" and "tube of lipstick" as hano-lipstick2. Instead of dropping hano-lipstick2, say "She needed to hang on to it and give it back to her sister before she realized it was gone.". Instead of wearing hano-lipstick2, say "She had plenty of it on already. If she flattened it, her sister would [italic type]freak out[roman type].".
Check giving hano-lipstick2 to someone:
if the second noun is not hano-sisterm:
say "She didn't want to give her sister's lipstick to [the second noun]."
Instead of putting hano-lipstick2 on something, say "Drawing on [the second noun] would ruin your sister's lipstick."
Instead of putting hano-lipstick2 on hano-jessica, try wearing hano-lipstick.
Section 3 - Meredith [hano-meredith]
hano-meredith is a woman. "Meredith stood in plain formation with coal-car Dawn and caboose Thelma.". The printed name is "Meredith Mulroney". Understand "meredith/mulroney/girl/woman/white/ribbon/hair/blouse/ruffles/plaid/skirt/grey/sock/socks/knee/knees/milk/pan" as hano-meredith. The description is "Meredith Mulroney, the plainest of the Plains. Studious. Put-together. Perfect white ribbon pulling back her straight, perfectly chestnut brown hair. Her blouse extra ruffly at the throat. Her grey-on-grey plaid skirt never less than three inches below her grey-socked knees. This girl was a total flat pan of warm milk."
Section 4 - Dawn [hano-dawn]
hano-dawn is a woman. She is part of hano-meredith. The printed name is "Dawn Whitford". Understand "dawn/whitford/girl/woman/pigtail/pigtails/clear/glass/bead/beads/tiny/gold/spectacles/glasses" as hano-dawn. The description is "Dawn Whitford, photographic memory, never forgets [italic type]like an elephant[roman type]. Has daily, since kindergarten, sported anywhere from two to five useless straight, skinny pigtails anchored on her head with those big clear glass beads and tiny gold spectacles like she's the cousin of both Mother Goose and Mrs. Claus. She was Sister Mary Marcia's favorite and thus was able to wield the old nun like an attack dog on call."
Section 5 - Thelma [hano-thelma]
hano-thelma is a woman. She is part of hano-meredith. The printed name is "Thelma Groffley". Understand "thelma/groffley/girl/sweats/skirt/strawberry/blond/blonde/braid/white/gold/bow/thigh/thighs" as hano-thelma. The description is "Thelma Groffley. Varsity Basketball, color team, volleyball, gymnastics and ROTC. She wore sweats under her skirt every day and one long strawberry-blond braid to her waist tied with a stupid white and gold bow. In eighth grade Thelma won a ten dollar bet that she couldn't pop a kickball by compressing it between her very sturdy thighs."
Section 6 - The Plains [hano-plains]
hano-plains is part of hano-meredith. Understand "plain/plains/girls/women/students/trio/group/squad" as hano-plains. The printed name is "The Plains".
Instead of examining hano-plains:
try examining hano-dawn;
try examining hano-thelma;
try examining hano-meredith;
say "They were all [italic type]so[roman type] going to heaven."
Section 7 - Sister Mary Marcia [hano-sisterm]
hano-sisterm is a woman. The printed name is "Sister Mary Marcia". Understand "woman/nun/sister/mary/marcia" as hano-sisterm. The description is "Sister Mary Marcia ruled the school with her favorite wooden measuring stick. The black habit and white band above her forehead belied her age as it did with all Jessica's instructors."
Section 8 - Lipstick Scene
Instead of going in hano-past-restroom when hano-jessica carries hano-lipstick2 and hano-sisterm is not in the location and hano-meredith is not in the location:
now hano-meredith is in hano-past-restroom;
say "As she turned to leave, the door creaked open. In walked [italic type]The Plains[roman type]--the three most devout girls in school.[paragraph break]'Thelma, didn't you tell me that this bathroom usually is deserted around lunchtime?' grumped Dawn.[paragraph break]'Well, it was yesterday. Don't worry, we won't be long, [italic type]Jezebel[roman type],' the biggest Plain sneered.[paragraph break]'Oh, Thelma, don't be so [italic type]mean[roman type] to her! Her name is [italic type]Jessica.[roman type] It is Jessica, right?' She could tell Meredith really didn't care since she was already checking her hair ribbon for right-angle-alignment in the bathroom mirror.[paragraph break]The Plains were worshipped and feared--they were the eyes and ears of the Sisters in every corner of the school and involved themselves in everyone else's business."
Instead of doing anything except examining when hano-meredith is in the location and hano-jessica carries hano-lipstick2 and hano-sisterm is not in the location:
say "[italic type]Jessica had recently started hearing voices in her head and had grown accustomed to supressing and ignoring what they said. Right now she just needed to be away from people.[roman type][line break]>[user input type]exit[roman type][line break]Jessica moved to exit, but Thelma wouldn't move away from the bathroom door. 'That's some awfully bright red lipstick you have on, [italic type]Jezebel[roman type]. You know red is Jesus's least favorite color.'[paragraph break]Meredith turned, 'Oh, cut her some slack, Thel. It looks like [italic type]someone[roman type] is trying to learn how to pretty herself up for the Maple Harvest dance!' she chirped.[paragraph break]Dawn blew her nose with some toilet paper from the stall and tossed it away. 'Well, [italic type]Jessica[roman type] probably should be aware that the Maple Harvest dance is a [italic type]formal[roman type] occasion and not a Halloween party, so she ought to dial back on the clown paint.'[paragraph break]'Or a Mary Magdalene look-alike contest, neither,' added Thelma.[paragraph break]'So,' Meredith continued, applying her own lip-shade that was exactly the same color as her lips and had no noticeable effect, 'Jessica, does this mean you've found a [italic type]special someone[roman type] who will be accompanying you to the biggest school event of the year?'[line break]";
if the player consents:
say "[italic type]That was none of Meredith Mulroney's beezwax.[roman type] 'No, I haven't,' Jessica replied.[line break]";
say "[line break]'Oh, that's so sad!' Meredith wailed. 'Your senior year, too! Hold on, [italic type]wait a minute[roman type]. I know someone who is more than likely free and isn't going...what about...[italic type]Brandon Cragne?[roman type]'[paragraph break]'Brandon Cragne? He plays [italic type]Dungeons and Dragons,[roman type]' Dawn slurped, articulating through her retainer. 'You know, [italic type]Satan's boardgame?[roman type]'[paragraph break]The two demi-Plains parted at the clacking of orthopedic shoes in the hallway, and suddenly the door was blockaded with Sister Mary Marcia's imposing frame. 'What in blazes is going on in here? This restroom is too small for all four of you at once.'[paragraph break]'Good [italic type]morning[roman type], Sister Mary Marcia,' Dawn wheedled. 'We were just pointing out to our classmate here that the vividness of her cosmetic selections violate the parameters of standard school dress code policy.'[paragraph break]The nun sucked a breath between her teeth, 'Jessica. You are too young to be wearing makeup, much less that shade of red. That lipstick is for[italic type] protestant girls![roman type]' Sister Marcia held out her hand. 'Are you [italic type]trying[roman type] to give the boys the wrong idea? If not, you'd better hand over that lipstick.'";
now hano-sisterm is in hano-past-restroom.
Instead of doing anything except examining or giving when hano-sisterm is in the location and the location is hano-past-restroom and hano-jessica carries hano-lipstick2:
say ">[user input type][one of]but it belongs to my sister[or]my sister will kill me if she doesn't get this back[or]but, Sister Mary Marcia...[cycling][roman type][line break]'[one of]This Sister says give me that lipstick,[or]Hand it over,[or]I don't want to hear any backsass, girl,[or]You can have it back at the end of the year,[cycling]' [one of]insisted[or]snapped[or]replied[in random order] [one of]Sister Mary Marcia[or]the nun[or]Sister, growing seemingly more impatient[cycling]."
instead of saying hello to hano-sisterm when hano-jessica carries hano-lipstick2:
say "Jessica relinquished the forbidden devil's paint. Sister Mary Marcia plucked a rough brown paper towel from the dispenser and licked it. 'You've still got some on your mouth. That will have to come off. Hold still...' the nun grabbed her face and began scrubbing, much to the amusement of the Plains.";
now hano-lipstick is off-stage;
now hano-lipstick2 is off-stage;
now the player is yourself;
now present-hano-stall is closed;
now hano-heels are in present-hano-stall;
now the story viewpoint is second person singular;
now the story tense is present tense;
say "Aaaaaaghh! Stop it! STOP IT!";
wait for any key;
say "[line break]>[user input type]take off lipstick[roman type]";
say "[paragraph break]You wipe all the red off of your lips, expecting your hands to come away covered in it--but there is no trace of the lipstick on your hands. You check the mirror--none on your face either.";
Section 9 - Shoe Scene
Instead of taking off hano-heels when the player is hano-jessica:
say "[italic type][if hano-sistertrap is true][one of]No! She can't have my beautiful shoes![or]No! She can't have my sister's beautiful shoes![or]I am not giving her these shoes for the rest of the year.[or]Anything but the shoes.[cycling][otherwise]I should take these off, but I'd rather not.[end if][roman type]"
hano-jesspower is a truth state that varies.
Instead of going in hano-past-restroom when hano-jessica wears hano-heels and hano-jesspower is false:
now hano-meredith is in hano-past-restroom;
say "Of course, the door banged open and Dawn Whitford peered around it, '[italic type]Está ocupado[roman type], Meredith!' Dawn flapped the rest of the way in with a clipboard, 'Jessica, I took the initiative to add your name to the Harvest Dance cleanup crew, since you more than likely aren't going to be attending with all the normal people.' Meredith flitted to the mirror, and Thelma skulked in behind her, guarding the door like usual. '...That way, you can at least come in the last half hour and hear some of the music and see everyone's dresses.'[paragraph break]'Oh, you [italic type]still[roman type] haven't found someone to accompany you to the dance yet?' Meredith read her face and wrinkled her nose. 'That's such a shame! Well, it's a good thing you'll be there at the end at least. I can't [italic type]wait[roman type] for you to see this luscious floor-length all-white chiffon number I found! Since it's senior year, I decided to throw caution to the wind and go [italic type]sleeveless[roman type]!'[paragraph break]The other two girls went [italic type]'oooooOOOOOOooo'[roman type] on cue like third-graders witnessing people kiss in a movie.[paragraph break]'I'll be there with my dancin['] shoes on!' Meredith squealed, briefly performing the most geriatric Charleston step Jessica could imagine before turning gleefully to the mirror to make sure her hair was still, in fact, completely straight.[paragraph break]'Speaking of footwear,' Thelma approached twirling her braid, 'check out the snazzy kicks on Jezebel here! Your shoes aren't going to get you closer to heaven, honey!'[paragraph break]'Red is Satan's favorite color,' Dawn reminded. 'And I don't have my ruler, but I'm quite sure the heel height on those don't fit the official school dress code.'[paragraph break]'Oh, nonsense, Meredith muttered into the mirror. 'I think they're pretty. You know every little bit helps when you start at a disadvantage!'[paragraph break]Thelma sauntered past, 'Jus['] remember: the higher you climb, the farther you fall.'[paragraph break]The shove wasn't hard, but it was deliberate, and Jessica was doing okay balancing but had no traction and her feet skidded out from under her as she flailed awkwardly. WHAM her tailbone contacted the tile and every limb went shockingly numb for a moment.";
now hano-jesspower is true.
Instead of attacking or pushing hano-meredith:
say "Jessica had no qualms about scrapping, but Meredith Mulroney hadn't quite pushed her to that brink yet."
Instead of attacking or pushing hano-dawn:
say "Jessica had no qualms about scrapping, but Dawn Whitford hadn't [italic type]quite[roman type] pushed her to that brink yet."
Instead of attacking or pushing hano-thelma when the player does not wear hano-heels and hano-meredith is in the location:
say "Without some kind of divine intervention, Thelma would certainly [italic type]trash Jessica's ass[roman type] in a fight. She pushed that impulse way back on the burner."
Instead of doing anything except examining or attacking or pushing when the player is hano-jessica and the player wears hano-heels and hano-meredith is in the location:
say ">[user input type][one of]push her[or]push thelma[or]PUSH THELMA[or]PUSH HER[OR]ATTACK HER[stopping][roman type][line break]";
say "[italic type][one of]no voices in my head you don't control me[or]stop arguing i cant think[or]thats not what i want to do oh god oh god[or]theres no way out of this just do something get me out of here[or]oh god oh god[stopping] stop laughing![roman type]";
Instead of pushing or attacking hano-thelma when the player wears hano-heels:
say "Once she gave in, it seemed gravity reversed, and she--[italic type]Llll r'luh ot syha'h vaadignephod, uh'eog ng uh'eog ot shugg uh'eagl ot n'ghftoggn'thor, vermont[roman type]--rose to her feet by magic. [italic type]like hurling a fastball at Thelma Groffley's stupid face[roman type] but there was no physical contact--Jessica raised her hands and--[paragraph break][italic type]!!!blam!!![roman type][paragraph break]--Thelma flew five feet into the ceramic wall tiles hard enough to loosen several.[paragraph break][italic type]'What?--'[roman type] shrieked Meredith.[paragraph break]'Holy [italic type]shit![roman type]' exclaimed Dawn, immediately babbling [italic type]Hail Mary[roman type] through her fingers.[paragraph break]Thelma slid down the wall onto her butt with her legs splayed, blinking morse code.[paragraph break]The white and gold bow that held her braid tightly wound fluttered from the ceiling, smoldering, then igniting. The flames crackled, spurring Dawn to step forward and stomp it out with her sneaker, [italic type]'What kind of demon are you?'[roman type][paragraph break]'Come on, Thelma,' Meredith hoisted the bigger girl to her feet--she was now blurbling nonsense words--[italic type]lloig ah mgepch'nglui'ahog. Y['] mgsyha'h ephaiah ahehyee[roman type]--through a bloody nose. 'Uh. Let's...get you to the nurse.' The leader of the Plains escorted her gently. 'I'm right here... Now the left one. Good. And...the right one. You're walking [italic type]so good[roman type], Thelma!'[paragraph break]Dawn remained, hands planted on hips, 'Don't think that Sister Mary Marcia won't hear about this!' and she stomped out indignantly, maintaining a five-foot radius.";
now hano-meredith is off-stage;
now hano-jesspower is true.
Chapter 6 - Narthex in past [hano-past-chu2]
hano-past-CHU2 is outside from hano-past-restroom. The printed name is "Narthex". "The bland checkerboard-floored antechamber (though the nuns always called it the [italic type]narthex[roman type])[know-narthex] that connected the chapel to the main school hallway proudly displayed a decade's worth of framed photographs of historical Catholic figures and famous nuns, posters for school activities, and important mimeographed lists of extra-curricular activity rosters taped to the walls."
Instead of smelling in hano-past-chu2, say "Jessica didn't find the ever-present aroma of wood soap as unpleasant as many other students claimed it was."
The commentary of hano-past-chu2 is "I was pretty happy with the nearly-all-female cast of 12 Angry Men on the poster and the obnoxious choir rehearsal. This room is probably the simplest, mainly containing the backdrop with the black tile to shuttle the library book to Naomi in the future and effectively rescue it from the Harvest Dance Inferno incident. The Backwater Public Library has been waiting for this book a while and the late fees are probably going to be astronomical. Sorry, Naomi![paragraph break]My conceit for why the book wasn't there before is originally Brandon never met Jessica and jumped from the bell tower to sacrifice himself to become a vessel for Vaadignephod. He mangled his body on the parking lot so badly that V manipulates Naomi to control Jessica to give Brandon a a more appropriate method of death they could inhabit a vessel with less blunt trauma and broken bones.) "
Section 1 - Past wall stuff [hano-list, hano-posters, hano-past-photos]
a hano-list is scenery in hano-past-chu2. The printed name is "mimeographed activity lists". Understand "list/lists/mimeographed/roster/rosters/activity/activities/wall/walls/extra/curricular/extra-curricular" as hano-list. The description is "Rosters for football, basketball, track, color team, chess club, drama club... Not important."
some hano-posters is scenery in hano-past-chu2. The printed name is "after school activity posters". Understand "poster/posters/school/activities/after/wall/walls/prom/dance/maple/harvest/play/drama/club/clubs/sports/sport" as hano-posters. The description is "Posters encouraged students to try out for football, basketball, track, color team, chess club...and there was a poster still up from the fall production of [italic type]12 Angry Men[roman type]. The nine girls who had to play men actually did a really good job.[paragraph break]The most prominent addition to the group was [italic type]Backwater Devotional Sisters of Mary Catholic High School Class of [']79 Presents our Maple Harvest Dance: Sweet Enchantment Under the Leaves![roman type]"
[Go BDSM-HS! This is certainly not my doing, and making this acronym was done under coercion from a tester. I was three-quarters of the way there with the school name and arms were twisted. At another point, the school name was "Many Sisters of Mary".]
some hano-past-photos is scenery in hano-past-chu2. The printed name is "framed photos". Understand "frame/frames/framed/photo/photos/photographs/historical/catholic/figures/famous/nuns/class/students/student/picture/pictures/wall/walls/glasses/horn-rimmed" as hano-past-photos. The description is "Scores of photos: Popes, Cardinals, Bishops and Priests and Decons and Nuns, oh my, most sported heavy horn-rimmed glasses. There were four or five class photos grouping high-school students in tweed blazers, pressed slacks, and plaid skirts up through 1978. The ones including Jessica and people she knew were up too high pick out individuals."
Section 2 - Fake Chapel Doors in past (choir rehearsal) [hano-past-doors]
some hano-past-doors are in hano-past-chu2. They are fixed in place. "Bellowed hosannas from choir rehearsal taking place behind the closed chapel doors to the [bold type]west[roman type] competed with the roar of the school hallway to the [bold type]east[roman type].". The printed name is "chapel doors". Understand "door/doors/double/choir/practice/chorus/singing/song/chapel/church/singer/singers/warmup/exercises/scales/rehearsal/hosanna/hosannas" as hano-past-doors. Instead of going west in hano-past-chu2, say "Jessica had been banished from choir for two weeks for her 'creative' scat-jazz interpretations of some of the warmup exercises. She probably didn't need to show her face in there for a while.". Instead of opening hano-past-doors, try going west. Instead of closing hano-past-doors, say "They were already closed.". The description is "The chapel doors were closed for a choir rehearsal.". Instead of listening when the location is hano-past-chu2, say "She could hear the choir warming up. Choir Director Sister Leticia believed in a [italic type]minimum[roman type] forty-five minutes of warmups to protect young throats and vocal cords. They were on [italic type][one of]bibba-beeba-bobba-bayba-boo[or]shmunna-munna-funna-punna-poo[or]zinga-zanga-zonga-zunga-zoo[or]red-leather-yellow-leather[or]mee-may-mah-moh-moo[cycling][roman type] up and down the scale in increasing half-steps."
Section 3 - [hano-past-ladder]
a hano-past-ladder is an enterable supporter in hano-past-chu2. "The ladder to the bell tower rose against the wall in its usual place. A sign mounted at face-height read 'STAFF ONLY. [italic type]NO STUDENTS![roman type]'". The printed name of hano-past-ladder is "woodstained ladder". Understand "woodstained/wood/stained/ladder/rung/rungs/opening/ceiling/steeple/bell/tower/quasimodo/hunchback" as hano-past-ladder when the location is hano-past-chu2. The description of hano-past-ladder is "Students aren't allowed up there.". Instead of entering hano-past-ladder, say "She knew she wasn't allowed up there. And despite being anti-rule in general, she had no business in the bell tower." Instead of climbing hano-past-ladder, say "Jessica didn't have any reason to climb to the bell tower. The Quasimodo story the seniors always told incoming underclassmen had been demonstrably proven false."
a hano-past-sign is scenery in hano-past-chu2. The description is "A sign indicated the ladder was for 'STAFF ONLY and especially [italic type]NO STUDENTS![roman type]' in capital italics.". Understand "plastic/sign" as hano-past-sign. The printed name of hano-past-sign is "ladder sign".
Instead of going up in hano-past-chu2, try climbing hano-past-ladder.
Section 4 - tee shirt [hano-shirt]
a hano-shirt is a thing. It is wearable. The printed name is "[if the player is hano-jessica]Black Sabbath tee shirt[otherwise]vintage Black Sabbath tee shirt[end if]". Understand "brandon's/black/sabbath/vintage/tee/shirt/concert/tshirt/teeshirt/t-shirt/thought/thoughts" as hano-shirt. The description is "The printing is legit metal--crackledy and faded."
[Most of my objects can't leave the room, but I wanted to give the player a cool wearable souvenir that has no other purpose in the game - other than summoning Sister Mary Marcia the first time it's worn.]
After wearing hano-shirt:
say "You pull the shirt on over your head... [italic type]Yes[roman type], you can still fit a medium...though it's a bit snug in the chest[first time]. As the shirt settles, you detect a faint whiff of a freshly-mown lawn in the spring.[hano-meetsister][only]".
To say hano-meetsister:
wait for any key;
say "[line break]You stifle a scream as a clawed hand squeezes your shoulder--[italic type]'Brandon Cragne!'[roman type]--you whirl face-to-face with a moon-faced nun in a black habit. She releases you and steps back. 'Oh. I'm sorry. You're not the person I thought you were!'[paragraph break]'No, I'm Naomi Cragne,' you say, unsure whether you're supposed to offer a handshake to a nun or curtsy or--'[italic type]I'm sorry[roman type]. I didn't realize anyone was in here,' you respond, oddly disappointed to still be yourself--[if the location is not chu2][italic type]I'm back in the church I'm back in the Narthex how the hell did I get back to--[roman type][end if]'I don't mean to intrude, Sister.'[paragraph break]'It's all right. All are welcome, dear.' She peers sagely into your eyes, placing her hands on your shoulders. 'May the Lord bless you and keep you safe. Be careful around here.'[paragraph break]A dull roaring rose behind her, fluttering her habit. She leaned back and shook her head sadly.[paragraph break]'You want to hear some irony? I became a nun because I figured that way I'd never feel what it was like to burn.'[paragraph break]";
wait for any key;
say "The picture wall behind her exploded into a vortex of orange and gold flames whirling with leaves which flamed out of existence [italic type]screaming[roman type].[paragraph break]The nun turned--her habit blazed a column of fire to the ceiling. [italic type]'I'm coming!' she called, and [italic type]ran directly into the flames to save as many of her students as she could, merging with the inferno.[roman type][paragraph break]";
wait for any key;
say "Three plain angels slammed the doors to the school hallway--[paragraph break][italic type]!!!kerblam!!![roman type][paragraph break]--hard enough to rumble the entire church and hurl every picture from the walls down to the tile floor in a thunderous crash of sparkling glass and wood[if the location is not chu2]. Your surroundings blur again and you find yourself back where you were[end if].[roman type][line break]";
now hano-photos is off-stage;
now hano-article is off-stage;
now hano-debris is in chu2.
hano-debris is a thing. it is fixed in place. "Shattered glass and broken pieces of picture frames cover the floor of the narthex around the edges near the walls." The printed name is "shattered photo frames". Understand "shattered/broken/piece/pieces/photo/photos/frame/frames/debris/wreckage/picture/pictures/student/students/nun/nuns/student/students/jessica/meredith/mulroney/thelma/groffley/dawn/whitford/brandon/cragne/bowler/librarian/whatshisname/baseboard/baseboards" as hano-debris. The description is "Every single photo lies destroyed in pieces near the baseboards.". Instead of taking hano-debris, say "There's no recognizable piece larger than a fingernail[first time]. You'd rather not cut your hands to ribbons sifting through the wreckage. Some unfortunate someone is going to have a huge mess on their hands come Sunday morning[only].".
Section 5 - Noose [hano-noose]
a hano-noose is a thing. It is fixed in place. It is wearable. "A noose of thick nylon boat-rope hangs down through the opening in the ceiling in front of the ladder.". The printed name is "noose". The description is "[one of]That's--a noose. That--wasn't there before, was it?[or]Surely you'd have seen a noose hanging down because it's right there and not really a thing that you'd overlook in a church-lobby-type space.[or]That's messed up. Someone is trying to scare you.[stopping]". Understand "noose/rope/boat/nylon/loop" as hano-noose.
[Originally the player was going to become Jessica again when they put on the t-shirt and there would be a scene of putting on her prom dress, the lipstick, the heels. Then she'd meet Brandon, kiss him, walk into the prom. Then I realized if she wore Brandon's shirt, I couldn't really have her take it off, so she'd wear it under her dress. That meant it would get burned in the fire along with her and not exist anymore, and I really wanted the player to keep the shirt. Finally I came up with the idea of letting the player become *Brandon* to mix it up and cut out another bathroom scene. I liked the inference that he consulted the book, then took of his shirt so Jessica could draw the ritual symbol on him and happened to just reflexively stash it with the book.]
Instead of doing anything except examining to hano-noose:
say "This noose doesn't belong here. It wasn't here before. Someone is playing a trick on you, surely. You climb three rungs up the ladder for a closer look.[paragraph break]>[user input type]wear noose[roman type]";
wait for any key;
say "[line break]The noose slips easily over your head and tightens around your neck before you can--your feet slip from the rungs...[paragraph break]";
wait for any key;
say "He had been waiting a really long time. [italic type]Maybe she chickened out...[roman type] And who could blame her? Brandon had been hearing the voices for weeks now, she'd only just started. The rope itched and he'd suffered through a total of [italic type]fourteen[roman type] horrible church-friendly music selections by DJ Deacon JesusLove echoing from the gymasium already. [italic type]I should just do it. Get the process started...[roman type] But he hadn't explained the part about the glyph! He would have to trust she'd follow through with the plan and he hadn't thought to--[paragraph break]There she was! Jessica emerged from the men's restroom resplendent in her glittery black dress, looking like a new and completely different beautiful person. Brandon knew not to let his thoughts idle long, lest one of [italic type]them[roman type] take control and speak for him...[paragraph break]>[user input type]examine jessica[roman type][line break]'Oh, my God, you look [italic type]amazing,[roman type] Jessica!' The dress was too short--just above the knee--for the Maple Harvest Dance in a Catholic school and they wouldn't have let her in, so they had to sneak here through the secret way from the chapel. Her hair glowed autumn orange and gold and it billowed in freshly-cut waves around her face, tied with beads adorned with small scarlet maple leaves.[paragraph break]The music from the gym changed from a vigorous polka to a slow song. [italic type]Finally.[roman type] Soothing electric piano--a BeeGees tune. She approached the ladder and gazed up where he sat perched with his back to the fifth rung.[paragraph break]'Um, I might say the same thing about [italic type]you look amazing,[roman type] Mister Brandon Cragne with-your-shirt-off!' she smirked, placing her hands on the sides of the ladder.[paragraph break]'It gets better,' he raised an eyebrow. 'Do you still have that lipstick with you?'[paragraph break]'Sure do,' she said, holding it up and smacking her red lips in air-kisses.[paragraph break]>";
wait for any key;
say "[user input type]give diagram to jessica[roman type][line break]'Can you copy this? I need you to write this glyph on my chest.'[paragraph break]Jessica peered at the college-ruled drawing torn from his spiral notebook. 'I can. But... how big do you want it? Neck to belly-button--?'[paragraph break]You're the artist. I trust you,' She intently started gliding the red pigment across his skin. 'It just needs to be accurate, not huge--yeah, just like that, that's perfect.'[paragraph break]'Hey,' she said, touching up where the lines were thin, 'I don't suppose there's any chance we could put this off? Just for tonight? Let's go in and dance and get kicked out. We can leave this town, run away, change our names, go up to Canada...'[paragraph break]Brandon grinned. 'Why on earth would you--[italic type]oh God that tickles! Ha![roman type]--Why would anyone want to go all the way up to [italic type]Canada[roman type]?'[paragraph break]'Dunno! I've never been! I've heard it's a cool place and it's gonna be all the rage someday!'[paragraph break]";
if the player consents:
say "'Yeah, it's a cool place with [italic type]really long winters.[roman type] And maple syrup and hockey--I know. That would be fun. But the Harvest Dance doesn't happen every night of the year. We won't get this chance ever again.'";
otherwise:
say "'I can't. We can't. The clock is ticking so... I can't say I don't wish I could have met you a [italic type]whole lot sooner.[roman type] Like junior-high,' he smirked.[line break]";
say "[line break]'Well, then,' Jessica climbed far enough up the ladder so they were almost face-to-face. 'I guess I'm gonna have to do this right now.'[paragraph break]Their lips touched--but she started giggling, then so was he. 'I'm serious!'[paragraph break]The tips of their noses touched. 'So serious!' He leaned down and kissed and it was much [italic type]much[roman type] better.[paragraph break][italic type]how deep is your howlove deepisyourlove how deep is your love? i really need to learn...[roman type]";
wait for any key;
say "[paragraph break]She pulled back, but their eyes never left each other, 'Thank you for inviting me to the dance, Brandon Cragne.'[paragraph break]'Thank you for accepting my invitation, Jessica Santos.'[paragraph break]>[user input type]kiss jessica[roman type]";
wait for any key;
say "[line break]They kissed as long as they could, smiling the whole time. When it was time, she retreated down the ladder and stepped back, sparkling in her outfit and heels.[paragraph break]'Give'm hell, Jessica.'[paragraph break]'That's what I'm planning,' she said, throwing her tiny purse over her shoulder and striding through the double doors to the east toward the gymnasium.[paragraph break]>[user input type]wait[roman type]";
wait for any key;
say "[line break]The fire doors between the narthex and the school hallway clicked closed. Brandon waited as long as he could. He didn't want to chance that she would have to see him or hear what was about to happen. [italic type]And at that moment his resolve faltered. There was no reason for this. He had free will! He didn't have to listen to the voices! He could take this noose right off...[paragraph break]>";
wait for any key;
say "[user input type]jump[roman type][line break]";
say "He stepped off the ladder and thrashed as the rope tightened. [italic type]There was no longer a hole in his head through which he could inhale or exhale--red and black flashes big red and black flashes multiplying and expanding and a vast rushing in his ears heartbeat black darkness try to breathe nope he was tumbling down into a black space of nowhere";
wait for any key;
say "--red flashes pulsing red flashes with veins on the sides those are my eye veins glowing hot pissing my pants how embarrassing red flashes and black flashes and bright black flashes and black--[paragraph break]>";
wait for any key;
say "[user input type]Ah, dear Naomi. As much as we do enjoy your company, there's hardly room for even one extra in young Master Cragne's corporeal form. We hadn't planned for your expeditious arrival so early! Let me first assure you that this isn't how you die. There's so much more you need to accomplish first. Goodness! You're turning quite an amusing shade of purple now, so how about we suspend this exchange temporarily? We'll see you back in, oh, say, fifteen or sixteen years? We look forward to meeting you again--both you and your delicious husband...[roman type][paragraph break]You seem to want to talk to someone, but I can't see whom.[paragraph break]";
wait for any key;
now hano-noose is in hano-cage;
say "The noose melts out of existence--[italic type]GASP[roman type]--and you tumble to the floor, cold green beautiful oxygen tearing painfully into your lungs. Gasping and wheezing. Then just laying with your cheek on the cool tile breathing and enjoying breathing for a good long time.";
wait for any key;
say "[line break]You're still alive, Naomi."
Instead of going up in chu2 when hano-noose is in the location:
try taking hano-noose.
Section 6 - Getting the library book
[Jessica and Naomi both have access to the black tile container, which is connected to a backdrop (hano-ladderfoot) existing in the past and the present]
After inserting hano-library-book into hano-blacktile when the player is hano-jessica:
now hano-library-book is in hano-blacktile;
now hano-shirt is in hano-blacktile;
now hano-blacktile is closed;
now the story viewpoint is second person singular;
now the story tense is present tense;
now the player is yourself;
say "[italic type]There.[roman type] Jessica replaced the black tile with a sense of satisfaction. Nobody would [italic type]ever[roman type] find it unless they knew where to look...[paragraph break][italic type]It was Jessica and Brandon's secret...[roman type][line break]";
Chapter 7 - High School Hallway [hano-hallway]
hano-hallway is east from hano-past-chu2. The printed name is "School Hallway". "The hallway stretched further [bold type]east[roman type] to classrooms and the cafeteria and back [bold type]west[roman type] to the Chapel. The Gymnasium yawned its familiar oppressive woodsmell to the [bold type]north[roman type] below a paper banner in direct opposition to the school Library, which was an oasis of quiet solitude to the [bold type]south[roman type]."
Instead of going east in hano-hallway, say "Jessica didn't feel like trying to socialize in the cafeteria, and she still had time before her next class."
Instead of smelling in hano-hallway, say "The usual fetid dishwater cafeteria funk during lunch from down the hall and the usual gym aroma cocktail of polished wood, public shower humidity, adolescent sweat was overpowered today by the dusty autum scent of a billion dried leaves and Krylon spray shellac."
Commentary of hano-hallway is "This was going to be [italic type]so long[roman type] and complicated originally. In my original scheme Sister Mary confronted Brandon and Jessica together, and the player was going to go back to Naomi and I was going to have to find another piece of something to wear to get back. Originally Brandon asked Jessica to the prom immediately and then asked her for the book. Reversing this worked better and eliminated a superfluous time-shift. Sister Mary Marcia is [italic type]totally[roman type] onto Brandon's diabolical plans and the unearthly voices have to employ Jessica to foil her attempts to stop him. The line [italic type]'vulgtmoth shuggoth marcia! ahf['] ah ahmgn'ghft bthnk Iiahe ymg['] ph'nglui ah agl fahf n'ghft Iiahe n'ghftoggn'thor, vermont?' means (holy woman Marcia! what is shining body as you doing in place this dark as Black-Water, Vermont?)[roman type] I love the idea that Sister Marcia and Vaadignephod have a past. 'Backwater' didnt have a R'lyeh equivalent, so I had Vaadignephod call it 'black water' sort of how people revert to their native pronunciations despite speaking another language. Or the way nobody not from your hometown ever can pronounce the name of your hometown correctly."
Section 1 - [hano-libdoor] library door scenery
a hano-libdoor is scenery in hano-hallway. The printed name is "library door". Understand "library/door/doors" as hano-libdoor. Instead of entering hano-libdoor, try going south. Instead of opening hano-libdoor, try going south.
Section 2 - [hano-banner] gym scenery
a hano-banner is scenery in hano-hallway. Understand "banner/sign/dance/prom/paper/gym/gymnasium/door/doors" as hano-banner. The printed name is "banner over the gym doors". The description is "That year's Maple Harvest Dance theme was [italic type]Sweet Enchantment Under the Leaves![roman type] with glittery numbers reminding people that it was 1979 in case they forgot. The dance was a big deal to the community and a massive student crew had been working on this theme since last fall, collecting [italic type]about a billion[roman type] dried leaves, letting them dry, spray-shellacking them shiny with glitter, and hanging them by the thousands from an overhead net stretched above the gym floor with individual lengths of fishing line. There was barely a location in the entire school that didn't have at least a few crunched-up leaves scattered in the corner.[first time][paragraph break][italic type]It looks cool, but those lights above the canopy are probably a fire-hazard. I can't believe Dawn didn't say something. Screw her and her cleaning crew sweeping up leaves all night. She and all the pretty dresses can go right to hell.[roman type][only]"
Instead of going north in hano-hallway, say "Nah[first time], there were probably about fifty people in there furiously hanging dried leaves to finish up for the dance this weekend, and they'd probably press her into service. Rumor had it at least two people had succumbed to toxic spray-paint fumes already and had to be carried to the nurse[only]."
Instead of entering hano-banner, try going north.
Section 3 - Jessica's locker [hano-locker, hano-pile]
a hano-locker is a closed, openable container in hano-hallway. It is scenery. The printed name is "locker". Understand "her/my/your/-- locker/lock" and "number/-- 74" as hano-locker. The description is "Number 74 had been Jessica's locker the whole year[if hano-locker is open]. The word [italic type]JEZEBEL![roman type] was scrawled all over the inside her locker in red lipstick. None of her schoolbooks were there--they must have removed them to fit more lipsticks.[end if]"
hano-pile is a thing in hano-locker. It is fixed in place. The description is "This took planning. There might be a thousand. Old ones, broken ones, melted ones, all red.". The printed name is "hundreds of lipsticks". Understand "hundred/hundreds/lipsticks/lipstick/tube/tubes" and "hundreds of lipsticks" as hano-pile. Instead of taking hano-pile, say "[italic type]No. Screw that. [roman type]She didn't put them there, so the last thing she was going to do was pick them all up. That's the custodian's job. More disturbing: [italic type]someone[roman type] knew the combination to her locker."
hano-brandeny is a truth state that varies.
After opening hano-locker when hano-pile is in hano-locker:
say "An avalanche of hundreds and hundreds of lipstick tubes poured out of her locker in a rush and spread across the floor, rolling underfoot in the hallway. First there were gasps, then whispering, then laughing. How the heck did they pull this one off?";
now hano-pile is in hano-hallway;
if hano-brandon is in the location:
say "[line break]Brandon glanced over, staring down at the tubes, 'I think you dropped something. So are you Jessica?'[paragraph break][italic type]omigod omigod how does he know my name?[roman type][line break]";
if the player consents:
say "[hano-meetbran]";
otherwise:
say "'No, no...not her. I don't know who she is,' Jessica blurted, not understanding why, her cheeks burning.";
now hano-brandeny is true.
Chapter 8 - Brandon Cragne [hano-brandon] (and his friend, [hano-whatshisname])
hano-brandon is a man in hano-hallway. "[if hano-jessica does not carry hano-library-book][italic type]omigodohmygod...[roman type]Brandon Cragne was leaning on the locker next to hers talking to his friend whatshisname...[otherwise]Brandon was leaning against her locker pushing buttons on his digital watch.[end if]". The printed name is "that dreamy Brandon Cragne". Understand "man/boy/student/guy/dude/love/that/dreamy/brandon/cragne/digital/watch" as hano-brandon. The description is "[one of]Ah. [italic type]Brandon[roman type].[or]Brandon's hair was dark, parted in the center, and made a perfect heart around his smooth forehead before going long and shaggy into perfect feathered waves at his temples where his round silver spectacles (like John Lennon and which he probably really didn't even need because the lenses barely even shifted the profile line of his face and she couldn't believe as clear as his sparkling green eyes were that they wouldn't work properly) [italic type]and his hair was probably too long and the nuns hadn't yet made him cut it and YOU WILL STRANGLE THE NUN WHO MAKES HIM CUT IT WITH YOUR BARE HANDS IF NEED BE.[roman type][or]Brandon grinned at something funny, forming a perfect dimple on his perfect cheek, shaking his hair side to side then it all landed exactly where it was again.[or]Brandon glanced to the side, brushing his hair back off his smooth neck and raising his strong jaw to greet someone distantly across the hall he knew.[or]Brandon fumbled with his top button and loosened it--[italic type]oooh, he's wearing a black shirt under his required white button down! They're going to make him button his top button again if they see him![roman type][or]Brandon's throat made a perfect V, plunging into his shirt where--there was a lump of something on his chest. Was he wearing a necklace under his shirt? What was the thing on his necklace? [italic type]Is that a dark chest hair curling over the collar of his shirt? Oh! There's more than one![roman type][or]Brandon's features blurred into a tingly warm mass of happiness that made her stomach feel funny. Not in a 'ha-ha' way, but in a [italic type]really good way[roman type].[or]Ah. [italic type]Brandon[roman type].[stopping]"
Instead of saying hello to hano-brandon:
if the player carries hano-library-book:
say "[hano-datebran]";
otherwise:
say "[italic type]'Oh, hi, Brandon isn't it? I'm Jessica. Nice to meet you finally!'[roman type] is what she wanted to say, but the words caught in her throat and wouldn't come out. She was going to do it. She was going to do something. She was going to walk right up to him--no, she was going to introduce herself--no, just walk by him like it's no big deal, just say 'Oh, hi, Brandon' and toss her hair and--[paragraph break]At that moment her balance on the high heels failed her, and she pitched forward [italic type]right into Brandon Cragne[roman type] who caught her and kept her from hitting the floor...his arms around her [italic type]he smells like he didn't have time to shower after mowing the lawn this morning sharp bitter green cut clippings and grape bubble gum--[roman type][paragraph break]'Are you okay?' he said, setting her back upright.[paragraph break]'I'm fine! Sorry, I--'[paragraph break]'You're Jessica, right[if hano-brandeny is true]? I know you said you weren't, but you must be,' his brow furrowed a bit and she melted.[else]?'[end if][line break]'Yeah, you got me,' she said, trying to stand up straight in the awkward shoes.[italic type] How does he know my name?[roman type][paragraph break]";
say "[hano-meetbran]";
Instead of going when hano-brandon is in the location:
say ">[user input type]no. stay right here where brandon is[roman type][line break]";
try examining hano-brandon.
Section 1 - Brandon's Note [hano-note]
a hano-note is a thing. The printed name is "scrap of paper". Understand "paper/scrap/note/dewey/decimal/number/card" and "scrap of paper" as hano-note. The description is "It's the Dewey Decimal number of the book Brandon wants you to get him: [italic type]R 623.8 CAM03[roman type]."
Instead of dropping hano-note:
say "Jessica didn't want to lose the paper with the Dewey Decimal code of the book Brandon wanted! She hadn't committed it to memory (yet)."
Section 2 - Meet Brandon
To say hano-meetbran:
say "He smoothed his hair with one hand. Pointlessly, because it fell right back into place. He dismissed his friend with a subtle jerk of his head and Whatshisname scurried off. 'Jessica, I wanted to ask you a question...'[paragraph break]'Sure, Brandon!'[paragraph break]He inhaled, hesitating, 'Are you going...I mean...are you...would you...'[paragraph break]'Yes, Brandon?'";
wait for any key;
say "'Are you...going into the library right now?'[paragraph break]'Um...yeah. I am...actually. I need to return these books.'[paragraph break]Brandon blinked, 'Great! Wonderful! Here's the thing...' He reached into his shirt pocket and drew out a scrap of paper. 'I need a book to do some research before Friday and Sister Mary Marshmallow took away my library privileges. I can't even go in there to read.'[paragraph break]'That's weird,' Jessica said, taking the card which had a Dewey Decimal number on it. 'What did you do to Sister Marcia?'[paragraph break]'Long story.' The hallway was clearing out as lunch was ending, and clacking heels echoed down the hallway. 'Speak of the Devil,' he said, glancing down at the nun who was in the process of confiscating cigarettes from a student. 'I need that book.'[paragraph break]'Sure, I'll go get it right now--'[paragraph break]'Thank you!' he said, putting his warm hands on Jessica's shoulders for a brief, wonderful moment. 'I need to stay out of the Marshmallow's sight, but I'll meet you back out here in a few minutes.'[paragraph break]And he disappeared into the dispersing late lunch crowd.";
now hano-brandon is off-stage;
now hano-whatshisname is off-stage;
now hano-jessica carries hano-note.
Instead of giving hano-library-book to hano-brandon:
say "[hano-datebran]".
Section 3 - Date Brandon
To say hano-datebran:
say "Hey! Brandon. We lucked out! The book was on loan from--'[paragraph break]'Amazing! You're really a groovy chick, you know, Jessica?' he grinned and she felt her neck flush as she held out the book for him.[paragraph break]'One other thing. Don't hand it to me here,' he said, looking over his shoulder. 'I can't even be [italic type]seen[roman type] with a library book. It's a secret. What I need you to do is hide it for me. You know where the black tile is? On the floor in the Narthex?'[line break]";
if the player consents:
say "'Good, okay. Hide that book under the black tile for me, and I'll...do... Hey, do you mind if I ask you another question, Jessica?'[paragraph break]";
otherwise:
say "'If you look right at the base of the ladder to the steeple--in the Narthex--there's one black tile in the floor and it's loose. There's enough room under it to hide the book. Put it under there for me, and...can I ask you one more question?'[paragraph break]";
say "'Sure, Brandon.'[paragraph break]'I know it's short notice, but is someone... I mean, do you um... Do you have plans for Friday night?'[paragraph break]'Friday, um. Well--' Jessica checked her wrist for a watch that wasn't there, 'that's the night of the Maple Harvest Dance, isn't it?'[paragraph break]'It is. And I...I hate social functions, but I get the feeling you do too. But I was wondering...if you weren't going with anyone, would you want to come with me Friday night? We can be anti-social together.[paragraph break]'Well... ";
if the player consents:
say "'Yes, yes! I'd love to go to the dance with you, Brandon!'";
otherwise:
say "'No, I'm not going with anybody, I'd [italic type]love[roman type] to go to the dance with you!'";
say "He leaned forward and [italic type]kissed her forehead[roman type], his lips gentle on her brow. 'Thank you, Jessica. I know it's hard to make your mark in this school, but I promise you after Friday, everyone in Backwater will know who Jessica and Brandon are. I gotta get to Trig. I'll talk to you after school!'[paragraph break]Brandon slipped away into the crowd, and Jessica felt as though she were floating three feet off the floor--until she remembered it was the heels.";
now hano-brandon is off-stage;
now hano-sisterm is in the location.
Every turn when the location is hano-hallway and hano-brandon is in the location and hano-jessica does not carry hano-library-book:
if a random chance of 1 in 2 succeeds:
say ">[user input type]talk to brandon[line break][italic type][one of]Noooo! [or]I caaaan't! [or]There's no way! [or]I'm too shy! [or]Impossible! [or]Not yet... [or]I don't know what to say! [cycling][roman type][if a random chance of 1 in 3 succeeds][italic type]Hush up voices in my head![roman type][end if][line break]"
Section 4 - Brandon's Friend, Whatshisname [hano-whatshisname]
hano-whatshisname is a man in hano-hallway. The description is "[first time]...um. Brandon's friend... has hair... and--[only]Never mind. It doesn't matter. He may as well be scenery other than the fact he's [italic type]Brandon Cragne's friend.[roman type]". hano-whatshisname is scenery. The printed name is "Whateverhisnameis". Understand "man/boy/guy/student/friend/whatshisname/whateverhisnameis/whoever/whatever/brandon's" and "brandon cragne's" and "friend of brandon" as hano-whatshisname.
After examining hano-whatshisname:
say ">[user input type]examine Brandon[roman type][line break]";
try examining hano-brandon.
Instead of doing anything except examining to hano-whatshisname:
say "[one of]Right...him.[or]That guy, [italic type]whatever[roman type].[or]He's blocking your view of Brandon...[or]GO AWAY FRIEND OF BRANDON.[or]But...[or]Um...[or]Did you have a class with him--DOESN'T MATTER.[or]If only you could be standing as close to Brandon as he is now...[then at random]";
try examining hano-brandon.
Section 5 - Sister Mary Marcia's Warning [hano-warning]
hano-sistertrap is a truth state that varies.
Instead of saying hello to hano-sisterm when the location is hano-hallway:
if hano-sistertrap is false:
say "She decided she'd rather stay away from the old nun for now and not engage in conversation.";
otherwise:
say "The nun's grip tightened on her wrist.[paragraph break]'Did you hear me, young lady? Or do we need to march over to the Mother Superior's office?'[paragraph break]>[user input type]push sister mary marcia[roman type][paragraph break]".
Instead of going in hano-hallway when hano-sisterm is in the location and hano-sistertrap is false, say "[hano-warning]".
Instead of taking off hano-heels when hano-sistertrap is true, try pushing hano-sisterm.
To say hano-warning:
now hano-sistertrap is true;
say "Jessica gasped as a clawed hand squeezed her shoulder, whirling her around. Sister Mary Marcia stepped in close, pinning her against the lockers. 'Those shoes are not appropriate for school wear. You are [italic type]out of dress-code[roman type], Missy.'[paragraph break]'I'm sorry Sister Mary Marcia, I didn't--'[paragraph break]'I don't have time for this. Just give me the shoes,' she demanded.[paragraph break]Jessica tried her best to keep control, 'But, please, Sister, these belong to my sister--my own sister--and she will kill me if I don't give them back...'[paragraph break]'Well, she can have them back at the end of the school year like everything else. Take them off this instant.'";
now hano-blacktile is closed.
Instead of doing anything except pushing or attacking hano-sisterm when hano-sistertrap is true:
say "[one of]'But, you don't understand,' Jessica pleaded.[or]'Please, Sister!'[or]'I'll take them off, I'll put them in my locker and you'll never see them again!'[or]'Please don't!'[cycling][line break]The old nun remained firm. '[one of]Hand them over[or]I don't make the rules[or]It's not my fault you don't know the dress code[or]Jesus will forgive you this time[cycling],' she [one of]declared, arms folded[or]stood tapping her foot[or]scowled[or]glared intently at Jessica[cycling].[paragraph break]>[user input type]push sister mary marcia[roman type][paragraph break][italic type][one of]nooooo[or]i cant[or]please don't[or]SHUT UP[or]I WON'T DO IT[or]STOP TELLING ME WHAT TO DO[cycling][roman type][paragraph break]Sister Mary Marcia's grip tightened on Jessica's wrist."
Instead of pushing hano-sisterm when hano-sistertrap is true:
now hano-sistertrap is false;
say "[italic type]Everything grew light as she accepted help again, but this time she held back, tempering the outward flow to a tenth of what it was with Thelma. A ping-pong ball, not a baseball...[paragraph break]!!!paf!!![paragraph break][roman type]A puff of air imploded between them and Sister stepped back, jaw dropped.[paragraph break]'You've been associating with that boy. That devil boy. [italic type]What did Brandon Cragne ask you to do?'[roman type][paragraph break]Jessica opened her mouth to explain he had just asked to accompany her to the dance like a gentleman, but her vocal cords went slack. Words made of air bubbles and tiny involuntary muscle constrictions crackled up from her diaphragm through her throat--[paragraph break]";
wait for any key;
say "[italic type]vulgtmoth shuggoth Marcia! ahf' ah ahmgn'ghft bthnk Iiahe ymg' ph'nglui ah agl fahf n'ghft Iiahe n'ghftoggn'thor, vermont?[roman type][paragraph break]Jessica and Sister Mary Marcia stared reciprocally through wide eyes.[paragraph break]'Jessica, my child. Please accept my sincere and humble advice. Do not listen to Brandon Cragne.' She blinked, then took Jessica's hands in hers. 'Do not ever speak of what I'm about to say to anyone!' She took a breath through her nose. 'Ignore for a moment all the trappings--all this Catholic Christianity bullcrap I usually say to you and please listen to my words--[italic type]for the sake of all of us![roman type] You are playing with [italic type]fire[roman type] that you cannot comprehend nor control, child, and we [italic type]all[roman type] stand to get burned if you insist on dallying with these forces. This is not religion. This is something [italic type]profane[roman type] beyond the known Universe.'[paragraph break]Jessica shook her head. 'I don't understand, Sister Marcia--'[paragraph break]'I am speaking to the entity or entities inside of Jessica now! [italic type]Leave this innocent child alone and return to your assigned plane of existence!'[roman type] She crossed herself and again clasped Jessica's hands in her own cool ones. 'You have no business here!'[roman type][paragraph break]";
wait for any key;
say ">[user input type]push sister mary marcia[roman type][line break]There was a pop like a spark on the doorknob, and the nun startled back, clutching her rosary.[paragraph break][italic type]Oh Jesus I didn't even do that![roman type] 'I'm sorry! Please forgive me, Sister!' but she was backing away, shaking her head and crossing herself.[paragraph break]>[user input type]'I'll see you at the Maple Harvest Dance, Sister Mary Marcia!'[roman type] Jessica called sweetly after her as she disappeared. [user input type]'I'll be there with my dancin['] shoes on!'[roman type][paragraph break]Why did she say that? What was the old woman talking about? Jessica couldn't remember. It didn't matter. She knew what she had to do.";
now hano-sisterm is off-stage.
Chapter 9 - High School Library [hano-library]
hano-library is south of hano-hallway. The printed name is "School Library". "Jessica let herself be submerged in the peace and quiet and smell of old paper that filled the library. The check out counter with its own set of shelves and private card catalog inaccessible to students took up the entryway, then the maze of library stacks spread away in every other direction besides [bold type]north[roman type], which returned to the mundane world of school[one of].[paragraph break]Jessica slid her books through the slot hoping Mrs. Bowler would overlook that they were two days overdue[or]. The school librarian was conversing on the phone in the back office, so she'd have to wait a moment if she needed help[or]. Mrs. Bowler was the only female faculty member who was not a nun, and therefore much easier to talk to[stopping]."
Instead of smelling in hano-library, say "Jessica inhaled deeply the environmental aroma of books, old paper, lemon wood polish, and a tinge of brewed coffee."
Instead of exiting in hano-library, try going north.
Carry out looking in hano-library when hano-jessica carries hano-fakebooks:
now hano-fakebooks is off-stage.
The commentary of hano-library is "The greenish-tome is a red herring. The book says something like 'In time child we will be together...'[paragraph break]When I was in fourth and fifth and sixth grade, I read all the Judy Blume books in the school library including [italic type]Are You There, God, It's Me, Margaret[roman type] like four times. At the time I thought nothing of it--I really liked Judy Blume and read a book a day, but who knows [italic type] what[roman type] the public-school librarian must have thought of this nine-through-eleven year old boy repeatedly checking out a book that frankly discusses menstruation. To her and the whole school's credit, nothing was ever said and I was never challenged nor made to feel embarrased about doing so. Maybe it's because I voraciously read all that they shelved...[italic type]Superfudge; Blubber; Freckle Juice; Then Again, Maybe I Won't; Tales of a Fourth Grade Nothing...[roman type]. Mind you, I had also read [italic type]The Shining[roman type] and the non-boring sections of [roman type]The Exorcist[roman type] before fourth grade. Yes, I was a weird kid who had nightmares."
Section 1 - Ominous Green Book [hano-tome]
a hano-tome is in hano-library. "Her eye was drawn to an ominous greenish-leather tome sitting by itself on the sorting shelves behind the counter." The printed name is "greenish leather tome". Understand "ominous/green/greenish/thick/tooled/uneven/scraps/leather/tome/book/volume/ancient/old/sorting/shelf" and "library book" as hano-tome. The description is "[one of]She couldn't tear her gaze from the thick, ancient volume on the shelf by itself--like the other books didn't want to be near it. The cover was rough-tooled moss-green leather stitched from uneven scraps, and the spine had a flat eye-shaped oval right above the title, which was unreadable at this distance.[or]Looking at the old leather book made her head hurt and her ears crackle like when she got out of the pool and a drop of stubborn water remained on the membrane of her eardrum.[stopping]"
a hano-eye is part of hano-tome. The printed name is "bloodshot eye". Understand "eye/oval/flat/eye-shaped/shaped/title/spine" as hano-eye. Instead of examining hano-eye, try taking hano-tome.
Does the player mean examining hano-eye: it is very likely.
Instead of taking hano-tome:
say "Jessica reached for the book. There was no way her arm would stretch that far, but she tried, [italic type]shoulder dislocating, elbow popping[roman type] fingers [italic type]tingle numb[roman type] ears crackle thoughts scrambled--[italic type]Y['] ahor ymg['] ah, gof'n, ph'nglui yar... [first time]The lidded eye on the spine opened, staring balefully at her, bloodshot, blinking--[only][roman type]";
say "[hano-librarian]".
Instead of examining hano-tome for the third time, try taking hano-tome.
Section 2 - Library scenery [hano-office, hano-stacks, hano-catalog, hano-counter]
hano-office is a woman in hano-library. It is scenery. The printed name is "the library office". Understand "office/mrs/bowler/librarian/teacher" as hano-office. The description is "Mrs. Bowler was back in the office on a phone call. Jessica didn't want to interrupt her.". Instead of doing anything except examining to hano-office, try examining hano-office.
[changed office to an npc last-minute because trying to talk to librarian was saying she wasn't animate]
hano-stacks is an enterable container in hano-library. It is scenery. It is fixed in place. The printed name is "the library stacks". Understand "library/book/books/stack/stacks/shelves/maze/bookshelf/bookshelves" as hano-stacks. The description is "There were thousands of books in the library. It's a good thing they were all cataloged." Instead of entering hano-stacks, try searching hano-stacks.
Instead of searching hano-stacks:
if hano-jessica does not carry hano-library-book:
say "[one of]She forged into the maze and quickly found the location where Brandon's book should have been shelved, but it didn't seem to be there.[or]Jessica made a cursory search nearby to see if the book was just put back in the wrong place, on the shelves, but she came up empty handed.[or]She searched a bit more, finally giving up. Her Dewey Decimal skills wouldn't help on this one.[or]She needed Mrs. Bowler's help to locate the book.[stopping]";
otherwise:
say "Jessica took a quick loop through her favorite sections, but nothing specifically caught her eye.".
a hano-catalog is an open, unopenable container in hano-library. It is fixed in place. It is scenery. the printed name is "card catalog". Understand "card/catalog/library" as hano-catalog. Instead of doing anything to hano-catalog, say "Jessica searched the card catalog[if hano-library-book is not carried by hano-jessica], but couldn't seem to find the book Brandon wanted. She'd probably have to get Mrs. Bowler to help her[otherwise] idly, since there wasn't anything specific she was looking for[end if]."
a hano-counter is a supporter in hano-library. It is scenery. The printed name is "check out counter". Understand "library/check/out/checkout/counter/desk" as hano-counter. The description is "The library check out counter provided a much needed barrier between staff and students."
Section 3 - Library Scene [hano-librarian]
to say hano-librarian:
wait for any key;
say "[paragraph break]'Jessica, are you okay?' Mrs. Bowler was right there.[paragraph break]'I'm fine,' she replied finally, shaking the static out of her head. 'I'm looking for this book.' She pushed the scrap forward on the counter and the librarian peered at it curiously. 'Give me a second.' Mrs. Bowler flipped effortlessly through the drawers of the private staff card catalog, then moved to an enormous paper ledger off to the side, licking her fingers and flipping bible-thin leaves. Jessica scuffed her toe, hoping Brandon wouldn't give up and leave before she returned...[paragraph break]";
now hano-note is off-stage;
wait for any key;
say "She was lost in her thoughts when Mrs. Bowler appeared again, displaying a lavender paperback copy of [italic type]Are You There, God? It's Me, Margaret[roman type], 'Have you ever read this one? It's a really heartwarming story about a girl just like you!'[paragraph break]'Yeah, I think so. Probably in fifth grade.'[paragraph break]'Oh, well, good!' Mrs. Bowler stashed the book under the counter. 'We don't shelve the book you asked about, but the city library does.'[paragraph break]'Really?' Jessica groaned. 'I need it.'[paragraph break]'Well, I can put in a request to transfer it here and you'll have it by next week. Or if your parents have a Backwater Public Library card you could go get it yourself--wait a second...' She turned to the sorting shelves behind her.";
wait for any key;
now hano-jessica carries hano-library-book;
now hano-tome is off-stage;
now hano-brandon is in hano-hallway;
say "[line break]'What was I thinking, here it is!' She grabbed a slim volume from the shelf, stamped a due date on the slip inside the cover, and placed it into Jessica's hands. 'I thought it sounded familiar. I guess someone asked for it to be transferred last week and never showed up to check it out!' The office phone blurbled and she moved toward it. 'Lucky for you!'"
Chapter 10 - Library Book (QUEST ITEM) [hano-library-book]
hano-library-book is a library book. The printed name is "a slim hardback manual". Understand "slim/hardback/tome/manual/volume/book/part/chapter/section/page/pages/print/printing/picture/thought/thoughts/black/knots/knot/illustration/illustrations/purple/indigo/ink" and "to have" and "to have knots" and "to have and to have knots" and "library book" as hano-library-book. The description is "[if the player is hano-jessica]It was the library book Brandon wanted. A stamp in indigo ink inside the cover declared it [italic type]ON LOAN from The Backwater Public Library[roman type] above their weird but kind of cool official library insignia: double eclipsing moons joined by an all-seeing eye reading an open book--[italic type]in Backwater, Vermont.[otherwise]It's a thin but colorful hardback manual, [italic type]To Have, and To Have Knots: An Illustrated Guide[roman type] by Melvyn Camber. A stamp in dark purple ink on the inside of the front cover reads [italic type]ON LOAN from The Backwater Public Library[roman type] above the official library insignia: it's supposed to be two back-to-back crescent moons joined by an eye looking down at an open book, but it's hard not to see it as a scuttling four-legged eye-creature preparing to leap onto the pages below. A loosely-gummed paper slip is pasted to the frontspiece of the book.". The passage of hano-library-book is "[if the player is hano-jessica]Jessica didn't have time to read--she was on a mission for Brandon![otherwise]The book falls naturally open to a picture of a noose.[paragraph break][italic type]The common noose looks great as a scary yard decoration during Halloween or to improve your fishing or boating experience. The noose is a secure and easy-tightening loop that holds it shape for tossing over a boat mooring. But kids, listen to Uncle Melvyn: DO NOT WEAR A NOOSE around your neck or tie one around anyone else's neck under any circumstances, even as a joke...[roman type][end if]". The official title is "To Have, and To Have Knots: An Illustrated Guide".
a hano-slip is part of hano-library-book. The printed name is "gummed slip". Understand "loose/loosely/loosely-gummed/gummed/slip/paper/frontspiece/due/date/stamp/stamps" as hano-slip. The description is "A yellowed slip of paper on the frontspiece of the illustrated knot book has a series of stamped due dates. The last one is [fixed letter spacing]1979 MAR 30 FRI[variable letter spacing]"
Instead of dropping hano-library-book:
say "Jessica didn't think it would be a good idea just to leave the library book out where any random person could take it."
Chapter 11 - Random Syntax
To apply is a verb. To present is a verb. To occur is a verb. To wipe is a verb. To appear is a verb. To name is a verb. To notice is a verb. To expand is a verb.
Section 1 - Mimic User Input (Courtesy Zarf)
To say user input type: (- glk_set_style(8); -).
[say ">[user input type]LOOK[roman type][line break]"]
Section 2 - [hano-applying]
hano-applying is an action applying to one touchable thing. Understand "apply [something]" as hano-applying when the location is chu2 or the location is hano-restroom.
Check hano-applying:
if the noun is hano-lipstick:
try wearing the noun instead;
otherwise:
say "[We] [apply] [our] puzzle-solving skills to [the noun]...no new ideas [occur] to [us]." instead.
Section 3 - [hano-relinquishing]
Dropping something is hano-relinquishing. Inserting something into is hano-relinquishing.
Section 4 - CHECK OUT [something]
Understand "check out [something]" as examining when the location is chu2 or the location is hano-restroom or the player is hano-jessica.
Section 5 - How to hanofrob
hanofrobbing is an action applying to one touchable thing. Understand "use [something]" as hanofrobbing when the location is chu2 or the location is hano-restroom or the player is hano-jessica.
Check hanofrobbing:
say "[We] [aren't] quite sure what to do with [the noun]." instead.
Section 6 - Instead of jumping
Instead of jumping when the location is chu2 or the location is hano-restroom, say "You should conserve your jump meter for the dynamic action sequence that is likely in store."
Instead of jumping when the player is hano-jessica, say "Jumping around randomly is a sign of demon-possession, she had repeatedly been told."
Section 7 - Praying [hano-praying]
hano-praying is an action applying to nothing. Understand "pray" and "worship" as hano-praying when the location is chu2 or the location is hano-restroom or the player is hano-jessica.
Instead of hano-praying when the player is hano-jessica:
say "She muttered a short prayer, mostly out of random reflex whenever she found herself idling in this place."
Instead of hano-praying, say "If you think it will help, Naomi, but keep it focused to what you know. There are a lot of jammed frequencies here in Backwater, Vermont."
Section 8 - Singing [hano-singing]
hano-singing is an action applying to nothing. Understand "sing" and "belt" and "make it your own" as hano-singing when the location is chu2 or the location is hano-restroom or the player is hano-jessica.
Instead of hano-singing:
if the player is hano-jessica:
say "[italic type]'[one of]do it light, taking me through the night[or]shadow danc-ehn baby you do it right[or]give me more, drag me across the floor[or]shadow danc-ehh-hen, all this and nothing more[cycling]...'[roman type][line break]";
otherwise:
if hano-jessica is off-stage:
say "[italic type]'[one of]cause we're living in a world of fools...breaking us down[or]when they all should let us be[or]we belong to you and me...[or]da da da da...dadada da dada da da...[stopping]'[roman type][line break]";
otherwise:
say "[italic type]'[one of]Came in from a ray-nee Thursdee..on the avenooooo[or]Thought I heardyoo talkeeen softleeeeee[or]I turned on the something, something and a ray-dee-ohhhh[or]Still I can't escape the ghost uh-huuuhve yoo-hooooo[cycling]...'[roman type][line break]";
Section 9 - Dancing [hano-dancin]
hano-dancin is an action applying to nothing. Understand "dance" and "groove" and "boogie" as hano-dancin when the location is chu2 or the location is hano-restroom or the player is hano-jessica.
Instead of hano-dancin:
if the player is hano-jessica:
say "Jessica subtly grooved a bit to the music in her head.";
otherwise:
say "You don't like dancing where people might see you, and it has felt like you're being watched ever since the first moment you set foot in Backwater."
Section 10 - Redirect looking behind
hano-looking-behind is an action applying to one thing. Understand "look behind [something]" as hano-looking-behind when the location is chu2 or the location is hano-restroom or the player is hano-jessica.
Instead of hano-looking-behind:
try looking under the noun.
Section 11 - XYZZY [hano-xyzzying]
hano-xyzzying is an action out of world applying to nothing. Understand "xyzzy" as hano-xyzzying when the location is chu2 or the location is hano-restroom or the player is hano-jessica.
Report hano-xyzzying:
if the player is hano-jessica:
if hano-iphone is off-stage:
say "[italic type]the fabric of the universe twists and creaks...[line break]what madness will be wrought upon the world...[line break]when a future-prophet of diabolical machination speaks?[roman type][line break]";
now hano-jessica carries hano-iphone;
otherwise:
say "She didn't want to say it again. She wasn't even quite sure how to pronounce that uncanny of a word.";
otherwise:
say "[one of]A hollow voice says [italic type]'ah[']legeth...'[or]There is nothing but silence.[stopping]";
a hano-iphone is a thing. The printed name is "black artifact". Understand "uncanny/black/artifact/device/phone/telephone/iphone/galaxy/screen/glass/surface/metal/smooth" as hano-iphone. The description is "[italic type]What is this thing? [roman type]A featureless black rectangle, about the size of a deck of cards but flatter, black, the corners perfectly rounded and smooth[first time]. It was slick like glass on one side, and made of...metal?...on the other. Not shiny metal; it was preternaturally smooth like a beach pebble worn over centuries and silvery-gray. Two small black holes on the corner? Metal? But it [italic type]weighed almost nothing in her hand! What metal weighs nothing? [roman type]She found herself caressing it in her hand. So touchable. It felt good to hold it but... It was [italic type]somehow wrong[roman type][only]."
a hano-cage is a closed, unopenable container in chu2. It is scenery. The printed name is "thing that doesn't exist".
Instead of hano-relinquishing when the noun is hano-iphone, say "No. She figured she shouldn't let this thing out of her sight until she could figure out what it actually was and... [italic type]did[roman type]."
After examining hano-iphone for the first time:
the hano-call happens in three turns from now.
At the time when hano-call happens:
if the player is hano-jessica and hano-jessica carries hano-iphone:
say "The weird artifact buzzed in her hand without warning, shocking as an electrical current. A guttural scream wrenched from her throat. She flailed her arms and winced back from the diabolical thing as if it were a red-hot coal.[paragraph break]It flew of its own volition, opening another cacaphonous dimension of hellish sound, pealing forth music from the very depths of an asylum basement. A deep voice from the pit of hell sang in unearthly clarion tones--[italic type]'A LITTLE BIT OF JESSICA HERE I AM[roman type]--' But before a monstrosity could cross over to the human-plane, the device impacted a hard surface and shattered with a delicate crash into 69,105 separate fragments--for all practical purposes [italic type]winking out of existence[roman type] as each particle collapsed into its own individual micro-black hole. ";
wait for any key;
say "Jessica stood clutching her beating heart for a moment, trying to breathe, wondering [italic type]what the hell[roman type] had just happened. [italic type]It said her name. IT KNEW HER NAME.[roman type] She felt dirty, somehow, and wished she'd kept carrying her rosary with her like she was supposed to.";
now hano-iphone is in hano-cage.
a hano-button is part of hano-iphone. The printed name is "fingertip-sized depression". Understand "button/home/fingertip-sized/fingertip/sized/depression" as hano-button.
Instead of pushing or touching hano-button:
say "Her thumb encountered a tiny depression on the surface of the artifact that clicked subtly with pressure and [italic type]vibrant colorful tendrils surfaced under the inky black glass, writhing and swirling like both smoke and liquid simultaneously.[roman type] She dropped the vile rectangle as reflexively as if she'd discovered she had been carrying a live tarantula. Her scream echoed as the infernal device tumbled end-over-end before it hit the floor and shattered with a delicate crash into 69,105 individual fragments [italic type]but just before that, she had seen things--diabolical symbols beginning to rise from the black depths within the glass...[roman type]";
wait for any key;
say "It was gone. Hopefully forever. She shuddered to imagine what nefarious purpose that magical thing had, and what she had done to unwittingly come into possession of it. Maybe she [italic type]should[roman type] go to confession this week.";
now hano-iphone is in hano-cage.
Instead of unlocking hano-iphone with something:
try pushing hano-button.